flex ¶

1 Copyright ¶

The flex manual is placed under the same licensing conditions as the rest of flex:

Copyright © 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2012 The Flex Project.

Copyright © 1990, 1997 The Regents of the University of California. All rights reserved.

This code is derived from software contributed to Berkeley by Vern Paxson.

The United States Government has rights in this work pursuant to contract no. DE-AC03-76SF00098 between the United States Department of Energy and the University of California.

Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:

1. Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
2. Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.

Neither the name of the University nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED “AS IS” AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.

2 Reporting Bugs ¶

If you find a bug in flex, please report it using GitHub’s issue tracking facility at https://github.com/westes/flex/issues/

3 Introduction ¶

flex is a tool for generating scanners. A scanner is a program which recognizes lexical patterns in text. The flex program reads the given input files, or its standard input if no file names are given, for a description of a scanner to generate. The description is in the form of pairs of regular expressions and C code, called rules. flex generates as output a C source file, lex.yy.c by default, which defines a routine yylex(). This file can be compiled and linked with the flex runtime library to produce an executable. When the executable is run, it analyzes its input for occurrences of the regular expressions. Whenever it finds one, it executes the corresponding C code.

4 Some Simple Examples ¶

First some simple examples to get the flavor of how one uses flex.

The following flex input specifies a scanner which, when it encounters the string ‘username’ will replace it with the user’s login name:

    %%
    username    printf( "%s", getlogin() );

By default, any text not matched by a flex scanner is copied to the output, so the net effect of this scanner is to copy its input file to its output with each occurrence of ‘username’ expanded. In this input, there is just one rule. ‘username’ is the pattern and the ‘printf’ is the action. The ‘%%’ symbol marks the beginning of the rules.

Here’s another simple example:

            int num_lines = 0, num_chars = 0;

    %%
    \n      ++num_lines; ++num_chars;
    .       ++num_chars;

    %%

    int main()
            {
            yylex();
            printf( "# of lines = %d, # of chars = %d\n",
                    num_lines, num_chars );
            }

This scanner counts the number of characters and the number of lines in its input. It produces no output other than the final report on the character and line counts. The first line declares two globals, num_lines and num_chars, which are accessible both inside yylex() and in the main() routine declared after the second ‘%%’. There are two rules, one which matches a newline (‘\n’) and increments both the line count and the character count, and one which matches any character other than a newline (indicated by the ‘.’ regular expression).

A somewhat more complicated example:

    /* scanner for a toy Pascal-like language */

    %{
    /* need this for the call to atof() below */
    #include <math.h>
    %}

    DIGIT    [0-9]
    ID       [a-z][a-z0-9]*

    %%

    {DIGIT}+    {
                printf( "An integer: %s (%d)\n", yytext,
                        atoi( yytext ) );
                }

    {DIGIT}+"."{DIGIT}*        {
                printf( "A float: %s (%g)\n", yytext,
                        atof( yytext ) );
                }

    if|then|begin|end|procedure|function        {
                printf( "A keyword: %s\n", yytext );
                }

    {ID}        printf( "An identifier: %s\n", yytext );

    "+"|"-"|"*"|"/"   printf( "An operator: %s\n", yytext );

    "{"[^{}\n]*"}"     /* eat up one-line comments */

    [ \t\n]+          /* eat up whitespace */

    .           printf( "Unrecognized character: %s\n", yytext );

    %%

    int main( int argc, char **argv )
        {
        ++argv, --argc;  /* skip over program name */
        if ( argc > 0 )
                yyin = fopen( argv[0], "r" );
        else
                yyin = stdin;

        yylex();
        }

This is the beginnings of a simple scanner for a language like Pascal. It identifies different types of tokens and reports on what it has seen.

The details of this example will be explained in the following sections.

5 Format of the Input File ¶

The flex input file consists of three sections, separated by a line containing only ‘%%’.

    definitions
    %%
    rules
    %%
    user code

• Format of the Definitions Section
• Format of the Rules Section
• Format of the User Code Section
• Comments in the Input

    name definition

    DIGIT    [0-9]
    ID       [a-z][a-z0-9]*

    {DIGIT}+"."{DIGIT}*

    ([0-9])+"."([0-9])*

    %top{
        /* This code goes at the "top" of the generated file. */
        #include <stdint.h>
        #include <inttypes.h>
    }

    pattern   action

%{
/* code block */
%}

/* Definitions Section */
%x STATE_X

%%
    /* Rules Section */
ruleA   /* after regex */ { /* code block */ } /* after code block */
        /* Rules Section (indented) */
<STATE_X>{
ruleC   ECHO;
ruleD   ECHO;
%{
/* code block */
%}
}
%%
/* User Code Section */

6 Patterns ¶

The patterns in the input (see Format of the Rules Section) are written using an extended set of regular expressions. These are:

‘x’

match the character ’x’

‘.’

any character (byte) except newline

‘[xyz]’ ¶

a character class; in this case, the pattern matches either an ’x’, a ’y’, or a ’z’

‘[abj-oZ]’ ¶

a "character class" with a range in it; matches an ’a’, a ’b’, any letter from ’j’ through ’o’, or a ’Z’

‘[^A-Z]’ ¶

a "negated character class", i.e., any character but those in the class. In this case, any character EXCEPT an uppercase letter.

‘[^A-Z\n]’

any character EXCEPT an uppercase letter or a newline

‘[a-z]{-}[aeiou]’

the lowercase consonants

‘r*’

zero or more r’s, where r is any regular expression

‘r+’

one or more r’s

‘r?’

zero or one r’s (that is, “an optional r”)

‘r{2,5}’ ¶

anywhere from two to five r’s

‘r{2,}’

two or more r’s

‘r{4}’

exactly 4 r’s

‘{name}’ ¶

the expansion of the ‘name’ definition (see Format of the Input File).

‘"[xyz]\"foo"’ ¶

the literal string: ‘[xyz]"foo’

‘\X’ ¶

if X is ‘a’, ‘b’, ‘f’, ‘n’, ‘r’, ‘t’, or ‘v’, then the ANSI-C interpretation of ‘\x’. Otherwise, a literal ‘X’ (used to escape operators such as ‘*’)

‘\0’ ¶

a NUL character (ASCII code 0)

‘\123’ ¶

the character with octal value 123

‘\x2a’

the character with hexadecimal value 2a

‘(r)’

match an ‘r’; parentheses are used to override precedence (see below)

‘(?r-s:pattern)’

apply option ‘r’ and omit option ‘s’ while interpreting pattern. Options may be zero or more of the characters ‘i’, ‘s’, or ‘x’.

‘i’ means case-insensitive. ‘-i’ means case-sensitive.

‘s’ alters the meaning of the ‘.’ syntax to match any single byte whatsoever. ‘-s’ alters the meaning of ‘.’ to match any byte except ‘\n’.

‘x’ ignores comments and whitespace in patterns. Whitespace is ignored unless it is backslash-escaped, contained within ‘""’s, or appears inside a character class.

The following are all valid:

(?:foo)         same as  (foo)
(?i:ab7)        same as  ([aA][bB]7)
(?-i:ab)        same as  (ab)
(?s:.)          same as  [\x00-\xFF]
(?-s:.)         same as  [^\n]
(?ix-s: a . b)  same as  ([Aa][^\n][bB])
(?x:a  b)       same as  ("ab")
(?x:a\ b)       same as  ("a b")
(?x:a" "b)      same as  ("a b")
(?x:a[ ]b)      same as  ("a b")
(?x:a
    /* comment */
    b
    c)          same as  (abc)

‘(?# comment )’

omit everything within ‘()’. The first ‘)’ character encountered ends the pattern. It is not possible to for the comment to contain a ‘)’ character. The comment may span lines.

‘rs’ ¶

the regular expression ‘r’ followed by the regular expression ‘s’; called concatenation

‘r|s’

either an ‘r’ or an ‘s’

‘r/s’ ¶

an ‘r’ but only if it is followed by an ‘s’. The text matched by ‘s’ is included when determining whether this rule is the longest match, but is then returned to the input before the action is executed. So the action only sees the text matched by ‘r’. This type of pattern is called trailing context. (There are some combinations of ‘r/s’ that flex cannot match correctly. See Limitations, regarding dangerous trailing context.)

‘^r’ ¶

an ‘r’, but only at the beginning of a line (i.e., when just starting to scan, or right after a newline has been scanned).

‘r$’ ¶

an ‘r’, but only at the end of a line (i.e., just before a newline). Equivalent to ‘r/\n’.

Note that flex’s notion of “newline” is exactly whatever the C compiler used to compile flex interprets ‘\n’ as; in particular, on some DOS systems you must either filter out ‘\r’s in the input yourself, or explicitly use ‘r/\r\n’ for ‘r$’.

‘<s>r’ ¶

an ‘r’, but only in start condition s (see Start Conditions for discussion of start conditions).

‘<s1,s2,s3>r’

same, but in any of start conditions s1, s2, or s3.

‘<*>r’

an ‘r’ in any start condition, even an exclusive one.

‘<<EOF>>’ ¶

an end-of-file.

‘<s1,s2><<EOF>>’

an end-of-file when in start condition s1 or s2

Note that inside of a character class, all regular expression operators lose their special meaning except escape (‘\’) and the character class operators, ‘-’, ‘]]’, and, at the beginning of the class, ‘^’.

The regular expressions listed above are grouped according to precedence, from highest precedence at the top to lowest at the bottom. Those grouped together have equal precedence (see special note on the precedence of the repeat operator, ‘{}’, under the documentation for the ‘--posix’ POSIX compliance option). For example,

    foo|bar*

is the same as

    (foo)|(ba(r*))

since the ‘*’ operator has higher precedence than concatenation, and concatenation higher than alternation (‘|’). This pattern therefore matches either the string ‘foo’ or the string ‘ba’ followed by zero-or-more ‘r’’s. To match ‘foo’ or zero-or-more repetitions of the string ‘bar’, use:

    foo|(bar)*

And to match a sequence of zero or more repetitions of ‘foo’ and ‘bar’:

    (foo|bar)*

In addition to characters and ranges of characters, character classes can also contain character class expressions. These are expressions enclosed inside ‘[:’ and ‘:]’ delimiters (which themselves must appear between the ‘[’ and ‘]’ of the character class. Other elements may occur inside the character class, too). The valid expressions are:

    [:alnum:] [:alpha:] [:blank:]
    [:cntrl:] [:digit:] [:graph:]
    [:lower:] [:print:] [:punct:]
    [:space:] [:upper:] [:xdigit:]

These expressions all designate a set of characters equivalent to the corresponding standard C isXXX function. For example, ‘[:alnum:]’ designates those characters for which isalnum() returns true - i.e., any alphabetic or numeric character. Some systems don’t provide isblank(), so flex defines ‘[:blank:]’ as a blank or a tab.

For example, the following character classes are all equivalent:

    [[:alnum:]]
    [[:alpha:][:digit:]]
    [[:alpha:][0-9]]
    [a-zA-Z0-9]

A word of caution. Character classes are expanded immediately when seen in the flex input. This means the character classes are sensitive to the locale in which flex is executed, and the resulting scanner will not be sensitive to the runtime locale. This may or may not be desirable.

• If your scanner is case-insensitive (the ‘-i’ flag), then ‘[:upper:]’ and ‘[:lower:]’ are equivalent to ‘[:alpha:]’.
• Character classes with ranges, such as ‘[a-Z]’, should be used with caution in a case-insensitive scanner if the range spans upper or lowercase characters. Flex does not know if you want to fold all upper and lowercase characters together, or if you want the literal numeric range specified (with no case folding). When in doubt, flex will assume that you meant the literal numeric range, and will issue a warning. The exception to this rule is a character range such as ‘[a-z]’ or ‘[S-W]’ where it is obvious that you want case-folding to occur. Here are some examples with the ‘-i’ flag enabled:

  Range	Result	Literal Range	Alternate Range
  ‘[a-t]’	ok	‘[a-tA-T]’
  ‘[A-T]’	ok	‘[a-tA-T]’
  ‘[A-t]’	ambiguous	‘[A-Z\[\\\]_`a-t]’	‘[a-tA-T]’
  ‘[_-{]’	ambiguous	‘[_`a-z{]’	‘[_`a-zA-Z{]’
  ‘[@-C]’	ambiguous	‘[@ABC]’	‘[@A-Z\[\\\]_`abc]’

• A negated character class such as the example ‘[^A-Z]’ above will match a newline unless ‘\n’ (or an equivalent escape sequence) is one of the characters explicitly present in the negated character class (e.g., ‘[^A-Z\n]’). This is unlike how many other regular expression tools treat negated character classes, but unfortunately the inconsistency is historically entrenched. Matching newlines means that a pattern like ‘[^"]*’ can match the entire input unless there’s another quote in the input.

  Flex allows negation of character class expressions by prepending ‘^’ to the POSIX character class name.

      [:^alnum:] [:^alpha:] [:^blank:]
      [:^cntrl:] [:^digit:] [:^graph:]
      [:^lower:] [:^print:] [:^punct:]
      [:^space:] [:^upper:] [:^xdigit:]
  

  Flex will issue a warning if the expressions ‘[:^upper:]’ and ‘[:^lower:]’ appear in a case-insensitive scanner, since their meaning is unclear. The current behavior is to skip them entirely, but this may change without notice in future revisions of flex.

• The ‘{-}’ operator computes the difference of two character classes. For example, ‘[a-c]{-}[b-z]’ represents all the characters in the class ‘[a-c]’ that are not in the class ‘[b-z]’ (which in this case, is just the single character ‘a’). The ‘{-}’ operator is left associative, so ‘[abc]{-}[b]{-}[c]’ is the same as ‘[a]’. Be careful not to accidentally create an empty set, which will never match.
• The ‘{+}’ operator computes the union of two character classes. For example, ‘[a-z]{+}[0-9]’ is the same as ‘[a-z0-9]’. This operator is useful when preceded by the result of a difference operation, as in, ‘[[:alpha:]]{-}[[:lower:]]{+}[q]’, which is equivalent to ‘[A-Zq]’ in the "C" locale.
• A rule can have at most one instance of trailing context (the ‘/’ operator or the ‘$’ operator). The start condition, ‘^’, and ‘<<EOF>>’ patterns can only occur at the beginning of a pattern, and, as well as with ‘/’ and ‘$’, cannot be grouped inside parentheses. A ‘^’ which does not occur at the beginning of a rule or a ‘$’ which does not occur at the end of a rule loses its special properties and is treated as a normal character.
• The following are invalid:

      foo/bar$
      <sc1>foo<sc2>bar
  

  Note that the first of these can be written ‘foo/bar\n’.

• The following will result in ‘$’ or ‘^’ being treated as a normal character:

      foo|(bar$)
      foo|^bar
  

  If the desired meaning is a ‘foo’ or a ‘bar’-followed-by-a-newline, the following could be used (the special | action is explained below, see Actions):

      foo      |
      bar$     /* action goes here */
  

  A similar trick will work for matching a ‘foo’ or a ‘bar’-at-the-beginning-of-a-line.

7 How the Input Is Matched ¶

When the generated scanner is run, it analyzes its input looking for strings which match any of its patterns. If it finds more than one match, it takes the one matching the most text (for trailing context rules, this includes the length of the trailing part, even though it will then be returned to the input). If it finds two or more matches of the same length, the rule listed first in the flex input file is chosen.

Once the match is determined, the text corresponding to the match (called the token) is made available in the global character pointer yytext, and its length in the global integer yyleng. The action corresponding to the matched pattern is then executed (see Actions), and then the remaining input is scanned for another match.

If no match is found, then the default rule is executed: the next character in the input is considered matched and copied to the standard output. Thus, the simplest valid flex input is:

    %%

which generates a scanner that simply copies its input (one character at a time) to its output.

Note that yytext can be defined in two different ways: either as a character pointer or as a character array. You can control which definition flex uses by including one of the special directives %pointer or %array in the first (definitions) section of your flex input. The default is %pointer, unless you use the ‘-l’ lex compatibility option, in which case yytext will be an array. The advantage of using %pointer is substantially faster scanning and no buffer overflow when matching very large tokens (unless you run out of dynamic memory). The disadvantage is that you are restricted in how your actions can modify yytext (see Actions), and calls to the unput() function destroys the present contents of yytext, which can be a considerable porting headache when moving between different lex versions.

The advantage of %array is that you can then modify yytext to your heart’s content, and calls to unput() do not destroy yytext (see Actions). Furthermore, existing lex programs sometimes access yytext externally using declarations of the form:

    extern char yytext[];

This definition is erroneous when used with %pointer, but correct for %array.

The %array declaration defines yytext to be an array of YYLMAX characters, which defaults to a fairly large value. You can change the size by simply #define’ing YYLMAX to a different value in the first section of your flex input. As mentioned above, with %pointer yytext grows dynamically to accommodate large tokens. While this means your %pointer scanner can accommodate very large tokens (such as matching entire blocks of comments), bear in mind that each time the scanner must resize yytext it also must rescan the entire token from the beginning, so matching such tokens can prove slow. yytext presently does not dynamically grow if a call to unput() results in too much text being pushed back; instead, a run-time error results.

Also note that you cannot use %array with C++ scanner classes (see Generating C++ Scanners).

8 Actions ¶

Each pattern in a rule has a corresponding action, which can be any arbitrary C statement. The pattern ends at the first non-escaped whitespace character; the remainder of the line is its action. If the action is empty, then when the pattern is matched the input token is simply discarded. For example, here is the specification for a program which deletes all occurrences of ‘zap me’ from its input:

    %%
    "zap me"

This example will copy all other characters in the input to the output since they will be matched by the default rule.

Here is a program which compresses multiple blanks and tabs down to a single blank, and throws away whitespace found at the end of a line:

    %%
    [ \t]+        putchar( ' ' );
    [ \t]+$       /* ignore this token */

If the action contains a ‘{’, then the action spans till the balancing ‘}’ is found, and the action may cross multiple lines. flex knows about C strings and comments and won’t be fooled by braces found within them, but also allows actions to begin with ‘%{’ and will consider the action to be all the text up to the next ‘%}’ (regardless of ordinary braces inside the action).

An action consisting solely of a vertical bar (‘|’) means “same as the action for the next rule”. See below for an illustration.

Actions can include arbitrary C code, including return statements to return a value to whatever routine called yylex(). Each time yylex() is called it continues processing tokens from where it last left off until it either reaches the end of the file or executes a return.

Actions are free to modify yytext except for lengthening it (adding characters to its end–these will overwrite later characters in the input stream). This however does not apply when using %array (see How the Input Is Matched). In that case, yytext may be freely modified in any way.

Actions are free to modify yyleng except they should not do so if the action also includes use of yymore() (see below).

There are a number of special directives which can be included within an action:

ECHO ¶

copies yytext to the scanner’s output.

BEGIN ¶

followed by the name of a start condition places the scanner in the corresponding start condition (see below).

REJECT ¶

directs the scanner to proceed on to the “second best” rule which matched the input (or a prefix of the input). The rule is chosen as described above in How the Input Is Matched, and yytext and yyleng set up appropriately. It may either be one which matched as much text as the originally chosen rule but came later in the flex input file, or one which matched less text. For example, the following will both count the words in the input and call the routine special() whenever ‘frob’ is seen:

            int word_count = 0;
    %%

    frob        special(); REJECT;
    [^ \t\n]+   ++word_count;

Without the REJECT, any occurrences of ‘frob’ in the input would not be counted as words, since the scanner normally executes only one action per token. Multiple uses of REJECT are allowed, each one finding the next best choice to the currently active rule. For example, when the following scanner scans the token ‘abcd’, it will write ‘abcdabcaba’ to the output:

    %%
    a        |
    ab       |
    abc      |
    abcd     ECHO; REJECT;
    .|\n     /* eat up any unmatched character */

The first three rules share the fourth’s action since they use the special ‘|’ action.

REJECT is a particularly expensive feature in terms of scanner performance; if it is used in any of the scanner’s actions it will slow down all of the scanner’s matching. Furthermore, REJECT cannot be used with the ‘-Cf’ or ‘-CF’ options (see Scanner Options).

Note also that unlike the other special actions, REJECT is a branch. Code immediately following it in the action will not be executed.

yymore() ¶

tells the scanner that the next time it matches a rule, the corresponding token should be appended onto the current value of yytext rather than replacing it. For example, given the input ‘mega-kludge’ the following will write ‘mega-mega-kludge’ to the output:

    %%
    mega-    ECHO; yymore();
    kludge   ECHO;

First ‘mega-’ is matched and echoed to the output. Then ‘kludge’ is matched, but the previous ‘mega-’ is still hanging around at the beginning of yytext so the ECHO for the ‘kludge’ rule will actually write ‘mega-kludge’.

Two notes regarding use of yymore(). First, yymore() depends on the value of yyleng correctly reflecting the size of the current token, so you must not modify yyleng if you are using yymore(). Second, the presence of yymore() in the scanner’s action entails a minor performance penalty in the scanner’s matching speed.

yyless(n) returns all but the first n characters of the current token back to the input stream, where they will be rescanned when the scanner looks for the next match. yytext and yyleng are adjusted appropriately (e.g., yyleng will now be equal to n). For example, on the input ‘foobar’ the following will write out ‘foobarbar’:

    %%
    foobar    ECHO; yyless(3);
    [a-z]+    ECHO;

An argument of 0 to yyless() will cause the entire current input string to be scanned again. Unless you’ve changed how the scanner will subsequently process its input (using BEGIN, for example), this will result in an endless loop.

Note that yyless() is a macro and can only be used in the flex input file, not from other source files.

unput(c) puts the character c back onto the input stream. It will be the next character scanned. The following action will take the current token and cause it to be rescanned enclosed in parentheses.

    {
    int i;
    /* Copy yytext because unput() trashes yytext */
    char *yycopy = strdup( yytext );
    unput( ')' );
    for ( i = yyleng - 1; i >= 0; --i )
        unput( yycopy[i] );
    unput( '(' );
    free( yycopy );
    }

Note that since each unput() puts the given character back at the beginning of the input stream, pushing back strings must be done back-to-front.

An important potential problem when using unput() is that if you are using %pointer (the default), a call to unput() destroys the contents of yytext, starting with its rightmost character and devouring one character to the left with each call. If you need the value of yytext preserved after a call to unput() (as in the above example), you must either first copy it elsewhere, or build your scanner using %array instead (see How the Input Is Matched).

Finally, note that you cannot put back ‘EOF’ to attempt to mark the input stream with an end-of-file.

input() reads the next character from the input stream. For example, the following is one way to eat up C comments:

    %%
    "/*"        {
                int c;

                for ( ; ; )
                    {
                    while ( (c = input()) != '*' &&
                            c != EOF )
                        ;    /* eat up text of comment */

                    if ( c == '*' )
                        {
                        while ( (c = input()) == '*' )
                            ;
                        if ( c == '/' )
                            break;    /* found the end */
                        }

                    if ( c == EOF )
                        {
                        error( "EOF in comment" );
                        break;
                        }
                    }
                }

(Note that if the scanner is compiled using C++, then input() is instead referred to as yyinput(), in order to avoid a name clash with the C++ stream by the name of input.)

YY_FLUSH_BUFFER; flushes the scanner’s internal buffer so that the next time the scanner attempts to match a token, it will first refill the buffer using YY_INPUT() (see The Generated Scanner). This action is a special case of the more general yy_flush_buffer; function, described below (see Multiple Input Buffers)

yyterminate() can be used in lieu of a return statement in an action. It terminates the scanner and returns a 0 to the scanner’s caller, indicating “all done”. By default, yyterminate() is also called when an end-of-file is encountered. It is a macro and may be redefined.

9 The Generated Scanner ¶

The output of flex is the file lex.yy.c, which contains the scanning routine yylex(), a number of tables used by it for matching tokens, and a number of auxiliary routines and macros. By default, yylex() is declared as follows:

    int yylex()
        {
        ... various definitions and the actions in here ...
        }

(If your environment supports function prototypes, then it will be int yylex( void ).) This definition may be changed by defining the YY_DECL macro. For example, you could use:

    #define YY_DECL float lexscan( a, b ) float a, b;

to give the scanning routine the name lexscan, returning a float, and taking two floats as arguments. Note that if you give arguments to the scanning routine using a K&R-style/non-prototyped function declaration, you must terminate the definition with a semi-colon (;).

flex generates ‘C99’ function definitions by default. Flex used to have the ability to generate obsolete, er, ‘traditional’, function definitions. This was to support bootstrapping gcc on old systems. Unfortunately, traditional definitions prevent us from using any standard data types smaller than int (such as short, char, or bool) as function arguments. Furthermore, traditional definitions support added extra complexity in the skeleton file. For this reason, current versions of flex generate standard C99 code only, leaving K&R-style functions to the historians.

Whenever yylex() is called, it scans tokens from the global input file yyin (which defaults to stdin). It continues until it either reaches an end-of-file (at which point it returns the value 0) or one of its actions executes a return statement.

If the scanner reaches an end-of-file, subsequent calls are undefined unless either yyin is pointed at a new input file (in which case scanning continues from that file), or yyrestart() is called. yyrestart() takes one argument, a FILE * pointer (which can be NULL, if you’ve set up YY_INPUT to scan from a source other than yyin), and initializes yyin for scanning from that file. Essentially there is no difference between just assigning yyin to a new input file or using yyrestart() to do so; the latter is available for compatibility with previous versions of flex, and because it can be used to switch input files in the middle of scanning. It can also be used to throw away the current input buffer, by calling it with an argument of yyin; but it would be better to use YY_FLUSH_BUFFER (see Actions). Note that yyrestart() does not reset the start condition to INITIAL (see Start Conditions).

If yylex() stops scanning due to executing a return statement in one of the actions, the scanner may then be called again and it will resume scanning where it left off.

By default (and for purposes of efficiency), the scanner uses block-reads rather than simple getc() calls to read characters from yyin. The nature of how it gets its input can be controlled by defining the YY_INPUT macro. The calling sequence for YY_INPUT() is YY_INPUT(buf,result,max_size). Its action is to place up to max_size characters in the character array buf and return in the integer variable result either the number of characters read or the constant YY_NULL (0 on Unix systems) to indicate ‘EOF’. The default YY_INPUT reads from the global file-pointer yyin.

Here is a sample definition of YY_INPUT (in the definitions section of the input file):

    %{
    #define YY_INPUT(buf,result,max_size) \
        { \
        int c = getchar(); \
        result = (c == EOF) ? YY_NULL : (buf[0] = c, 1); \
        }
    %}

This definition will change the input processing to occur one character at a time.

When the scanner receives an end-of-file indication from YY_INPUT, it then checks the yywrap() function. If yywrap() returns false (zero), then it is assumed that the function has gone ahead and set up yyin to point to another input file, and scanning continues. If it returns true (non-zero), then the scanner terminates, returning 0 to its caller. Note that in either case, the start condition remains unchanged; it does not revert to INITIAL.

If you do not supply your own version of yywrap(), then you must either use %option noyywrap (in which case the scanner behaves as though yywrap() returned 1), or you must link with ‘-lfl’ to obtain the default version of the routine, which always returns 1.

For scanning from in-memory buffers (e.g., scanning strings), see Scanning Strings. See Multiple Input Buffers.

The scanner writes its ECHO output to the yyout global (default, stdout), which may be redefined by the user simply by assigning it to some other FILE pointer.

10 Start Conditions ¶

flex provides a mechanism for conditionally activating rules. Any rule whose pattern is prefixed with ‘<sc>’ will only be active when the scanner is in the start condition named sc. For example,

    <STRING>[^"]*        { /* eat up the string body ... */
                ...
                }

will be active only when the scanner is in the STRING start condition, and

    <INITIAL,STRING,QUOTE>\.        { /* handle an escape ... */
                ...
                }

will be active only when the current start condition is either INITIAL, STRING, or QUOTE.

Start conditions are declared in the definitions (first) section of the input using unindented lines beginning with either ‘%s’ or ‘%x’ followed by a list of names. The former declares inclusive start conditions, the latter exclusive start conditions. A start condition is activated using the BEGIN action. Until the next BEGIN action is executed, rules with the given start condition will be active and rules with other start conditions will be inactive. If the start condition is inclusive, then rules with no start conditions at all will also be active. If it is exclusive, then only rules qualified with the start condition will be active. A set of rules contingent on the same exclusive start condition describe a scanner which is independent of any of the other rules in the flex input. Because of this, exclusive start conditions make it easy to specify “mini-scanners” which scan portions of the input that are syntactically different from the rest (e.g., comments).

If the distinction between inclusive and exclusive start conditions is still a little vague, here’s a simple example illustrating the connection between the two. The set of rules:

    %s example
    %%

    <example>foo   do_something();

    bar            something_else();

is equivalent to

    %x example
    %%

    <example>foo   do_something();

    <INITIAL,example>bar    something_else();

Without the <INITIAL,example> qualifier, the bar pattern in the second example wouldn’t be active (i.e., couldn’t match) when in start condition example. If we just used <example> to qualify bar, though, then it would only be active in example and not in INITIAL, while in the first example it’s active in both, because in the first example the example start condition is an inclusive (%s) start condition.

Also note that the special start-condition specifier <*> matches every start condition. Thus, the above example could also have been written:

    %x example
    %%

    <example>foo   do_something();

    <*>bar    something_else();

The default rule (to ECHO any unmatched character) remains active in start conditions. It is equivalent to:

    <*>.|\n     ECHO;

BEGIN(0) returns to the original state where only the rules with no start conditions are active. This state can also be referred to as the start-condition INITIAL, so BEGIN(INITIAL) is equivalent to BEGIN(0). (The parentheses around the start condition name are not required but are considered good style.)

BEGIN actions can also be given as indented code at the beginning of the rules section. For example, the following will cause the scanner to enter the SPECIAL start condition whenever yylex() is called and the global variable enter_special is true:

            int enter_special;

    %x SPECIAL
    %%
            if ( enter_special )
                BEGIN(SPECIAL);

    <SPECIAL>blahblahblah
    ...more rules follow...

To illustrate the uses of start conditions, here is a scanner which provides two different interpretations of a string like ‘123.456’. By default it will treat it as three tokens, the integer ‘123’, a dot (‘.’), and the integer ‘456’. But if the string is preceded earlier in the line by the string ‘expect-floats’ it will treat it as a single token, the floating-point number ‘123.456’:

    %{
    #include <math.h>
    %}
    %s expect

    %%
    expect-floats        BEGIN(expect);

    <expect>[0-9]+.[0-9]+      {
                printf( "found a float, = %f\n",
                        atof( yytext ) );
                }
    <expect>\n           {
                /* that's the end of the line, so
                 * we need another "expect-number"
                 * before we'll recognize any more
                 * numbers
                 */
                BEGIN(INITIAL);
                }

    [0-9]+      {
                printf( "found an integer, = %d\n",
                        atoi( yytext ) );
                }

    "."         printf( "found a dot\n" );

Here is a scanner which recognizes (and discards) C comments while maintaining a count of the current input line.

    %x comment
    %%
            int line_num = 1;

    "/*"         BEGIN(comment);

    <comment>[^*\n]*        /* eat anything that's not a '*' */
    <comment>"*"+[^*/\n]*   /* eat up '*'s not followed by '/'s */
    <comment>\n             ++line_num;
    <comment>"*"+"/"        BEGIN(INITIAL);

This scanner goes to a bit of trouble to match as much text as possible with each rule. In general, when attempting to write a high-speed scanner try to match as much possible in each rule, as it’s a big win.

Note that start-conditions names are really integer values and can be stored as such. Thus, the above could be extended in the following fashion:

    %x comment foo
    %%
            int line_num = 1;
            int comment_caller;

    "/*"         {
                 comment_caller = INITIAL;
                 BEGIN(comment);
                 }

    ...

    <foo>"/*"    {
                 comment_caller = foo;
                 BEGIN(comment);
                 }

    <comment>[^*\n]*        /* eat anything that's not a '*' */
    <comment>"*"+[^*/\n]*   /* eat up '*'s not followed by '/'s */
    <comment>\n             ++line_num;
    <comment>"*"+"/"        BEGIN(comment_caller);

Furthermore, you can access the current start condition using the integer-valued YY_START macro. For example, the above assignments to comment_caller could instead be written

    comment_caller = YY_START;

Flex provides YYSTATE as an alias for YY_START (since that is what’s used by AT&T lex).

For historical reasons, start conditions do not have their own name-space within the generated scanner. The start condition names are unmodified in the generated scanner and generated header. See option-header. See option-prefix.

Finally, here’s an example of how to match C-style quoted strings using exclusive start conditions, including expanded escape sequences (but not including checking for a string that’s too long):

    %x str

    %%
            char string_buf[MAX_STR_CONST];
            char *string_buf_ptr;


    \"      string_buf_ptr = string_buf; BEGIN(str);

    <str>\"        { /* saw closing quote - all done */
            BEGIN(INITIAL);
            *string_buf_ptr = '\0';
            /* return string constant token type and
             * value to parser
             */
            }

    <str>\n        {
            /* error - unterminated string constant */
            /* generate error message */
            }

    <str>\\[0-7]{1,3} {
            /* octal escape sequence */
            int result;

            (void) sscanf( yytext + 1, "%o", &result );

            if ( result > 0xff )
                    /* error, constant is out-of-bounds */

            *string_buf_ptr++ = result;
            }

    <str>\\[0-9]+ {
            /* generate error - bad escape sequence; something
             * like '\48' or '\0777777'
             */
            }

    <str>\\n  *string_buf_ptr++ = '\n';
    <str>\\t  *string_buf_ptr++ = '\t';
    <str>\\r  *string_buf_ptr++ = '\r';
    <str>\\b  *string_buf_ptr++ = '\b';
    <str>\\f  *string_buf_ptr++ = '\f';

    <str>\\(.|\n)  *string_buf_ptr++ = yytext[1];

    <str>[^\\\n\"]+        {
            char *yptr = yytext;

            while ( *yptr )
                    *string_buf_ptr++ = *yptr++;
            }

Often, such as in some of the examples above, you wind up writing a whole bunch of rules all preceded by the same start condition(s). Flex makes this a little easier and cleaner by introducing a notion of start condition scope. A start condition scope is begun with:

    <SCs>{

where <SCs> is a list of one or more start conditions. Inside the start condition scope, every rule automatically has the prefix <SCs> applied to it, until a ‘}’ which matches the initial ‘{’. So, for example,

    <ESC>{
        "\\n"   return '\n';
        "\\r"   return '\r';
        "\\f"   return '\f';
        "\\0"   return '\0';
    }

is equivalent to:

    <ESC>"\\n"  return '\n';
    <ESC>"\\r"  return '\r';
    <ESC>"\\f"  return '\f';
    <ESC>"\\0"  return '\0';

Start condition scopes may be nested.

The following routines are available for manipulating stacks of start conditions:

Function: void yy_push_state ( int new_state ) ¶

pushes the current start condition onto the top of the start condition stack and switches to new_state as though you had used BEGIN new_state (recall that start condition names are also integers).

Function: void yy_pop_state () ¶

pops the top of the stack and switches to it via BEGIN.

Function: int yy_top_state () ¶

returns the top of the stack without altering the stack’s contents.

The start condition stack grows dynamically and so has no built-in size limitation. If memory is exhausted, program execution aborts.

To use start condition stacks, your scanner must include a %option stack directive (see Scanner Options).

11 Multiple Input Buffers ¶

Some scanners (such as those which support “include” files) require reading from several input streams. As flex scanners do a large amount of buffering, one cannot control where the next input will be read from by simply writing a YY_INPUT() which is sensitive to the scanning context. YY_INPUT() is only called when the scanner reaches the end of its buffer, which may be a long time after scanning a statement such as an include statement which requires switching the input source.

To negotiate these sorts of problems, flex provides a mechanism for creating and switching between multiple input buffers. An input buffer is created by using:

Function: YY_BUFFER_STATE yy_create_buffer ( FILE *file, int size ) ¶

which takes a FILE pointer and a size and creates a buffer associated with the given file and large enough to hold size characters (when in doubt, use YY_BUF_SIZE for the size). It returns a YY_BUFFER_STATE handle, which may then be passed to other routines (see below). The YY_BUFFER_STATE type is a pointer to an opaque struct yy_buffer_state structure, so you may safely initialize YY_BUFFER_STATE variables to ((YY_BUFFER_STATE) 0) if you wish, and also refer to the opaque structure in order to correctly declare input buffers in source files other than that of your scanner. Note that the FILE pointer in the call to yy_create_buffer is only used as the value of yyin seen by YY_INPUT. If you redefine YY_INPUT() so it no longer uses yyin, then you can safely pass a NULL FILE pointer to yy_create_buffer. You select a particular buffer to scan from using:

Function: void yy_switch_to_buffer ( YY_BUFFER_STATE new_buffer ) ¶

The above function switches the scanner’s input buffer so subsequent tokens will come from new_buffer. Note that yy_switch_to_buffer() may be used by yywrap() to set things up for continued scanning, instead of opening a new file and pointing yyin at it. If you are looking for a stack of input buffers, then you want to use yypush_buffer_state() instead of this function. Note also that switching input sources via either yy_switch_to_buffer() or yywrap() does not change the start condition.

Function: void yy_delete_buffer ( YY_BUFFER_STATE buffer ) ¶

is used to reclaim the storage associated with a buffer. (buffer can be NULL, in which case the routine does nothing.) You can also clear the current contents of a buffer using:

Function: void yypush_buffer_state ( YY_BUFFER_STATE buffer ) ¶

This function pushes the new buffer state onto an internal stack. The pushed state becomes the new current state. The stack is maintained by flex and will grow as required. This function is intended to be used instead of yy_switch_to_buffer, when you want to change states, but preserve the current state for later use.

Function: void yypop_buffer_state ( ) ¶

This function removes the current state from the top of the stack, and deletes it by calling yy_delete_buffer. The next state on the stack, if any, becomes the new current state.

Function: void yy_flush_buffer ( YY_BUFFER_STATE buffer ) ¶

This function discards the buffer’s contents, so the next time the scanner attempts to match a token from the buffer, it will first fill the buffer anew using YY_INPUT().

Function: YY_BUFFER_STATE yy_new_buffer ( FILE *file, int size ) ¶

is an alias for yy_create_buffer(), provided for compatibility with the C++ use of new and delete for creating and destroying dynamic objects.

YY_CURRENT_BUFFER macro returns a YY_BUFFER_STATE handle to the current buffer. It should not be used as an lvalue.

Here are two examples of using these features for writing a scanner which expands include files (the <<EOF>> feature is discussed below).

This first example uses yypush_buffer_state and yypop_buffer_state. Flex maintains the stack internally.

    /* the "incl" state is used for picking up the name
     * of an include file
     */
    %x incl
    %%
    include             BEGIN(incl);

    [a-z]+              ECHO;
    [^a-z\n]*\n?        ECHO;

    <incl>[ \t]*      /* eat the whitespace */
    <incl>[^ \t\n]+   { /* got the include file name */
            yyin = fopen( yytext, "r" );

            if ( ! yyin )
                error( ... );

			yypush_buffer_state(yy_create_buffer( yyin, YY_BUF_SIZE ));

            BEGIN(INITIAL);
            }

    <<EOF>> {
			yypop_buffer_state();

            if ( !YY_CURRENT_BUFFER )
                {
                yyterminate();
                }
            }

The second example, below, does the same thing as the previous example did, but manages its own input buffer stack manually (instead of letting flex do it).

    /* the "incl" state is used for picking up the name
     * of an include file
     */
    %x incl

    %{
    #define MAX_INCLUDE_DEPTH 10
    YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
    int include_stack_ptr = 0;
    %}

    %%
    include             BEGIN(incl);

    [a-z]+              ECHO;
    [^a-z\n]*\n?        ECHO;

    <incl>[ \t]*      /* eat the whitespace */
    <incl>[^ \t\n]+   { /* got the include file name */
            if ( include_stack_ptr >= MAX_INCLUDE_DEPTH )
                {
                fprintf( stderr, "Includes nested too deeply" );
                exit( 1 );
                }

            include_stack[include_stack_ptr++] =
                YY_CURRENT_BUFFER;

            yyin = fopen( yytext, "r" );

            if ( ! yyin )
                error( ... );

            yy_switch_to_buffer(
                yy_create_buffer( yyin, YY_BUF_SIZE ) );

            BEGIN(INITIAL);
            }

    <<EOF>> {
            if ( --include_stack_ptr == 0 )
                {
                yyterminate();
                }

            else
                {
                yy_delete_buffer( YY_CURRENT_BUFFER );
                yy_switch_to_buffer(
                     include_stack[include_stack_ptr] );
                }
            }

The following routines are available for setting up input buffers for scanning in-memory strings instead of files. All of them create a new input buffer for scanning the string, and return a corresponding YY_BUFFER_STATE handle (which you should delete with yy_delete_buffer() when done with it). They also switch to the new buffer using yy_switch_to_buffer(), so the next call to yylex() will start scanning the string.

Function: YY_BUFFER_STATE yy_scan_string ( const char *str ) ¶

scans a NUL-terminated string.

Function: YY_BUFFER_STATE yy_scan_bytes ( const char *bytes, int len ) ¶

scans len bytes (including possibly NULs) starting at location bytes.

Note that both of these functions create and scan a copy of the string or bytes. (This may be desirable, since yylex() modifies the contents of the buffer it is scanning.) You can avoid the copy by using:

Function: YY_BUFFER_STATE yy_scan_buffer (char *base, yy_size_t size) ¶

which scans in place the buffer starting at base, consisting of size bytes, the last two bytes of which must be YY_END_OF_BUFFER_CHAR (ASCII NUL). These last two bytes are not scanned; thus, scanning consists of base[0] through base[size-2], inclusive.

If you fail to set up base in this manner (i.e., forget the final two YY_END_OF_BUFFER_CHAR bytes), then yy_scan_buffer() returns a NULL pointer instead of creating a new input buffer.

Data type: yy_size_t ¶

is an integral type to which you can cast an integer expression reflecting the size of the buffer.

12 End-of-File Rules ¶

The special rule <<EOF>> indicates actions which are to be taken when an end-of-file is encountered and yywrap() returns non-zero (i.e., indicates no further files to process). The action must finish by doing one of the following things:

• assigning yyin to a new input file (in previous versions of flex, after doing the assignment you had to call the special action YY_NEW_FILE. This is no longer necessary.)
• executing a return statement;
• executing the special yyterminate() action.
• or, switching to a new buffer using yy_switch_to_buffer() as shown in the example above.

<<EOF>> rules may not be used with other patterns; they may only be qualified with a list of start conditions. If an unqualified <<EOF>> rule is given, it applies to all start conditions which do not already have <<EOF>> actions. To specify an <<EOF>> rule for only the initial start condition, use:

    <INITIAL><<EOF>>

These rules are useful for catching things like unclosed comments. An example:

    %x quote
    %%

    ...other rules for dealing with quotes...

    <quote><<EOF>>   {
             error( "unterminated quote" );
             yyterminate();
             }
   <<EOF>>  {
             if ( *++filelist )
                 yyin = fopen( *filelist, "r" );
             else
                yyterminate();
             }

13 Miscellaneous Macros ¶

The macro YY_USER_ACTION can be defined to provide an action which is always executed prior to the matched rule’s action. For example, it could be #define’d to call a routine to convert yytext to lower-case. When YY_USER_ACTION is invoked, the variable yy_act gives the number of the matched rule (rules are numbered starting with 1). Suppose you want to profile how often each of your rules is matched. The following would do the trick:

    #define YY_USER_ACTION ++ctr[yy_act]

where ctr is an array to hold the counts for the different rules. Note that the macro YY_NUM_RULES gives the total number of rules (including the default rule), even if you use ‘-s)’, so a correct declaration for ctr is:

    int ctr[YY_NUM_RULES];

The macro YY_USER_INIT may be defined to provide an action which is always executed before the first scan (and before the scanner’s internal initializations are done). For example, it could be used to call a routine to read in a data table or open a logging file.

The macro yy_set_interactive(is_interactive) can be used to control whether the current buffer is considered interactive. An interactive buffer is processed more slowly, but must be used when the scanner’s input source is indeed interactive to avoid problems due to waiting to fill buffers (see the discussion of the ‘-I’ flag in Scanner Options). A non-zero value in the macro invocation marks the buffer as interactive, a zero value as non-interactive. Note that use of this macro overrides %option always-interactive or %option never-interactive (see Scanner Options). yy_set_interactive() must be invoked prior to beginning to scan the buffer that is (or is not) to be considered interactive.

The macro yy_set_bol(at_bol) can be used to control whether the current buffer’s scanning context for the next token match is done as though at the beginning of a line. A non-zero macro argument makes rules anchored with ‘^’ active, while a zero argument makes ‘^’ rules inactive.

The macro YY_AT_BOL() returns true if the next token scanned from the current buffer will have ‘^’ rules active, false otherwise.

In the generated scanner, the actions are all gathered in one large switch statement and separated using YY_BREAK, which may be redefined. By default, it is simply a break, to separate each rule’s action from the following rule’s. Redefining YY_BREAK allows, for example, C++ users to #define YY_BREAK to do nothing (while being very careful that every rule ends with a break or a return!) to avoid suffering from unreachable statement warnings where because a rule’s action ends with return, the YY_BREAK is inaccessible.

14 Values Available To the User ¶

This chapter summarizes the various values available to the user in the rule actions.

char *yytext ¶

holds the text of the current token. It may be modified but not lengthened (you cannot append characters to the end).

If the special directive %array appears in the first section of the scanner description, then yytext is instead declared char yytext[YYLMAX], where YYLMAX is a macro definition that you can redefine in the first section if you don’t like the default value (generally 8KB). Using %array results in somewhat slower scanners, but the value of yytext becomes immune to calls to unput(), which potentially destroy its value when yytext is a character pointer. The opposite of %array is %pointer, which is the default.

You cannot use %array when generating C++ scanner classes (the ‘-+’ flag).

int yyleng ¶

holds the length of the current token.

FILE *yyin ¶

is the file which by default flex reads from. It may be redefined but doing so only makes sense before scanning begins or after an EOF has been encountered. Changing it in the midst of scanning will have unexpected results since flex buffers its input; use yyrestart() instead. Once scanning terminates because an end-of-file has been seen, you can assign yyin at the new input file and then call the scanner again to continue scanning.

void yyrestart( FILE *new_file ) ¶

may be called to point yyin at the new input file. The switch-over to the new file is immediate (any previously buffered-up input is lost). Note that calling yyrestart() with yyin as an argument thus throws away the current input buffer and continues scanning the same input file.

FILE *yyout ¶

is the file to which ECHO actions are done. It can be reassigned by the user.

YY_CURRENT_BUFFER ¶

returns a YY_BUFFER_STATE handle to the current buffer.

YY_START ¶

returns an integer value corresponding to the current start condition. You can subsequently use this value with BEGIN to return to that start condition.

15 Interfacing with Yacc ¶

One of the main uses of flex is as a companion to the yacc parser-generator. yacc parsers expect to call a routine named yylex() to find the next input token. The routine is supposed to return the type of the next token as well as putting any associated value in the global yylval. To use flex with yacc, one specifies the ‘-d’ option to yacc to instruct it to generate the file y.tab.h containing definitions of all the %tokens appearing in the yacc input. This file is then included in the flex scanner. For example, if one of the tokens is TOK_NUMBER, part of the scanner might look like:

    %{
    #include "y.tab.h"
    %}

    %%

    [0-9]+        yylval = atoi( yytext ); return TOK_NUMBER;

16 Scanner Options ¶

The various flex options are categorized by function in the following menu. If you want to lookup a particular option by name, See Index of Scanner Options.

Even though there are many scanner options, a typical scanner might only specify the following options:

%option   8bit reentrant bison-bridge
%option   warn nodefault
%option   yylineno
%option   outfile="scanner.c" header-file="scanner.h"

The first line specifies the general type of scanner we want. The second line specifies that we are being careful. The third line asks flex to track line numbers. The last line tells flex what to name the files. (The options can be specified in any order. We just divided them.)

flex also provides a mechanism for controlling options within the scanner specification itself, rather than from the flex command-line. This is done by including %option directives in the first section of the scanner specification. You can specify multiple options with a single %option directive, and multiple directives in the first section of your flex input file.

Most options are given simply as names, optionally preceded by the word ‘no’ (with no intervening whitespace) to negate their meaning. The names are the same as their long-option equivalents (but without the leading ‘--’ ).

flex scans your rule actions to determine whether you use the REJECT or yymore() features. The REJECT and yymore options are available to override its decision as to whether you use the options, either by setting them (e.g., %option reject) to indicate the feature is indeed used, or unsetting them to indicate it actually is not used (e.g., %option noyymore).

A number of options are available for lint purists who want to suppress the appearance of unneeded routines in the generated scanner. Each of the following, if unset (e.g., %option nounput), results in the corresponding routine not appearing in the generated scanner:

    input, unput
    yy_push_state, yy_pop_state, yy_top_state
    yy_scan_buffer, yy_scan_bytes, yy_scan_string

    yyget_extra, yyset_extra, yyget_leng, yyget_text,
    yyget_lineno, yyset_lineno, yyget_in, yyset_in,
    yyget_out, yyset_out, yyget_lval, yyset_lval,
    yyget_lloc, yyset_lloc, yyget_debug, yyset_debug

(though yy_push_state() and friends won’t appear anyway unless you use %option stack).

• Options for Specifying Filenames
• Options Affecting Scanner Behavior
• Code-Level And API Options
• Options for Scanner Speed and Size
• Debugging Options
• Miscellaneous Options

17 Performance Considerations ¶

The main design goal of flex is that it generate high-performance scanners. It has been optimized for dealing well with large sets of rules. Aside from the effects on scanner speed of the table compression ‘-C’ options outlined above, there are a number of options/actions which degrade performance. These are, from most expensive to least:

    REJECT
    arbitrary trailing context

    pattern sets that require backing up
    %option yylineno
    %array

    %option interactive
    %option always-interactive

    ^ beginning-of-line operator
    yymore()

with the first two all being quite expensive and the last two being quite cheap. Note also that unput() is implemented as a routine call that potentially does quite a bit of work, while yyless() is a quite-cheap macro. So if you are just putting back some excess text you scanned, use yyless().

REJECT should be avoided at all costs when performance is important. It is a particularly expensive option.

There is one case when %option yylineno can be expensive. That is when your patterns match long tokens that could possibly contain a newline character. There is no performance penalty for rules that can not possibly match newlines, since flex does not need to check them for newlines. In general, you should avoid rules such as [^f]+, which match very long tokens, including newlines, and may possibly match your entire file! A better approach is to separate [^f]+ into two rules:

%option yylineno
%%
    [^f\n]+
    \n+

The above scanner does not incur a performance penalty.

Getting rid of backing up is messy and often may be an enormous amount of work for a complicated scanner. In principal, one begins by using the ‘-b’ flag to generate a lex.backup file. For example, on the input:

    %%
    foo        return TOK_KEYWORD;
    foobar     return TOK_KEYWORD;

the file looks like:

    State #6 is non-accepting -
     associated rule line numbers:
           2       3
     out-transitions: [ o ]
     jam-transitions: EOF [ \001-n  p-\177 ]

    State #8 is non-accepting -
     associated rule line numbers:
           3
     out-transitions: [ a ]
     jam-transitions: EOF [ \001-`  b-\177 ]

    State #9 is non-accepting -
     associated rule line numbers:
           3
     out-transitions: [ r ]
     jam-transitions: EOF [ \001-q  s-\177 ]

    Compressed tables always back up.

The first few lines tell us that there’s a scanner state in which it can make a transition on an ’o’ but not on any other character, and that in that state the currently scanned text does not match any rule. The state occurs when trying to match the rules found at lines 2 and 3 in the input file. If the scanner is in that state and then reads something other than an ’o’, it will have to back up to find a rule which is matched. With a bit of headscratching one can see that this must be the state it’s in when it has seen ‘fo’. When this has happened, if anything other than another ‘o’ is seen, the scanner will have to back up to simply match the ‘f’ (by the default rule).

The comment regarding State #8 indicates there’s a problem when ‘foob’ has been scanned. Indeed, on any character other than an ‘a’, the scanner will have to back up to accept "foo". Similarly, the comment for State #9 concerns when ‘fooba’ has been scanned and an ‘r’ does not follow.

The final comment reminds us that there’s no point going to all the trouble of removing backing up from the rules unless we’re using ‘-Cf’ or ‘-CF’, since there’s no performance gain doing so with compressed scanners.

The way to remove the backing up is to add “error” rules:

    %%
    foo         return TOK_KEYWORD;
    foobar      return TOK_KEYWORD;

    fooba       |
    foob        |
    fo          {
                /* false alarm, not really a keyword */
                return TOK_ID;
                }

Eliminating backing up among a list of keywords can also be done using a “catch-all” rule:

    %%
    foo         return TOK_KEYWORD;
    foobar      return TOK_KEYWORD;

    [a-z]+      return TOK_ID;

This is usually the best solution when appropriate.

Backing up messages tend to cascade. With a complicated set of rules it’s not uncommon to get hundreds of messages. If one can decipher them, though, it often only takes a dozen or so rules to eliminate the backing up (though it’s easy to make a mistake and have an error rule accidentally match a valid token. A possible future flex feature will be to automatically add rules to eliminate backing up).

It’s important to keep in mind that you gain the benefits of eliminating backing up only if you eliminate every instance of backing up. Leaving just one means you gain nothing.

Variable trailing context (where both the leading and trailing parts do not have a fixed length) entails almost the same performance loss as REJECT (i.e., substantial). So when possible a rule like:

    %%
    mouse|rat/(cat|dog)   run();

is better written:

    %%
    mouse/cat|dog         run();
    rat/cat|dog           run();

or as

    %%
    mouse|rat/cat         run();
    mouse|rat/dog         run();

Note that here the special ’|’ action does not provide any savings, and can even make things worse (see Limitations).

Another area where the user can increase a scanner’s performance (and one that’s easier to implement) arises from the fact that the longer the tokens matched, the faster the scanner will run. This is because with long tokens the processing of most input characters takes place in the (short) inner scanning loop, and does not often have to go through the additional work of setting up the scanning environment (e.g., yytext) for the action. Recall the scanner for C comments:

    %x comment
    %%
            int line_num = 1;

    "/*"         BEGIN(comment);

    <comment>[^*\n]*
    <comment>"*"+[^*/\n]*
    <comment>\n             ++line_num;
    <comment>"*"+"/"        BEGIN(INITIAL);

This could be sped up by writing it as:

    %x comment
    %%
            int line_num = 1;

    "/*"         BEGIN(comment);

    <comment>[^*\n]*
    <comment>[^*\n]*\n      ++line_num;
    <comment>"*"+[^*/\n]*
    <comment>"*"+[^*/\n]*\n ++line_num;
    <comment>"*"+"/"        BEGIN(INITIAL);

Now instead of each newline requiring the processing of another action, recognizing the newlines is distributed over the other rules to keep the matched text as long as possible. Note that adding rules does not slow down the scanner! The speed of the scanner is independent of the number of rules or (modulo the considerations given at the beginning of this section) how complicated the rules are with regard to operators such as ‘*’ and ‘|’.

A final example in speeding up a scanner: suppose you want to scan through a file containing identifiers and keywords, one per line and with no other extraneous characters, and recognize all the keywords. A natural first approach is:

    %%
    asm      |
    auto     |
    break    |
    ... etc ...
    volatile |
    while    /* it's a keyword */

    .|\n     /* it's not a keyword */

To eliminate the back-tracking, introduce a catch-all rule:

    %%
    asm      |
    auto     |
    break    |
    ... etc ...
    volatile |
    while    /* it's a keyword */

    [a-z]+   |
    .|\n     /* it's not a keyword */

Now, if it’s guaranteed that there’s exactly one word per line, then we can reduce the total number of matches by a half by merging in the recognition of newlines with that of the other tokens:

    %%
    asm\n    |
    auto\n   |
    break\n  |
    ... etc ...
    volatile\n |
    while\n  /* it's a keyword */

    [a-z]+\n |
    .|\n     /* it's not a keyword */

One has to be careful here, as we have now reintroduced backing up into the scanner. In particular, while we know that there will never be any characters in the input stream other than letters or newlines, flex can’t figure this out, and it will plan for possibly needing to back up when it has scanned a token like ‘auto’ and then the next character is something other than a newline or a letter. Previously it would then just match the ‘auto’ rule and be done, but now it has no ‘auto’ rule, only a ‘auto\n’ rule. To eliminate the possibility of backing up, we could either duplicate all rules but without final newlines, or, since we never expect to encounter such an input and therefore don’t how it’s classified, we can introduce one more catch-all rule, this one which doesn’t include a newline:

    %%
    asm\n    |
    auto\n   |
    break\n  |
    ... etc ...
    volatile\n |
    while\n  /* it's a keyword */

    [a-z]+\n |
    [a-z]+   |
    .|\n     /* it's not a keyword */

Compiled with ‘-Cf’, this is about as fast as one can get a flex scanner to go for this particular problem.

A final note: flex is slow when matching NULs, particularly when a token contains multiple NULs. It’s best to write rules which match short amounts of text if it’s anticipated that the text will often include NULs.

Another final note regarding performance: as mentioned in How the Input Is Matched, dynamically resizing yytext to accommodate huge tokens is a slow process because it presently requires that the (huge) token be rescanned from the beginning. Thus if performance is vital, you should attempt to match “large” quantities of text but not “huge” quantities, where the cutoff between the two is at about 8K characters per token.

18 Generating C++ Scanners ¶

IMPORTANT: the present form of the scanning class is experimental and may change considerably between major releases.

flex provides two different ways to generate scanners for use with C++. The first way is to simply compile a scanner generated by flex using a C++ compiler instead of a C compiler. You should not encounter any compilation errors (see Reporting Bugs). You can then use C++ code in your rule actions instead of C code. Note that the default input source for your scanner remains yyin, and default echoing is still done to yyout. Both of these remain FILE * variables and not C++ streams.

You can also use flex to generate a C++ scanner class, using the ‘-+’ option (or, equivalently, %option c++), which is automatically specified if the name of the flex executable ends in a ’+’, such as flex++. When using this option, flex defaults to generating the scanner to the file lex.yy.cc instead of lex.yy.c. The generated scanner includes the header file FlexLexer.h, which defines the interface to two C++ classes.

The first class in FlexLexer.h, FlexLexer, provides an abstract base class defining the general scanner class interface. It provides the following member functions:

const char* YYText() ¶

returns the text of the most recently matched token, the equivalent of yytext.

int YYLeng() ¶

returns the length of the most recently matched token, the equivalent of yyleng.

int lineno() const ¶

returns the current input line number (see %option yylineno), or 1 if %option yylineno was not used.

void set_debug( int flag ) ¶

sets the debugging flag for the scanner, equivalent to assigning to yy_flex_debug (see Scanner Options). Note that you must build the scanner using %option debug to include debugging information in it.

int debug() const ¶

returns the current setting of the debugging flag.

Also provided are member functions equivalent to yy_switch_to_buffer(), yy_create_buffer() (though the first argument is an istream& object reference and not a FILE*), yy_flush_buffer(), yy_delete_buffer(), and yyrestart() (again, the first argument is a istream& object reference).

The second class defined in FlexLexer.h is yyFlexLexer, which is derived from FlexLexer. It defines the following additional member functions:

yyFlexLexer( istream* arg_yyin = 0, ostream* arg_yyout = 0 ) ¶

yyFlexLexer( istream& arg_yyin, ostream& arg_yyout )

constructs a yyFlexLexer object using the given streams for input and output. If not specified, the streams default to cin and cout, respectively. yyFlexLexer does not take ownership of its stream arguments. It’s up to the user to ensure the streams pointed to remain alive at least as long as the yyFlexLexer instance.

virtual int yylex() ¶

performs the same role is yylex() does for ordinary flex scanners: it scans the input stream, consuming tokens, until a rule’s action returns a value. If you derive a subclass S from yyFlexLexer and want to access the member functions and variables of S inside yylex(), then you need to use %option yyclass="S" to inform flex that you will be using that subclass instead of yyFlexLexer. In this case, rather than generating yyFlexLexer::yylex(), flex generates S::yylex() (and also generates a dummy yyFlexLexer::yylex() that calls yyFlexLexer::LexerError() if called).

virtual void switch_streams(istream* new_in = 0, ostream* new_out = 0) ¶

virtual void switch_streams(istream& new_in, ostream& new_out)

reassigns yyin to new_in (if non-null) and yyout to new_out (if non-null), deleting the previous input buffer if yyin is reassigned.

int yylex( istream* new_in, ostream* new_out = 0 )

int yylex( istream& new_in, ostream& new_out )

first switches the input streams via switch_streams( new_in, new_out ) and then returns the value of yylex().

In addition, yyFlexLexer defines the following protected virtual functions which you can redefine in derived classes to tailor the scanner:

virtual int LexerInput( char* buf, int max_size ) ¶

reads up to max_size characters into buf and returns the number of characters read. To indicate end-of-input, return 0 characters. Note that interactive scanners (see the ‘-B’ and ‘-I’ flags in Scanner Options) define the macro YY_INTERACTIVE. If you redefine LexerInput() and need to take different actions depending on whether or not the scanner might be scanning an interactive input source, you can test for the presence of this name via #ifdef statements.

virtual void LexerOutput( const char* buf, int size ) ¶

writes out size characters from the buffer buf, which, while NUL-terminated, may also contain internal NULs if the scanner’s rules can match text with NULs in them.

virtual void LexerError( const char* msg ) ¶

reports a fatal error message. The default version of this function writes the message to the stream cerr and exits.

Note that a yyFlexLexer object contains its entire scanning state. Thus you can use such objects to create reentrant scanners, but see also Reentrant C Scanners. You can instantiate multiple instances of the same yyFlexLexer class, and you can also combine multiple C++ scanner classes together in the same program using the ‘-P’ option discussed above.

Finally, note that the %array feature is not available to C++ scanner classes; you must use %pointer (the default).

Here is an example of a simple C++ scanner:

     // An example of using the flex C++ scanner class.

    %{
    #include <iostream>
    using namespace std;
    int mylineno = 0;
    %}

    %option noyywrap c++

    string  \"[^\n"]+\"

    ws      [ \t]+

    alpha   [A-Za-z]
    dig     [0-9]
    name    ({alpha}|{dig}|\$)({alpha}|{dig}|[_.\-/$])*
    num1    [-+]?{dig}+\.?([eE][-+]?{dig}+)?
    num2    [-+]?{dig}*\.{dig}+([eE][-+]?{dig}+)?
    number  {num1}|{num2}

    %%

    {ws}    /* skip blanks and tabs */

    "/*"    {
            int c;

            while((c = yyinput()) != 0)
                {
                if(c == '\n')
                    ++mylineno;

                else if(c == '*')
                    {
                    if((c = yyinput()) == '/')
                        break;
                    else
                        unput(c);
                    }
                }
            }

    {number}  cout << "number " << YYText() << '\n';

    \n        mylineno++;

    {name}    cout << "name " << YYText() << '\n';

    {string}  cout << "string " << YYText() << '\n';

    %%

	// This include is required if main() is an another source file.
	//#include <FlexLexer.h>

    int main( int /* argc */, char** /* argv */ )
    {
        FlexLexer* lexer = new yyFlexLexer;
        while(lexer->yylex() != 0)
            ;
        return 0;
    }

If you want to create multiple (different) lexer classes, you use the ‘-P’ flag (or the prefix= option) to rename each yyFlexLexer to some other ‘xxFlexLexer’. You then can include <FlexLexer.h> in your other sources once per lexer class, first renaming yyFlexLexer as follows:

    #undef yyFlexLexer
    #define yyFlexLexer xxFlexLexer
    #include <FlexLexer.h>

    #undef yyFlexLexer
    #define yyFlexLexer zzFlexLexer
    #include <FlexLexer.h>

if, for example, you used %option prefix="xx" for one of your scanners and %option prefix="zz" for the other.

19 Reentrant C Scanners ¶

flex has the ability to generate a reentrant C scanner. This is accomplished by specifying %option reentrant (‘-R’) The generated scanner is both portable, and safe to use in one or more separate threads of control. The most common use for reentrant scanners is from within multi-threaded applications. Any thread may create and execute a reentrant flex scanner without the need for synchronization with other threads.

• Uses for Reentrant Scanners
• An Overview of the Reentrant API
• Reentrant Example
• The Reentrant API in Detail
• Functions and Macros Available in Reentrant C Scanners

    /* Example of maintaining more than one active scanner. */

    do {
        int tok1, tok2;

        tok1 = yylex( scanner_1 );
        tok2 = yylex( scanner_2 );

        if( tok1 != tok2 )
            printf("Files are different.");

   } while ( tok1 && tok2 );

    /* Example of recursive invocation. */

    %option reentrant

    %%
    "eval(".+")"  {
                      yyscan_t scanner;
                      YY_BUFFER_STATE buf;

                      yylex_init( &scanner );
                      yytext[yyleng-1] = ' ';

                      buf = yy_scan_string( yytext + 5, scanner );
                      yylex( scanner );

                      yy_delete_buffer(buf,scanner);
                      yylex_destroy( scanner );
                 }
    ...
    %%

    /* This scanner prints "//" comments. */

    %option reentrant stack noyywrap
    %x COMMENT

    %%

    "//"                 yy_push_state( COMMENT, yyscanner);
    .|\n

    <COMMENT>\n          yy_pop_state( yyscanner );
    <COMMENT>[^\n]+      fprintf( yyout, "%s\n", yytext);

    %%

    int main ( int argc, char * argv[] )
    {
        yyscan_t scanner;

        yylex_init ( &scanner );
        yylex ( scanner );
        yylex_destroy ( scanner );
    return 0;
   }

    static void yy_push_state  ( int new_state , yyscan_t yyscanner ) ;
    static void yy_pop_state  ( yyscan_t yyscanner  ) ;

#define yytext (((struct yyguts_t*)yyscanner)->yytext_r)

    int yylex_init ( yyscan_t * ptr_yy_globals ) ;
    int yylex_init_extra ( YY_EXTRA_TYPE user_defined, yyscan_t * ptr_yy_globals ) ;
    int yylex ( yyscan_t yyscanner ) ;
    int yylex_destroy ( yyscan_t yyscanner ) ;

    int main ()
    {
        yyscan_t scanner;
        int tok;

        yylex_init(&scanner);

        while ((tok=yylex(scanner)) > 0)
            printf("tok=%d  yytext=%s\n", tok, yyget_text(scanner));

        yylex_destroy(scanner);
        return 0;
    }

    /* Set the last character of yytext to NULL. */
    void chop ( yyscan_t scanner )
    {
        int len = yyget_leng( scanner );
        yyget_text( scanner )[len - 1] = '\0';
    }

    %%
    .+\n    { chop( yyscanner );}

    #define YY_EXTRA_TYPE  void*
    YY_EXTRA_TYPE  yyget_extra ( yyscan_t scanner );
    void           yyset_extra ( YY_EXTRA_TYPE arbitrary_data , yyscan_t scanner);

    /* An example of overriding YY_EXTRA_TYPE. */
    %{
    #include <sys/stat.h>
    #include <unistd.h>
    %}
    %option reentrant
    %option extra-type="struct stat *"
    %%

    __filesize__     printf( "%ld", yyextra->st_size  );
    __lastmod__      printf( "%ld", yyextra->st_mtime );
    %%
    void scan_file( char* filename )
    {
        yyscan_t scanner;
        struct stat buf;
        FILE *in;

        in = fopen( filename, "r" );
        stat( filename, &buf );

        yylex_init_extra( buf, &scanner );
        yyset_in( in, scanner );
        yylex( scanner );
        yylex_destroy( scanner );

        fclose( in );
   }

     typedef void* yyscan_t;

    char *yyget_text ( yyscan_t scanner );
    int yyget_leng ( yyscan_t scanner );
    FILE *yyget_in ( yyscan_t scanner );
    FILE *yyget_out ( yyscan_t scanner );
    int yyget_lineno ( yyscan_t scanner );
    YY_EXTRA_TYPE yyget_extra ( yyscan_t scanner );
    int  yyget_debug ( yyscan_t scanner );

    void yyset_debug ( int flag, yyscan_t scanner );
    void yyset_in  ( FILE * in_str , yyscan_t scanner );
    void yyset_out  ( FILE * out_str , yyscan_t scanner );
    void yyset_lineno ( int line_number , yyscan_t scanner );
    void yyset_extra ( YY_EXTRA_TYPE user_defined , yyscan_t scanner );

    yytext
    yyleng
    yyin
    yyout
    yylineno
    yyextra
    yy_flex_debug

    YYSTYPE * yyget_lval ( yyscan_t scanner );
    void yyset_lval ( YYSTYPE * yylvalp , yyscan_t scanner );
    yylval

    YYLTYPE *yyget_lloc ( yyscan_t scanner );
    void yyset_lloc ( YYLTYPE * yyllocp , yyscan_t scanner );
    yylloc

20 Incompatibilities with Lex and Posix ¶

flex is a rewrite of the AT&T Unix lex tool (the two implementations do not share any code, though), with some extensions and incompatibilities, both of which are of concern to those who wish to write scanners acceptable to both implementations. flex is fully compliant with the POSIX lex specification, except that when using %pointer (the default), a call to unput() destroys the contents of yytext, which is counter to the POSIX specification. In this section we discuss all of the known areas of incompatibility between flex, AT&T lex, and the POSIX specification. flex’s ‘-l’ option turns on maximum compatibility with the original AT&T lex implementation, at the cost of a major loss in the generated scanner’s performance. We note below which incompatibilities can be overcome using the ‘-l’ option. flex is fully compatible with lex with the following exceptions:

• The undocumented lex scanner internal variable yylineno is not supported unless ‘-l’ or %option yylineno is used.
• yylineno should be maintained on a per-buffer basis, rather than a per-scanner (single global variable) basis.
• yylineno is not part of the POSIX specification.
• The input() routine is not redefinable, though it may be called to read characters following whatever has been matched by a rule. If input() encounters an end-of-file the normal yywrap() processing is done. A “real” end-of-file is returned by input() as EOF.
• Input is instead controlled by defining the YY_INPUT() macro.
• The flex restriction that input() cannot be redefined is in accordance with the POSIX specification, which simply does not specify any way of controlling the scanner’s input other than by making an initial assignment to yyin.
• The unput() routine is not redefinable. This restriction is in accordance with POSIX.
• flex scanners are not as reentrant as lex scanners. In particular, if you have an interactive scanner and an interrupt handler which long-jumps out of the scanner, and the scanner is subsequently called again, you may get the following message:

      fatal flex scanner internal error--end of buffer missed
  

  To reenter the scanner, first use:

      yyrestart( yyin );
  

  Note that this call will throw away any buffered input; usually this isn’t a problem with an interactive scanner. See Reentrant C Scanners, for flex’s reentrant API.

• Also note that flex C++ scanner classes are reentrant, so if using C++ is an option for you, you should use them instead. See Generating C++ Scanners, and Reentrant C Scanners for details.
• output() is not supported. Output from the ECHO macro is done to the file-pointer yyout (default stdout).
• output() is not part of the POSIX specification.
• lex does not support exclusive start conditions (%x), though they are in the POSIX specification.
• When definitions are expanded, flex encloses them in parentheses. With lex, the following:

      NAME    [A-Z][A-Z0-9]*
      %%
      foo{NAME}?      printf( "Found it\n" );
      %%
  

  will not match the string ‘foo’ because when the macro is expanded the rule is equivalent to ‘foo[A-Z][A-Z0-9]*?’ and the precedence is such that the ‘?’ is associated with ‘[A-Z0-9]*’. With flex, the rule will be expanded to ‘foo([A-Z][A-Z0-9]*)?’ and so the string ‘foo’ will match.

• Note that if the definition begins with ‘^’ or ends with ‘$’ then it is not expanded with parentheses, to allow these operators to appear in definitions without losing their special meanings. But the ‘<s>’, ‘/’, and <<EOF>> operators cannot be used in a flex definition.
• Using ‘-l’ results in the lex behavior of no parentheses around the definition.
• The POSIX specification is that the definition be enclosed in parentheses.
• Some implementations of lex allow a rule’s action to begin on a separate line, if the rule’s pattern has trailing whitespace:

      %%
      foo|bar<space here>
        { foobar_action();}
  

  flex does not support this feature.

• The lex %r (generate a Ratfor scanner) option is not supported. It is not part of the POSIX specification.
• After a call to unput(), yytext is undefined until the next token is matched, unless the scanner was built using %array. This is not the case with lex or the POSIX specification. The ‘-l’ option does away with this incompatibility.
• The precedence of the ‘{,}’ (numeric range) operator is different. The AT&T and POSIX specifications of lex interpret ‘abc{1,3}’ as match one, two, or three occurrences of ‘abc’”, whereas flex interprets it as “match ‘ab’ followed by one, two, or three occurrences of ‘c’”. The ‘-l’ and ‘--posix’ options do away with this incompatibility.
• The precedence of the ‘^’ operator is different. lex interprets ‘^foo|bar’ as “match either ’foo’ at the beginning of a line, or ’bar’ anywhere”, whereas flex interprets it as “match either ‘foo’ or ‘bar’ if they come at the beginning of a line”. The latter is in agreement with the POSIX specification.
• The special table-size declarations such as %a supported by lex are not required by flex scanners.. flex ignores them.
• The name FLEX_SCANNER is #define’d so scanners may be written for use with either flex or lex. Scanners also include YY_FLEX_MAJOR_VERSION, YY_FLEX_MINOR_VERSION and YY_FLEX_SUBMINOR_VERSION indicating which version of flex generated the scanner. For example, for the 2.5.22 release, these defines would be 2, 5 and 22 respectively. If the version of flex being used is a beta version, then the symbol FLEX_BETA is defined.
• The symbols ‘[[’ and ‘]]’ in the code sections of the input may conflict with the m4 delimiters. See M4 Dependency.

The following flex features are not included in lex or the POSIX specification:

• C++ scanners
• %option
• start condition scopes
• start condition stacks
• interactive/non-interactive scanners
• yy_scan_string() and friends
• yyterminate()
• yy_set_interactive()
• yy_set_bol()
• YY_AT_BOL() <<EOF>>
• <*>
• YY_DECL
• YY_START
• YY_USER_ACTION
• YY_USER_INIT
• #line directives
• %{}’s around actions
• reentrant C API
• multiple actions on a line
• almost all of the flex command-line options

The feature “multiple actions on a line” refers to the fact that with flex you can put multiple actions on the same line, separated with semi-colons, while with lex, the following:

    foo    handle_foo(); ++num_foos_seen;

is (rather surprisingly) truncated to

    foo    handle_foo();

flex does not truncate the action. Actions that are not enclosed in braces are simply terminated at the end of the line.

21 Memory Management ¶

This chapter describes how flex handles dynamic memory, and how you can override the default behavior.

• The Default Memory Management
• Overriding The Default Memory Management
• A Note About yytext And Memory

%{
#include "some_allocator.h"
%}

/* Suppress the default implementations. */
%option noyyalloc noyyrealloc noyyfree
%option reentrant

/* Initialize the allocator. */
%{
#define YY_EXTRA_TYPE  struct allocator*
#define YY_USER_INIT  yyextra = allocator_create();
%}

%%
.|\n   ;
%%

/* Provide our own implementations. */
void * yyalloc (size_t bytes, void* yyscanner) {
    return allocator_alloc (yyextra, bytes);
}

void * yyrealloc (void * ptr, size_t bytes, void* yyscanner) {
    return allocator_realloc (yyextra, bytes);
}

void yyfree (void * ptr, void * yyscanner) {      
    /* Do nothing -- we leave it to the garbage collector. */
}

22 Serialized Tables ¶

A flex scanner has the ability to save the DFA tables to a file, and load them at runtime when needed. The motivation for this feature is to reduce the runtime memory footprint. Traditionally, these tables have been compiled into the scanner as C arrays, and are sometimes quite large. Since the tables are compiled into the scanner, the memory used by the tables can never be freed. This is a waste of memory, especially if an application uses several scanners, but none of them at the same time.

The serialization feature allows the tables to be loaded at runtime, before scanning begins. The tables may be discarded when scanning is finished.

• Creating Serialized Tables
• Loading and Unloading Serialized Tables
• Tables File Format

    %option tables-file=FILE
or
    --tables-file=FILE

$ flex --tables-file --prefix=cpp cpp.l
$ flex --tables-file --prefix=c   c.l
$ cat lex.cpp.tables lex.c.tables  >  all.tables

                 TABLE SET 1
                +-------------------------------+
        Header  | uint32          th_magic;     |
                | uint32          th_hsize;     |
                | uint32          th_ssize;     |
                | uint16          th_flags;     |
                | char            th_version[]; |
                | char            th_name[];    |
                | uint8           th_pad64[];   |
                +-------------------------------+
        Table 1 | uint16          td_id;        |
                | uint16          td_flags;     |
                | uint32          td_hilen;     |
                | uint32          td_lolen;     |
                | void            td_data[];    |
                | uint8           td_pad64[];   |
                +-------------------------------+
        Table 2 |                               |
           .    .                               .
           .    .                               .
           .    .                               .
           .    .                               .
        Table n |                               |
                +-------------------------------+
                 TABLE SET 2
                      .
                      .
                      .
                 TABLE SET N

23 Diagnostics ¶

The following is a list of flex diagnostic messages:

• ‘warning, rule cannot be matched’ indicates that the given rule cannot be matched because it follows other rules that will always match the same text as it. For example, in the following ‘foo’ cannot be matched because it comes after an identifier “catch-all” rule:

      [a-z]+    got_identifier();
      foo       got_foo();
  

  Using REJECT in a scanner suppresses this warning.

• ‘warning, -s option given but default rule can be matched’ means that it is possible (perhaps only in a particular start condition) that the default rule (match any single character) is the only one that will match a particular input. Since ‘-s’ was given, presumably this is not intended.
• reject_used_but_not_detected undefined or yymore_used_but_not_detected undefined. These errors can occur at compile time. They indicate that the scanner uses REJECT or yymore() but that flex failed to notice the fact, meaning that flex scanned the first two sections looking for occurrences of these actions and failed to find any, but somehow you snuck some in (via a #include file, for example). Use %option reject or %option yymore to indicate to flex that you really do use these features.
• ‘flex scanner jammed’. a scanner compiled with ‘-s’ has encountered an input string which wasn’t matched by any of its rules. This error can also occur due to internal problems.
• ‘token too large, exceeds YYLMAX’. your scanner uses %array and one of its rules matched a string longer than the YYLMAX constant (8K bytes by default). You can increase the value by #define’ing YYLMAX in the definitions section of your flex input.
• ‘scanner requires -8 flag to use the character 'x'’. Your scanner specification includes recognizing the 8-bit character ‘'x'’ and you did not specify the -8 flag, and your scanner defaulted to 7-bit because you used the ‘-Cf’ or ‘-CF’ table compression options. See the discussion of the ‘-7’ flag, Scanner Options, for details.
• ‘flex scanner push-back overflow’. you used unput() to push back so much text that the scanner’s buffer could not hold both the pushed-back text and the current token in yytext. Ideally the scanner should dynamically resize the buffer in this case, but at present it does not.
• ‘input buffer overflow, can't enlarge buffer because scanner uses REJECT’. the scanner was working on matching an extremely large token and needed to expand the input buffer. This doesn’t work with scanners that use REJECT.
• ‘fatal flex scanner internal error--end of buffer missed’. This can occur in a scanner which is reentered after a long-jump has jumped out (or over) the scanner’s activation frame. Before reentering the scanner, use:

      yyrestart( yyin );
  

  or, as noted above, switch to using the C++ scanner class.

• ‘too many start conditions in <> construct!’ you listed more start conditions in a <> construct than exist (so you must have listed at least one of them twice).

24 Limitations ¶

Some trailing context patterns cannot be properly matched and generate warning messages (‘dangerous trailing context’). These are patterns where the ending of the first part of the rule matches the beginning of the second part, such as ‘zx*/xy*’, where the ’x*’ matches the ’x’ at the beginning of the trailing context. (Note that the POSIX draft states that the text matched by such patterns is undefined.) For some trailing context rules, parts which are actually fixed-length are not recognized as such, leading to the abovementioned performance loss. In particular, parts using ‘|’ or ‘{n}’ (such as ‘foo{3}’) are always considered variable-length. Combining trailing context with the special ‘|’ action can result in fixed trailing context being turned into the more expensive variable trailing context. For example, in the following:

    %%
    abc      |
    xyz/def

Use of unput() invalidates yytext and yyleng, unless the %array directive or the ‘-l’ option has been used. Pattern-matching of NULs is substantially slower than matching other characters. Dynamic resizing of the input buffer is slow, as it entails rescanning all the text matched so far by the current (generally huge) token. Due to both buffering of input and read-ahead, you cannot intermix calls to <stdio.h> routines, such as, getchar(), with flex rules and expect it to work. Call input() instead. The total table entries listed by the ‘-v’ flag excludes the number of table entries needed to determine what rule has been matched. The number of entries is equal to the number of DFA states if the scanner does not use REJECT, and somewhat greater than the number of states if it does. REJECT cannot be used with the ‘-f’ or ‘-F’ options.

The flex internal algorithms need documentation.

25 Additional Reading ¶

You may wish to read more about the following programs:

• lex
• yacc
• sed
• awk

The following books may contain material of interest:

John Levine, Tony Mason, and Doug Brown, Lex & Yacc, O’Reilly and Associates. Be sure to get the 2nd edition.

M. E. Lesk and E. Schmidt, LEX – Lexical Analyzer Generator

Alfred Aho, Ravi Sethi and Jeffrey Ullman, Compilers: Principles, Techniques and Tools, Addison-Wesley (1986). Describes the pattern-matching techniques used by flex (deterministic finite automata).