Master Menu


            An Interactive Plotting Program
             Thomas Williams & Colin Kelley
                Version 5.0 organized by
       Ethan A Merritt with help from many others

   Copyright (C) 1986 - 1993, 1998, 2004   Thomas Williams, Colin Kelley
           Copyright (C) 2004 - 2012  various authors

       Mailing list for comments:
     Mailing list for bug reports:

         This manual was originally prepared by Dick Crawford
                   Version 5.0 - March 2014

Major contributors (alphabetic order):

Table of Contents

1 gnuplot

1.2 Introduction

‘Gnuplot‘ is a portable command-line driven graphing utility for Linux, OS/2, MS Windows, OSX, VMS, and many other platforms. The source code is copyrighted but freely distributed (i.e., you don’t have to pay for it). It was originally created to allow scientists and students to visualize mathematical functions and data interactively, but has grown to support many non-interactive uses such as web scripting. It is also used as a plotting engine by third-party applications like Octave. Gnuplot has been supported and under active development since 1986.

Gnuplot supports many types of plots in either 2D and 3D. It can draw using lines, points, boxes, contours, vector fields, surfaces, and various associated text. It also supports various specialized plot types.

Gnuplot supports many different types of output: interactive screen terminals (with mouse and hotkey input), direct output to pen plotters or modern printers, and output to many file formats (eps, emf, fig, jpeg, LaTeX, pdf, png, postscript, ...). Gnuplot is easily extensible to include new output modes. Recent additions include interactive terminals based on wxWidgets (usable on multiple platforms), and Qt. Mouseable plots embedded in web pages can be generated using the svg or HTML5 canvas terminal drivers.

The command language of ‘gnuplot‘ is case sensitive, i.e. commands and function names written in lowercase are not the same as those written in capitals. All command names may be abbreviated as long as the abbreviation is not ambiguous. Any number of commands may appear on a line, separated by semicolons (;). Strings may be set off by either single or double quotes, although there are some subtle differences. See ‘syntax‘ and ‘quotes‘ for more details. Example:

      set title "My First Plot";  plot 'data';  print "all done!"

Commands may extend over several input lines by ending each line but the last with a backslash (\). The backslash must be the _last_ character on each line. The effect is as if the backslash and newline were not there. That is, no white space is implied, nor is a comment terminated. Therefore, commenting out a continued line comments out the entire command (see ‘comments‘). But note that if an error occurs somewhere on a multi-line command, the parser may not be able to locate precisely where the error is and in that case will not necessarily point to the correct line.

In this document, curly braces ({}) denote optional arguments and a vertical bar (|) separates mutually exclusive choices. ‘Gnuplot‘ keywords or help topics are indicated by backquotes or ‘boldface‘ (where available). Angle brackets (<>) are used to mark replaceable tokens. In many cases, a default value of the token will be taken for optional arguments if the token is omitted, but these cases are not always denoted with braces around the angle brackets.

For built-in help on any topic, type help followed by the name of the topic or ‘help ?‘ to get a menu of available topics.

A large set of demo plots is available on the web page When run from command line, gnuplot is invoked using the syntax

      gnuplot {OPTIONS} file1 file2 ...

where file1, file2, etc. are input file as in the ‘load‘ command. On X11-based systems, you can use

      gnuplot {X11OPTIONS} {OPTIONS} file1 file2 ...

see your X11 documentation and ‘x11‘ in this document.

Options interpreted by gnuplot may come anywhere on the line. Files are executed in the order specified, as are commands supplied by the -e option, for example

      gnuplot   -e "reset"

The special filename "-" is used to force reading from stdin. ‘Gnuplot‘ exits after the last file is processed. If no load files are named, ‘Gnuplot‘ takes interactive input from stdin. See help ‘batch/interactive‘ for more details. The options specific to gnuplot can be listed by typing

      gnuplot --help

See ‘command-line-options‘ for more details.

In sessions with an interactive plot window you can hit ’h’ anywhere on the plot for help about ‘hotkeys‘ and ‘mousing‘ features. Section ‘seeking-assistance‘ will help you to find further information, help and FAQ.

1.3 Seeking-assistance

The canonical gnuplot home page can be found at

Before seeking help, please check file FAQ.pdf or the above website for a FAQ (Frequently Asked Questions) list.

Another resource for help with specific plotting problems (not bugs) is

Bug reports and feature requests should be uploaded to the trackers at

Please check previous reports to see if the bug you want to report has already been fixed in a newer version.

When reporting a bug or posting a question, please include full details of the gnuplot version, the terminal type, and the operating system. A short self-contained script demonstrating the problem is very helpful.

Instructions for subscribing to gnuplot mailing lists may be found via the gnuplot development website on SourceForge

Please note that before you write to any of the gnuplot mailing lists you must first subscribe to the list. This helps reduce the amount of spam.

The address for mailing to list members is:

A mailing list for those interested in the development version of gnuplot is:

1.4 New features

1.4.1 Features introduced in version 5.4

These sections list new commands, plot styles, and other features introduced in version 5.4. Support for 64-bit integer arithmetic

  • All evaluation of expressions and functions uses 64-integer arithmetic if supported by the platform.
  • Integer overflow is detected and handled according to user preference. See overflow. Voxel grids

Gnuplot now supports operations based on 3D grids of voxel data.

  • ‘set vgrid $gridname size N‘ creates an NxNxN grid of voxels.
  • ‘set vxrange [vxmin:vxmax]‘ together with vyrange and vzrange define which region of space the grid occupies. This may or may not be identical to the xyz range of the plot.
  • ‘voxel(x,y,z)‘ can be used in expressions to read or write an individual voxel.
  • ‘vfill DATA_SOURCE using x:y:z:radius:(<expression>)‘ acts analogously to a plot command except that instead of plotting it increments voxels near each point in the input data.
  • ‘vclear $gridname‘ resets an existing voxel grid to contain all zero values.
  • the current contents of one or more voxel grids can be referenced by ‘splot‘ commands to assign colors or other properties of plot elements by using the ‘voxel‘ function in using specifiers. See demo ‘voxel.dem‘.
  • voxel grids can also be plotted by name in ‘splot‘ commands with plot styles dots, ‘points‘, or isosurface. See demo ‘vplot.dem‘. New plot styles and style options

  • 3D plot style polygons reads polygon faces from a data file. This can be used to create a surface or to construct a solid object. See polygons.
  • ‘splot $voxelgrid with {dots|points}‘ marks all voxels whose value is above a requested threshold level.
  • isosurface creates a tessellated 3D surface enclosing voxels above a requested threshold level. See isosurface.
  • Voxel grid values can be referenced in the ‘using‘ specifiers for 3D plots.
  • spiderplot selects a new plotting mode allowing creation of spider plots (also known as radar charts). These are essentially parallel axis plots where the axes are arranged radially rather than vertically. See spiderplot, spiderplot, paxis.
  • Plot style circles can be used in 3D plots.
  • Plot style boxes can be used in 3D plots.
  • 2D plot style ‘with arrows‘ is identical to vectors except that each arrow is specified using x:y:length:angle rather than x:y:xdelta:ydelta
  • splot FOO with pm3d fillcolor <colorspec>
  • pm3d surfaces can have individual fillstyle and separate top/bottom fillcolor
  • pm3d option ‘noclipcb‘ causes quadrangles with palette color outside cbrange to be skipped rather than being drawn with color clipped to cbmin or cbmax.
  • Customized contour line types. See cntrparam. New data pre-processing filters

  • ‘smooth zsort‘ sorts 2D points on values in a 3rd column. See ‘smooth zsort‘. New commands and command options

  • Voxel grid commands. See vgrid, vxrange, vclear, vfill, and ‘voxel‘.
  • New options for showing the xy xz and yz planes in 3D plots. See walls, ‘set grid vertical‘.
  • ‘set table separator {tab|comma|"char"}‘ can be used to create csv files. See table.
  • New options ‘set view projection {xy|xz|yz}‘ adjust view angles, axis tic and label placement to generate a 2D projection of a 3D splot. ‘set view projection xy‘ is equivalent to ‘set view map‘.
  • ‘set rgbmax <value>‘ controls interpretation of input RGB values.
  • Array size can be implicit if an initializer is present, e.g. ‘Array A = [1,2,3]‘.
  • Optional radial clipping of line segments in polar mode. See ‘set clip‘.
  • Extra lines to customize the key can be added by substituting ‘keyentry‘ in place of a filename or function in ‘plot‘ and ‘splot‘ commands. This produces a line in the key without generating a corresponding plot. See ‘keyentry‘.
  • User-specified translation of mouse coordinates (EXPERIMENTAL). See map_projection demo.
  • columnheaders causes first line of input to be read as strings rather than as data values. Equivalent to ‘set key autotitle columnheader‘ except that it does not affect generation of key entries. If this option is in effect the ‘stats‘ command will generate an array of strings containing the column headers found.
  • You can define multiple textbox styles. See ‘set style textbox‘. New terminals and terminal options

  • The ‘pcl5‘ terminal has been extended to support PCL5e/PCL5c printers and many modern gnuplot features.
  • The ‘pstricks‘ terminal has been extended to support many modern gnuplot features including RGB colors and transparency, filled polygons, and boxes.
  • New terminal ‘pict2e‘ to use the LaTeX2e pict2e environment. It directly supersedes older terminals ‘latex‘, ‘emtex‘, ‘eepic‘, and ‘tpic‘, which are no longer built by default.
  • The ‘texdraw‘ terminal has been extended to support text at arbitrary angles, variable line width, v5 dashed lines, and filled boxes and polygons. It can now be used with plain TeX, too.
  • The previously experimental Direct2D variant of the ‘windows‘ terminal replaces the GDI and GDI+ variants. It now supports printing using D2D and color fonts.
  • The ‘pm‘ OS/2 terminal has been modernized to support e.g. uft8, bold and italic text, and dashed lines. (Since 5.2.7).
  • The ‘dospc‘ and ‘svga‘ DOS terminals have been modernized and now support interactive keyboard and mouse (svga only) input. Pixmaps as objects

  • pixmap allows import of an image in standard format (png jpeg gif) as a pixmap that can be positioned anywhere in a plot or on the page. Unlike plotting ‘with image‘, pixmap objects retain their original aspect ratio and size independent of axis scaling or rotation. See pixmap. Week-date time formats

The Covid-19 pandemic of 2020/2021 generated increased interest in plotting epidemiological data, which is often tabulated using a "week date" reporting convention. This revealed deficiencies with gnuplot support for this convention, including errors in time formats %W and %U. These formats worked incorrectly prior to version 5.4.2.

  • Time specifier format %W has been brought into accord with the ISO 8601 week date standard.
  • Time specifier format %U has been brought into accord with the CDC/MMWR week date standard.
  • New function ‘tm_week(time, std)‘ returns ISO or CDC standard week of year.
  • New function ‘weekdate_iso(year, week, day)‘ converts ISO standard week date to calendar time.
  • New function ‘weekdate_cdc(year, week, day)‘ converts CDC standard week date to calendar time. Other new features

  • Enhanced text mode accepts \U+xxxx (xxxx is a 4 or 5 character hexadecimal) as representing a Unicode code point that is converted to the corresponding UTF-8 byte sequence on output.
  • The character sequence $# in a ‘using‘ specifier evaluates to the total number of columns available in the current line of data. For example "plot FOO using 0:(column($# - 1))" plots the last-but-one field of each row.
  • Time/date input recognizes format %p to handle am/pm field
  • plot titles are evaluated *after* plotting, rather than before. This allows the title to reference quantities calculated while plotting.
  • Built-in modified Bessel functions (besi0 besi1 besin)
  • Built-in order N Bessel functions of the 1st and 2nd kind (besjn besyn)
  • (5.4.2) in "using" context, $# means "number of columns in current data line"
  • (5.4.2) "plot with fillsteps {above|below y=<value>}" analogous to filledcurves
  • (5.4.3) "nogrid" flag allows splot components to opt out of dgrid3d processing
  • (5.4.3) "set style histogram nokeyseparators" (see newhistogram)
  • (5.4.5) column(0) returns the linear ordering of nonuniform matrix elements.
            Thus for element A[i,j] in an MxN matrix,
            column(0) / M  gives the row index i
            column(0) % M  gives the column index j
  • (5.4.5) Component boxes in "plot with histograms" can be colored according to
            a separate column of category/color information. See `lc variable`.
  • (5.4.5) Fix a regression in version 5.4.4 that caused string->int promotion
            to incorrectly assume a leading 0 implies an octal number
  • (5.4.5) The position of the key box can be manually tweaked by giving an
            offset added to whatever position the program would otherwise use.
            See `set key offset`.
  • (5.4.6) New ‘set key‘ options force exact number of columns, exact key width. Changes

  • ‘pm3d filled area quadrangles‘ are clipped smoothly to current zrange. This affects pm3d surfaces and also the faces of 3D boxes, polygons, etc. ‘set pm3d border retrace‘ paints over potential antialiasing glitches between adjacent pm3d quadrangles by drawing a same-color border.
  • Revised syntax for plot style ’with parallelaxes’. See ‘parallel‘. The histogram, parallelaxis, and spiderplot styles now use similar syntax that can iterate over plot elements:
        `plot for [column=1:N] DATA using column`
  • Sampling generated by pseudofile ’+’ is affected by trange.
  • Offsets from offsets are applied only to autoscaled axes. The documentation has always said this, but it was not applied consistently.
  • Imaginary values returned by the using specifier of a 2D plot are treated as undefined values (NaN) rather than as real(value). This was always true for function plots and 3D data plots. E.g. the following two plots are equivalent. plot [-1:1] sqrt(x); plot [-1:1] ’+’ using 1:(sqrt($1)
  • The fontpath command is deprecated. The search path for fonts to be embedded in output from the postscript terminal has been revised.

1.4.2 Features introduced in version 5.2 New plot styles and style options

  • 3D plot style ‘with zerrorfill‘. See ‘zerrorfill‘, ‘fenceplots‘ and zerror demo.
  • Beeswarm plots. See jitter, ‘beeswarm‘ and beeswarm plot demo
  • The symbol used for individual points in a plot can be controlled by data values (see ‘pointtype variable‘) New data pre-processing filters

  • Normalized frequency of occurrence in a data set (see ‘smooth fnormal‘)
  • Automated binning of data (see bins) Polar mode improvements and extensions

  • Polar coordinates may be used in label, arrow, and object definitions
  • ‘set [m]ttics‘ places ticmarks and labels on the perimeter of a polar plot. See polar axis and ticlabels demo
  • rlabel places a label above the r axis
  • Inverted rrange (i.e. set rrange [90:0]) allows use of celestial horizontal coordinates. See solar path demo
  • ‘set border polar‘ draws a solid line around the perimeter of a polar plot
  • theta controls the position of theta = 0 around the perimeter of a polar plot and the sense (clockwise or anti-clockwise) of increasing theta Nonlinear coordinates systems

  • Any plot axis can be assigned a pair of functions, possibly nonlinear, that describe the forward and reverse mapping to a linear range (see nonlinear) Nonlinear x/y axis demo
  • The familiar command logscale has been reimplemented as a special case nonlinear axis where the paired functions are log(x) and exp(x). New commands and command options

  • Inside the bracketed clause of an iteration, ‘continue‘ jumps immediately to the next iteration, ‘break‘ immediately exits from the iteration
  • ‘toggle {<plotno> | "plottitle" | all}"‘ interactively enables or disables display of one element of the current plot (see toggle)
  • fit replaces deprecated command update
  • ‘set table "" append‘ will append subsequent tabulated plots to an existing text file rather replacing its contents
  • lighting describes a lighting model with specular highlighting (see lighting)
  • minussign tells gnuplot to use a special symbol in the current encoding to replace the ascii character ’-’ in negative numbers
  • micro tells gnuplot to use a special symbol in the current encoding to replace the ascii character ’u’ for the scientific notation prefix "micro" The special typographic symbols for micro and minussign are used only in axis tic labels and strings explicitly created with gprintf(). The byte sequence used to represent these characters depends on the current encoding. New data type "array"

  • This gnuplot version introduces a new data type ‘array name[size]‘. An array must be declared before use. Each array element A[i] may be a string, an integer, a real number, or a complex value. A single array may contain elements with different types. The cardinality operator |A| returns the size of array A. See ‘arrays‘. New terminals and terminal options

  • See ‘sixelgd‘ for description of a new terminal that supports interleaving plots with the command lines that generated them if gnuplot is run inside a vt340-compatible terminal emulator
  • The ‘domterm‘ terminal supports interleaving plots with the command lines that generated them if gnuplot is run inside an svg-aware terminal emulator
  • The ‘windows‘ terminal supports saving the current graph to a bitmap file
  • The ‘windows‘ terminal graph window can be docked to the wgnuplot text window
  • New (experimental) Direct2D/DirectWrite backend for the ‘windows‘ terminal
  • The ‘wxt‘ terminal supports exporting to an EMF file or printer on Windows
  • The ‘dumb‘ terminal supports ANSI colors for lines and fill area
  • The ‘tkcanvas‘ terminal has been rewritten to support many more modern gnuplot features, as well as new languages. (Since 5.0.3) Other new features

  • An additional rotation angle azimuth affects the orientation of 3D plots. This can be set from the command line (see azimuth) or by dragging with the right mouse button. Hotkey ‘z‘ resets azimuth to 0.
  • gnuplot running under Windows can interpret Unicode (BMP) input scripts by converting them to the current encoding from encoding, including UTF-8
  • Textboxes can be assigned a border color and fill color (see ‘set style textbox‘)
  • Customized plot legends (see title, ‘set key‘, ‘multiple keys‘)
  • A sampling range specifier for plotting with pseudofile ’+’ can include a sampling interval. For example: plot sample [t=0:100:10] ’+’ using (t):(1):(label[t]) with labels
  • Pseudo-file ’++’ generates samples on the u and v axes, rather than x and y. This allows placement of multiple parametric surfaces in 3D that occupy distinct regions of Cartesian space. See ‘sampling.dem‘.
  • new formats descriptors tH tM tS handle relative times (interval lengths). See ‘time_specifiers‘.
  • ^R initiates a reverse-search through the history for the built-in readline which is used on Windows, too, see ‘command-line-editing‘.
  • Revised printing support on Windows using ‘set output "PRN"‘, see ‘windows printing‘.

1.4.3 Features introduced in version 5.0

  • The dot-dash pattern of a line can now be specified independent of other line properties. See dashtype, dashtype, ‘set linetype‘
  • The default sequence of colors used for successive elements in a plot is more easily distinguished by users with color-vision defects. The color sequence is under user control (see colorsequence). This mechanism can also be used to generate monochrome plots (see monochrome). In previous gnuplot versions monochrome could only be selected when changing the current terminal via terminal.
  • New plot styles parallelaxes, table, and labeled contours.
  • New data pre-processing filter for monotonic cubic splines (see ‘smooth mcsplines‘)
  • Text markup now supports bold and italic font settings in addition to subscript, superscript, font size and other previously available properties. Enhanced text mode is now enabled by default. See ‘enhanced text‘. Text elements can be enclosed in a box (see ‘set style textbox‘).
  • Interactive terminals support hypertext labels that only appear when the mouse hovers over the label’s anchor point.
  • New coordinate system (Degrees, Minutes, Seconds). See geographic.
  • The default format for axis labels is "% h" ("$%h$" for LaTeX terminals). This format is like the C standard format %g except that the exponential term, if present, is written using a superscript. E.g. 1.2 x 10^5 rather than 1.2E05.
  • Command scripts may place in-line data in a named data block for repeated plotting. See ‘inline data‘.
  • Support for 32-bit Alpha channel + RGB color #AARRGGBB. See colorspec.
  • Support for HSV color space via a translation function hsv2rgb(H,S,V).
  • Secondary axes (x2, y2) may be locked to the primary axis via a mapping function. In the simplest case this guarantees that the primary and secondary axis ranges are identical. In the general case it allows you to define a non-linear axis, something that previously was possible only for log scaling. See link.
  • Each function in a plot command may optionally be preceded by a sampling range. This does not affect the overall range of the plot, only the range over which this function is sampled. See ‘plot‘ and ‘piecewise.dem‘.
  • If the external library libcerf is available, it is used to provide complex math routines cerf, cdawson, erfi, faddeeva, and the Voigt profile VP(x,sigma,gamma).
  • The import command attaches a user-defined function name to a function provided by an external shared object (support is operating-system dependent). A template header and example source and make files for creating a suitable external shared object are provided in the demo collection.
  • Previous commands in the history list of an interactive session can be reexecuted by number. For example, ‘history !5‘ will reexecute the command numbered 5 in the ‘history‘ list.
  • Bit-shift operators >> and <<.
  • Shell invocation of gnuplot can pass parameters to a gnuplot script. gnuplot -c ARG1 ARG2 ARG3 ...

1.5 Differences between versions 4 and 5

Some changes introduced in version 5 may cause certain scripts written for earlier versions of gnuplot to behave differently.

* Revised handling of input data containing NaN, inconsistent number of data columns, or other unexpected content. See Note under ‘missing‘ for examples and figures.

* Time coordinates are stored internally as the number of seconds relative to the standard unix epoch 1-Jan-1970. Earlier versions of gnuplot used a different epoch internally (1-Jan-2000). This change resolves inconsistencies introduced whenever time in seconds was generated externally. The epoch convention used by a particular gnuplot installation can be determined using the command ‘print strftime("%F",0)‘. Time is now stored to at least millisecond precision.

* The function ‘timecolumn(N,"timeformat")‘ now has 2 parameters. Because the new second parameter is not associated with any particular data axis, this allows using the ‘timecolumn‘ function to read time data for reasons other than specifying the x or y coordinate. This functionality replaces the command sequence ‘set xdata time; set timefmt "timeformat"‘. It allows combining time data read from multiple files with different formats within a single plot.

* The ‘reverse‘ keyword of the ‘set [axis]range‘ command affects only autoscaling. It does not invert or otherwise alter the meaning of a command such as ‘set xrange [0:1]‘. If you want to reverse the direction of the x axis in such a case, say instead ‘set xrange [1:0]‘.

* The call command is provides a set of variables ARGC, ARG0, ..., ARG9. ARG0 holds the name of the script file being executed. ARG1 to ARG9 are string variables and thus may either be referenced directly or expanded as macros, e.g. @ARG1. The contents of ARG0 ... ARG9 may alternatively be accessed as array elements ARGV[0] ... ARGV[ARGC]. An older gnuplot convention of referencing call parameters as tokens $0 ... $9 is deprecated.

* The optional bandwidth for the kernel density smoothing option is taken from a keyword rather than a data column. See ‘smooth kdensity‘.

1.6 Deprecated syntax

Gnuplot version 4 deprecated certain syntax used in earlier versions but provided a configuration option that allowed backward compatibility. Support for the old syntax has now been removed.

Deprecated in version 4 and removed in version 5:

      set title "Old" 0,-1
      set data linespoints
      plot 'file' thru f(x)
      plot 1 2 4               # horizontal line at y=1

Current equivalent:

      TITLE = "New"
      set title TITLE offset char 0, char -1
      set style data linespoints
      plot 'file' using 1:(f(column(2)))
      plot 1 linetype 2 pointtype 4
      save fit "filename"

Deprecated in version 5

      if (defined(VARNAME)) ...
      set style increment user
      call 'script' 1.23 ABC
         (in script:  print $0, "$1", "number of args = $#")
      set fontpath
      set clabel
      fit control variables FIT_*

Current equivalent:

      if (exists("VARNAME")) ...
      set linetype
      call 'script' 1.23 "ABC"
         (in script:  print ARG1, ARG2, "number of args = ", ARGC
      set cntrlabel
      set fit <option> <value>

Deprecated in version 5.4

      # use of a file containing reread to perform iteration
      N = 0;  load "file-containing-reread";
      file content:
          N = N+1
          plot func(N,x)
          pause -1
          if (N<5) reread

Current equivalent

      do for [N=1:5] {
          plot func(N, x)
          pause -1

1.7 Demos and Online Examples

The ‘gnuplot‘ distribution contains a collection of examples in the ‘demo‘ directory. You can browse on-line versions of these examples produced by the png, svg, and canvas terminals at The commands that produced each demo plot are shown next to the plot, and the corresponding gnuplot script can be downloaded to serve as a model for generating similar plots.

1.8 Batch/Interactive Operation

‘Gnuplot‘ may be executed in either batch or interactive modes, and the two may even be mixed together on many systems.

Any command-line arguments are assumed to be either program options (see command-line-options) or names of files containing ‘gnuplot‘ commands. Each file or command string will be executed in the order specified. The special filename "-" is indicates that commands are to be read from stdin. ‘Gnuplot‘ exits after the last file is processed. If no load files and no command strings are specified, ‘gnuplot‘ accepts interactive input from stdin.

1.8.1 command line options

Gnuplot accepts the following options on the command line

     -V, --version
     -h, --help
     -p  --persist
     -d  --default-settings
     -s  --slow
     -e  "command1; command2; ..."
     -c  scriptfile ARG1 ARG2 ...

-p tells the program not to close any remaining interactive plot windows when the program exits.

-d tells the program not to execute any private or system initialization (see ‘initialization‘).

-s tells the program to wait for slow font initialization on startup. Otherwise it prints an error and continues with bad font metrics.

-e "command" tells gnuplot to execute that single command before continuing.

-c is equivalent to -e "call scriptfile ARG1 ARG2 ...". See call.

1.8.2 Examples

To launch an interactive session:


To launch a batch session using two command files "input1" and "input2":

      gnuplot input1 input2

To launch an interactive session after an initialization file "header" and followed by another command file "trailer":

      gnuplot header - trailer

To give ‘gnuplot‘ commands directly in the command line, using the "-persist" option so that the plot remains on the screen afterwards:

      gnuplot -persist -e "set title 'Sine curve'; plot sin(x)"

To set user-defined variables a and s prior to executing commands from a file:

      gnuplot -e "a=2; s='file.png'" input.gpl

1.9 Canvas size

This documentation uses the term "canvas" to mean the full drawing area available for positioning the plot and associated elements like labels, titles, key, etc. NB: For information about the HTML5 canvas terminal see ‘set term canvas‘.

In earlier versions of gnuplot, some terminal types used the values from size to control also the size of the output canvas; others did not. The use of ’set size’ for this purpose was deprecated in version 4. Almost all terminals now behave as follows:

‘set term <terminal_type> size <XX>, <YY>‘ controls the size of the output file, or "canvas". By default, the plot will fill this canvas.

‘set size <XX>, <YY>‘ scales the plot itself relative to the size of the canvas. Scale values less than 1 will cause the plot to not fill the entire canvas. Scale values larger than 1 will cause only a portion of the plot to fit on the canvas. Please be aware that setting scale values larger than 1 may cause problems.


      set size 0.5, 0.5
      set term png size 600, 400
      set output "figure.png"
      plot "data" with lines

These commands produce an output file "figure.png" that is 600 pixels wide and 400 pixels tall. The plot will fill the lower left quarter of this canvas. This is consistent with the way multiplot mode has always worked.

1.10 Command-line-editing

Command-line editing and command history are supported using either an external gnu readline library, an external BSD libedit library, or a built-in equivalent. This choice is a configuration option at the time gnuplot is built.

The editing commands of the built-in version are given below. Please note that the action of the DEL key is system-dependent. The gnu readline and BSD libedit libraries have their own documentation.


      ^B    moves back a single character.
      ^F    moves forward a single character.
      ^A    moves to the beginning of the line.
      ^E    moves to the end of the line.
      ^H    deletes the previous character.
      DEL   deletes the current character.
      ^D    deletes current character, sends EOF if the line is empty.
      ^K    deletes from current position to the end of line.
      ^L    redraws line in case it gets trashed.
      ^U    deletes the entire line.
      ^W    deletes previous word.
      ^V    inhibits the interpretation of the following key as editing command.
      TAB   performs filename-completion.


      ^P    moves back through history.
      ^N    moves forward through history.
      ^R    starts a backward-search.


The comment character ‘#‘ may appear almost anywhere in a command line, and ‘gnuplot‘ will ignore the rest of that line. A ‘#‘ does not have this effect inside a quoted string. Note that if a commented line ends in ’\’ then the subsequent line is also treated as part of the comment.

See also ‘set datafile commentschars‘ for specifying a comment character for data files.

1.12 Coordinates

The commands ‘set arrow‘, ‘set key‘, ‘set label‘ and object allow you to draw something at an arbitrary position on the graph. This position is specified by the syntax:

      {<system>} <x>, {<system>} <y> {,{<system>} <z>}

Each <system> can either be ‘first‘, ‘second‘, ‘polar‘, ‘graph‘, ‘screen‘, or ‘character‘.

‘first‘ places the x, y, or z coordinate in the system defined by the left and bottom axes; ‘second‘ places it in the system defined by the x2,y2 axes (top and right); ‘graph‘ specifies the area within the axes—0,0 is bottom left and 1,1 is top right (for splot, 0,0,0 is bottom left of plotting area; use negative z to get to the base—see xyplane); ‘screen‘ specifies the screen area (the entire area—not just the portion selected by size), with 0,0 at bottom left and 1,1 at top right. ‘character‘ coordinates are used primarily for offsets, not absolute positions. The ‘character‘ vertical and horizontal size depend on the current font.

‘polar‘ causes the first two values to be interpreted as angle theta and radius r rather than as x and y. This could be used, for example, to place labels on a 2D plot in polar coordinates or a 3D plot in cylindrical coordinates.

If the coordinate system for x is not specified, ‘first‘ is used. If the system for y is not specified, the one used for x is adopted.

In some cases, the given coordinate is not an absolute position but a relative value (e.g., the second position in ‘set arrow‘ ... ‘rto‘). In most cases, the given value serves as difference to the first position. If the given coordinate belongs to a log-scaled axis, a relative value is interpreted as multiplier. For example,

      set logscale x
      set arrow 100,5 rto 10,2

plots an arrow from position 100,5 to position 1000,7 since the x axis is logarithmic while the y axis is linear.

If one (or more) axis is timeseries, the appropriate coordinate should be given as a quoted time string according to the timefmt format string. See xdata and timefmt. ‘Gnuplot‘ will also accept an integer expression, which will be interpreted as seconds relative to 1 January 1970.

1.13 Datastrings

Data files may contain string data consisting of either an arbitrary string of printable characters containing no whitespace or an arbitrary string of characters, possibly including whitespace, delimited by double quotes. The following line from a datafile is interpreted to contain four columns, with a text field in column 3:

  1.000 2.000 "Third column is all of this text" 4.00

Text fields can be positioned within a 2-D or 3-D plot using the commands:

  plot 'datafile' using 1:2:4 with labels
  splot 'datafile' using 1:2:3:4 with labels

A column of text data can also be used to label the ticmarks along one or more of the plot axes. The example below plots a line through a series of points with (X,Y) coordinates taken from columns 3 and 4 of the input datafile. However, rather than generating regularly spaced tics along the x axis labeled numerically, gnuplot will position a tic mark along the x axis at the X coordinate of each point and label the tic mark with text taken from column 1 of the input datafile.

  set xtics
  plot 'datafile' using 3:4:xticlabels(1) with linespoints

There is also an option that will interpret the first entry in a column of input data (i.e. the column heading) as a text field, and use it as the key title for data plotted from that column. The example given below will use the first entry in column 2 to generate a title in the key box, while processing the remainder of columns 2 and 4 to draw the required line:

  plot 'datafile' using 1:(f($2)/$4) with lines title columnhead(2)

Another example:

  plot for [i=2:6] 'datafile' using i title "Results for ".columnhead(i)

This use of column headings is automated by columnheaders or ‘set key autotitle columnhead‘. See labels, ‘using xticlabels‘, title, ‘using‘, ‘key autotitle‘.

1.14 Enhanced text mode

Many terminal types support an enhanced text mode in which additional formatting information is embedded in the text string. For example, "x^2" will write x-squared as we are used to seeing it, with a superscript 2. This mode is selected by default when you set the terminal, but may be toggled afterward using "set termoption [no]enhanced", or by marking individual strings as in "set label ’x_2’ noenhanced".

 Control      Examples        Explanation
  ^           a^x             superscript
  _           a_x             subscript
  @           @x or a@^b_{cd} phantom box (occupies no width)
  &           &{space}        inserts space of specified length
  ~           ~a{.8-}         overprints '-' on 'a', raised by .8
                              times the current fontsize
  {/Times abc}                print abc in font Times at current size
  {/Times*2 abc}              print abc in font Times at twice current size
  {/Times:Italic abc}         print abc in font Times with style italic
  {/Arial:Bold=20 abc}        print abc in boldface Arial font size 20
  \U+         \U+221E         Unicode point U+221E (INFINITY)

The markup control characters act on the following single character or bracketed clause. The bracketed clause may contain a string of characters with no additional markup, e.g. 2^{10}, or it may contain additional markup that changes font properties. Font specifiers MUST be preceded by a ’/’ character that immediately follows the opening ’{’. If a font name contains spaces it must be enclosed in single or double quotes.

Examples: The first example illustrates nesting one bracketed clause inside another to produce a boldface A with an italic subscript i, all in the current font. If the clause introduced by :Normal were omitted the subscript would be both italic and boldface. The second example illustrates the same markup applied to font "Times New Roman" at 20 point size.

     {/:Bold A_{/:Normal{/:Italic i}}}
     {/"Times New Roman":Bold=20 A_{/:Normal{/:Italic i}}}

The phantom box is useful for a@^b_c to align superscripts and subscripts but does not work well for overwriting an accent on a letter. For the latter, it is much better to use an encoding (e.g. iso_8859_1 or utf8) that contains a large variety of letters with accents or other diacritical marks. See encoding. Since the box is non-spacing, it is sensible to put the shorter of the subscript or superscript in the box (that is, after the @).

Space equal in length to a string can be inserted using the ’&’ character. Thus


would produce

        'abc   ghi'.

The ’~’ character causes the next character or bracketed text to be overprinted by the following character or bracketed text. The second text will be horizontally centered on the first. Thus ’~a/’ will result in an ’a’ with a slash through it. You can also shift the second text vertically by preceding the second text with a number, which will define the fraction of the current fontsize by which the text will be raised or lowered. In this case the number and text must be enclosed in brackets because more than one character is necessary. If the overprinted text begins with a number, put a space between the vertical offset and the text (’~{abc}{.5 000}’); otherwise no space is needed (’~{abc}{.5—}’). You can change the font for one or both strings (’~a{.5 /*.2 o}’—an ’a’ with a one-fifth-size ’o’ on top—and the space between the number and the slash is necessary), but you can’t change it after the beginning of the string. Neither can you use any other special syntax within either string. You can, of course, use control characters by escaping them (see below), such as ’~a{\^}’

You can escape control characters using \, e.g., \\, \{, and so on. See ‘escape sequences‘ below.

Note that strings in double-quotes are parsed differently than those enclosed in single-quotes. The major difference is that backslashes may need to be doubled when in double-quoted strings.

The file "" in the /docs/psdoc subdirectory of the gnuplot source distribution contains more examples of the enhanced syntax, as does the demo ‘enhanced_utf8.dem‘

1.14.1 Escape sequences

The backslash character \ is used to escape single byte character codes or Unicode entry points.

The form \ooo (where ooo is a 3 character octal value) can be used to index a known character code in a specific font encoding. For example the Adobe Symbol font uses a custom encoding in which octal 245 represents the infinity symbol. You could embed this in an enhanced text string by giving the font name and the character code "{/Symbol \245}". This is mostly useful for the PostScript terminal, which cannot easily handle UTF-8 encoding.

You can specify a character by its Unicode code point as \U+hhhh, where hhhh is the 4 or 5 character hexadecimal code point. For example the code point for the infinity symbol is \U+221E. This will be converted to a UTF-8 byte sequence on output if appropriate. In a UTF-8 environment this mechanism is not needed for printable special characters since they are handled in a text string like any other character. However it is useful for combining forms or supplemental diacritical marks (e.g. an arrow over a letter to represent a vector). See encoding, ‘utf8‘, and the online unicode demo.

1.15 Environment

A number of shell environment variables are understood by ‘gnuplot‘. None of these are required, but may be useful.

GNUTERM, if defined, is used to set the terminal type on start-up. Starting with version 5.2 the entire string in GNUTERM is passed to "set term" so that terminal options may be included. E.g.

     GNUTERM="postscript eps color size 5in, 3in"

This can be overridden by the ~/.gnuplot (or equivalent) start-up file (see ‘startup‘) and of course by later explicit ‘set term‘ commands.

GNUHELP may be defined to be the pathname of the HELP file (gnuplot.gih).

On VMS, the logical name GNUPLOT$HELP should be defined as the name of the help library for ‘gnuplot‘. The ‘gnuplot‘ help can be put inside any VMS system help library.

On Unix, HOME is used as the name of a directory to search for a .gnuplot file if none is found in the current directory. Additionally gnuplot searches for $XDG_CONFIG_HOME/gnuplot/gnuplotrc which is loaded after .gnuplot. On MS-DOS, Windows and OS/2, GNUPLOT is used. On Windows, the NT-specific variable USERPROFILE is also tried. VMS, SYS$LOGIN: is used. Type ‘help startup‘.

On Unix, PAGER is used as an output filter for help messages.

On Unix, SHELL is used for the shell command. On MS-DOS and OS/2, COMSPEC is used for the shell command.

‘FIT_SCRIPT‘ may be used to specify a ‘gnuplot‘ command to be executed when a fit is interrupted—see fit. ‘FIT_LOG‘ specifies the default filename of the logfile maintained by fit.

GNUPLOT_LIB may be used to define additional search directories for data and command files. The variable may contain a single directory name, or a list of directories separated by a platform-specific path separator, eg. ’:’ on Unix, or ’;’ on DOS/Windows/OS/2 platforms. The contents of GNUPLOT_LIB are appended to the loadpath variable, but not saved with the save and ‘save set‘ commands.

Several gnuplot terminal drivers access TrueType fonts via the gd library. For these drivers the font search path is controlled by the environmental variable GDFONTPATH. Furthermore, a default font for these drivers may be set via the environmental variable GNUPLOT_DEFAULT_GDFONT.

The postscript terminal uses its own font search path. It is controlled by the environmental variable GNUPLOT_FONTPATH.

GNUPLOT_PS_DIR is used by the postscript driver to search for external prologue files. Depending on the build process, gnuplot contains either a built-in copy of those files or a default hardcoded path. You can use this variable have the postscript terminal use custom prologue files rather than the default files. See ‘postscript prologue‘.

1.16 Expressions

In general, any mathematical expression accepted by C, FORTRAN, Pascal, or BASIC is valid. The precedence of these operators is determined by the specifications of the C programming language. White space (spaces and tabs) is ignored inside expressions.

Note that gnuplot uses both "real" and "integer" arithmetic, like FORTRAN and C. Integers are entered as "1", "-10", etc; reals as "1.0", "-10.0", "1e1", 3.5e-1, etc. The most important difference between the two forms is in division: division of integers truncates: 5/2 = 2; division of reals does not: 5.0/2.0 = 2.5. In mixed expressions, integers are "promoted" to reals before evaluation: 5/2e0 = 2.5. The result of division of a negative integer by a positive one may vary among compilers. Try a test like "print -5/2" to determine if your system always rounds down (-5/2 yields -3) or always rounds toward zero (-5/2 yields -2).

The integer expression "1/0" may be used to generate an "undefined" flag, which causes a point to be ignored. Or you can use the pre-defined variable NaN to achieve the same result. See ‘using‘ for an example.

Gnuplot can also perform simple operations on strings and string variables. For example, the expression ("A" . "B" eq "AB") evaluates as true, illustrating the string concatenation operator and the string equality operator.

A string which contains a numerical value is promoted to the corresponding integer or real value if used in a numerical expression. Thus ("3" + "4" == 7) and (6.78 == "6.78") both evaluate to true. An integer, but not a real or complex value, is promoted to a string if used in string concatenation. A typical case is the use of integers to construct file names or other strings; e.g. ("file" . 4 eq "file4") is true.

Substrings can be specified using a postfixed range descriptor [beg:end]. For example, "ABCDEF"[3:4] == "CD" and "ABCDEF"[4:*] == "DEF" The syntax "string"[beg:end] is exactly equivalent to calling the built-in string-valued function substr("string",beg,end), except that you cannot omit either beg or end from the function call.

1.16.1 Complex arithmetic

Arithmetic operations and most built-in functions support the use of complex arguments. Complex constants are expressed as {<real>,<imag>}, where <real> and <imag> must be numerical constants. Thus {0,1} represents ’i’. The real and imaginary components of complex value x can be extracted as real(x) and imag(x). The modulus is given by abs(x).

Gnuplot’s standard 2D and 3D plot styles can plot only real values; if you need to plot a complex-valued function f(x) with non-zero imaginary components you must choose between plotting real(f(x)) or abs(f(x)). For examples of representing complex values using color, see the complex trigonometric function demos (complex_trig.dem)

1.16.2 Constants

Integer constants are interpreted via the C library routine strtoll(). This means that constants beginning with "0" are interpreted as octal, and constants beginning with "0x" or "0X" are interpreted as hexadecimal.

Floating point constants are interpreted via the C library routine atof().

Complex constants are expressed as {<real>,<imag>}, where <real> and <imag> must be numerical constants. For example, {3,2} represents 3 + 2i; {0,1} represents ’i’ itself. The curly braces are explicitly required here.

String constants consist of any sequence of characters enclosed either in single quotes or double quotes. The distinction between single and double quotes is important. See ‘quotes‘.


     1 -10 0xffaabb        # integer constants
     1.0 -10. 1e1 3.5e-1   # floating point constants
     {1.2, -3.4}           # complex constant
     "Line 1\nLine 2"      # string constant (\n is expanded to newline)
     '123\n456'            # string constant (\ and n are ordinary characters)

1.16.3 Functions

Arguments to math functions in ‘gnuplot‘ can be integer, real, or complex unless otherwise noted. Functions that accept or return angles (e.g. sin(x)) treat angle values as radians, but this may be changed to degrees using the command angles. abs

The ‘abs(x)‘ function returns the absolute value of its argument. The returned value is of the same type as the argument.

For complex arguments, abs(x) is defined as the length of x in the complex plane [i.e., sqrt(real(x)**2 + imag(x)**2) ]. This is also known as the norm or complex modulus of x. acos

The ‘acos(x)‘ function returns the arc cosine (inverse cosine) of its argument. ‘acos‘ returns its argument in radians or degrees, as selected by angles. acosh

The ‘acosh(x)‘ function returns the inverse hyperbolic cosine of its argument in radians or degrees, as selected by angles. airy

The ‘airy(x)‘ function returns the value of the Airy function Ai(x) of its argument. The function Ai(x) is that solution of the equation y” - x y = 0 which is everywhere finite. If the argument is complex, its imaginary part is ignored. arg

The ‘arg(x)‘ function returns the phase of a complex number in radians or degrees, as selected by angles. asin

The ‘asin(x)‘ function returns the arc sin (inverse sin) of its argument. ‘asin‘ returns its argument in radians or degrees, as selected by angles. asinh

The ‘asinh(x)‘ function returns the inverse hyperbolic sin of its argument in radians or degress, as selected by angles. atan

The ‘atan(x)‘ function returns the arc tangent (inverse tangent) of its argument. ‘atan‘ returns its argument in radians or degrees, as selected by angles. atan2

The ‘atan2(y,x)‘ function returns the arc tangent (inverse tangent) of the ratio of the real parts of its arguments. atan2 returns its argument in radians or degrees, as selected by angles, in the correct quadrant. atanh

The ‘atanh(x)‘ function returns the inverse hyperbolic tangent of its argument in radians or degrees, as selected by angles. EllipticK

The ‘EllipticK(k)‘ function returns the complete elliptic integral of the first kind. See ‘elliptic integrals‘ for more details. EllipticE

The ‘EllipticE(k)‘ function returns the complete elliptic integral of the second kind. See ‘elliptic integrals‘ for more details. EllipticPi

The ‘EllipticPi(n,k)‘ function returns the complete elliptic integral of the third kind. See ‘elliptic integrals‘ for more details. besj0

The ‘besj0(x)‘ function returns the J0th Bessel function of its argument. besj0 expects its argument to be in radians. besj1

The ‘besj1(x)‘ function returns the J1st Bessel function of its argument. besj1 expects its argument to be in radians. besjn

The ‘besjn(n,x)‘ functions returns the Jn Bessel function of x in radians. besy0

The ‘besy0(x)‘ function returns the Y0th Bessel function of its argument. besy0 expects its argument to be in radians. besy1

The ‘besy1(x)‘ function returns the Y1st Bessel function of its argument. besy1 expects its argument to be in radians. besyn

The ‘besyn(n,x)‘ functions returns the Yn Bessel function of x in radians. besi0

The ‘besi0(x)‘ function is the modified Bessel function or order 0. besi0 expects its argument to be in radians. besi1

The ‘besi1(x)‘ function is the modified Bessel function or order 1. besi1 expects its argument to be in radians. besin

‘besin(n,x)‘ is the modified Bessel function or order n for integer n and x in radians. ceil

The ‘ceil(x)‘ function returns the smallest integer that is not less than its argument. For complex numbers, ceil returns the smallest integer not less than the real part of its argument. cos

The ‘cos(x)‘ function returns the cosine of its argument. ‘cos‘ accepts its argument in radians or degrees, as selected by angles. cosh

The ‘cosh(x)‘ function returns the hyperbolic cosine of its argument. cosh expects its argument to be in radians. erf

The ‘erf(x)‘ function returns the error function of the real part of its argument. If the argument is a complex value, the imaginary component is ignored. See erfc, inverf, and norm. erfc

The ‘erfc(x)‘ function returns 1.0 - the error function of the real part of its argument. If the argument is a complex value, the imaginary component is ignored. See ‘erf‘, inverf, and norm. exp

The ‘exp(x)‘ function returns ‘e‘ raised to the power of x, which can be an integer, real, or complex value. expint

The ‘expint(n,x)‘ function returns the exponential integral of the real part of its argument: integral from 1 to infinity of t^(-n) e^(-tx) dt. n must be a nonnegative integer, x>=0, and either x>0 or n>1. floor

The ‘floor(x)‘ function returns the largest integer not greater than its argument. For complex numbers, floor returns the largest integer not greater than the real part of its argument. gamma

The ‘gamma(x)‘ function returns the gamma function of the real part of its argument. For integer n, gamma(n+1) = n!. If the argument is a complex value, the imaginary component is ignored. ibeta

The ‘ibeta(p,q,x)‘ function returns the incomplete beta function of the real parts of its arguments. p, q > 0 and x in [0:1]. If the arguments are complex, the imaginary components are ignored. The function is approximated by the method of continued fractions (Abramowitz and Stegun, 1964). The approximation is only accurate in the region x < (p-1)/(p+q-2). inverf

The ‘inverf(x)‘ function returns the inverse error function of the real part of its argument. See ‘erf‘ and invnorm. igamma

The ‘igamma(a,x)‘ function returns the normalized incomplete gamma function of the real parts of its arguments, where a > 0 and x >= 0. The standard notation is P(a,x), e.g. Abramowitz and Stegun (6.5.1), with limiting value of 1 as x approaches infinity. If the arguments are complex, the imaginary components are ignored. imag

The ‘imag(x)‘ function returns the imaginary part of its argument as a real number. invnorm

The ‘invnorm(x)‘ function returns the inverse cumulative normal (Gaussian) distribution function of the real part of its argument. See norm. int

The ‘int(x)‘ function returns the integer part of its argument, truncated toward zero. lambertw

The ‘lambertw(x)‘ function returns the value of the principal branch of Lambert’s W function, which is defined by the equation (W(x)*exp(W(x))=x. x must be a real number with x >= -exp(-1). lgamma

The ‘lgamma(x)‘ function returns the natural logarithm of the gamma function of the real part of its argument. If the argument is a complex value, the imaginary component is ignored. log

The ‘log(x)‘ function returns the natural logarithm (base ‘e‘) of its argument. See log10. log10

The ‘log10(x)‘ function returns the logarithm (base 10) of its argument. norm

The ‘norm(x)‘ function returns the cumulative normal (Gaussian) distribution function of the real part of its argument. See invnorm, ‘erf‘ and erfc. rand

The ‘rand(x)‘ function returns a pseudo random number in the interval (0:1). See ‘random‘ for more details. real

The ‘real(x)‘ function returns the real part of its argument. sgn

The ‘sgn(x)‘ function returns 1 if its argument is positive, -1 if its argument is negative, and 0 if its argument is 0. If the argument is a complex value, the imaginary component is ignored. sin

The ‘sin(x)‘ function returns the sine of its argument. ‘sin‘ expects its argument to be in radians or degrees, as selected by angles. sinh

The ‘sinh(x)‘ function returns the hyperbolic sine of its argument. sinh expects its argument to be in radians. sqrt

The ‘sqrt(x)‘ function returns the square root of its argument. If the x is a complex value, this always returns the root with positive real part. tan

The ‘tan(x)‘ function returns the tangent of its argument. ‘tan‘ expects its argument to be in radians or degrees, as selected by angles. tanh

The ‘tanh(x)‘ function returns the hyperbolic tangent of its argument. tanh expects its argument to be in radians. voigt

The function ‘voigt(x,y)‘ returns an approximation to the Voigt/Faddeeva function used in spectral analysis. The approximation is accurate to one part in 10^4. If the libcerf routines are available, the re_w_of_z() routine is used to provide a more accurate value. Note that voigt(x,y) = real(faddeeva( x + y*{0,1} )). cerf

‘cerf(z)‘ is the complex version of the error function erf(x) cdawson

‘cdawson(z)‘ returns Dawson’s Integral evaluated for the complex argument z. cdawson(z) = sqrt(pi)/2 * exp(-z^2) * erfi(z) faddeeva

The ‘faddeeva(z)‘ function returns the rescaled complex error function faddeeva(z) = exp(-z^2) * erfc(-i*z) This corresponds to Eqs 7.1.3 and 7.1.4 of Abramowitz and Stegun. erfi

Imaginary error function erfi(x) = -i * erf(ix) Voigt Profile

‘VP(x,sigma,gamma)‘ corresponds to the Voigt profile defined by convolution of a Gaussian G(x;sigma) with a Lorentzian L(x;gamma). gprintf

‘gprintf("format",x)‘ applies gnuplot’s own format specifiers to the single variable x and returns the resulting string. If you want standard C-language format specifiers, you must instead use ‘sprintf("format",x)‘. See ‘format specifiers‘. sprintf

‘sprintf("format",var1,var2,...)‘ applies standard C-language format specifiers to multiple arguments and returns the resulting string. If you want to use gnuplot’s own format specifiers, you must instead call ‘gprintf()‘. For information on sprintf format specifiers, please see standard C-language documentation or the unix sprintf man page. strlen

‘strlen("string")‘ returns the number of characters in a string taking into account the current encoding. If the current encoding supports multibyte characters (SJIS UTF8), this may be less than the number of bytes in the string. If the string contains multibyte UTF8 characters but the current encoding is set to something other than UTF8, strlen("utf8string") will return a value that is larger than the actual number of characters. strstrt

‘strstrt("string","key")‘ searches for the character string "key" in "string" and returns the index to the first character of "key". If "key" is not found, it returns 0. Similar to C library function strstr except that it returns an index rather than a string pointer. strstrt("hayneedlestack","needle") = 4. This function is aware of utf8 encoding, so strstrt("αβγ","β") returns 2. substr

‘substr("string",beg,end)‘ returns the substring consisting of characters beg through end of the original string. This is exactly equivalent to the expression "string"[beg:end] except that you do not have the option of omitting beg or end. strftime

‘strftime("timeformat",t)‘ applies the timeformat specifiers to the time t given in seconds since the year 1970. See ‘time_specifiers‘ and strptime. strptime

‘strptime("timeformat",s)‘ reads the time from the string s using the timeformat specifiers and converts it into seconds since the year 1970. See ‘time_specifiers‘ and strftime. system

‘system("command")‘ executes "command" using the standard shell and returns the resulting character stream from stdout as string variable. One optional trailing newline is ignored.

This can be used to import external functions into gnuplot scripts using ’f(x) = real(system(sprintf("somecommand %f", x)))’. trim

‘trim(" padded string ")‘ returns the original string stripped of leading and trailing whitespace. This is useful for string comparisons of input data fields that may contain extra whitespace. For example

     plot FOO using 1:( trim(strcol(3)) eq "A" ? $2 : NaN ) word

‘word("string",n)‘ returns the nth word in string. For example, ‘word("one two three",2)‘ returns the string "two". words

‘words("string")‘ returns the number of words in string. For example, ‘words(" a b c d")‘ returns 4. exists

The argument to ‘exists()‘ is a string constant or a string variable; if the string contains the name of a defined variable, the function returns 1. Otherwise the function returns 0. hsv2rgb

The ‘hsv2rgb(h,s,v)‘ function converts HSV (Hue/Saturation/Value) triplet to an equivalent RGB value. palette

‘palette(z)‘ returns the RGB representation of the palette color mapped to z

 given the current extremes of cbrange. tm_hour

The ‘tm_hour(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the hour (an integer in the range 0–23) as a real. tm_mday

The ‘tm_mday(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the day of the month (an integer in the range 1–31) as a real. tm_min

The ‘tm_min(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the minute (an integer in the range 0–59) as a real. tm_mon

The ‘tm_mon(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the month (an integer in the range 0–11) as a real. tm_sec

The ‘tm_sec(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the second (an integer in the range 0–59) as a real. tm_wday

The ‘tm_wday(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the day of the week (Sun..Sat) as an integer (0..6). tm_week tm_yday

The ‘tm_yday(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the day of the year (an integer in the range 0–365) as a real. tm_year

The ‘tm_year(t)‘ function interprets its argument as a time, in seconds from 1 Jan 1970. It returns the year (an integer) as a real. time

The ‘time(x)‘ function returns the current system time. This value can be converted to a date string with the strftime function, or it can be used in conjunction with ‘timecolumn‘ to generate relative time/date plots. The type of the argument determines what is returned. If the argument is an integer, time() returns the current time as an integer, in seconds from the epoch start, 1 Jan 1970. If the argument is real the result is also real and may include fractional seconds. If the argument is a string, it is assumed to be a format and is passed to strftime to provide a formatted time string. See also ‘time_specifiers‘ and timefmt. voxel

The function voxel(x,y,z) returns the value of the voxel in the currently active grid that contains the point (x,y,z). It may also be used on the left side of an assignment statement to set the value of that voxel. E.g. voxel(x,y,z) = 0.0 See ‘splot voxel-grids‘, vgrid. elliptic integrals

The ‘EllipticK(k)‘ function returns the complete elliptic integral of the first kind, i.e. the definite integral between 0 and pi/2 of the function ‘(1-(k*sin(p))**2)**(-0.5)‘. The domain of ‘k‘ is -1 to 1 (exclusive).

The ‘EllipticE(k)‘ function returns the complete elliptic integral of the second kind, i.e. the definite integral between 0 and pi/2 of the function ‘(1-(k*sin(p))**2)**0.5‘. The domain of ‘k‘ is -1 to 1 (inclusive).

The ‘EllipticPi(n,k)‘ function returns the complete elliptic integral of the third kind, i.e. the definite integral between 0 and pi/2 of the function ‘(1-(k*sin(p))**2)**(-0.5)/(1-n*sin(p)**2)‘. The parameter ‘n‘ must be less than 1, while ‘k‘ must lie between -1 and 1 (exclusive). Note that by definition EllipticPi(0,k) == EllipticK(k) for all possible values of ‘k‘. Random number generator

The function ‘rand()‘ produces a sequence of pseudo-random numbers between 0 and 1 using an algorithm from P. L’Ecuyer and S. Cote, "Implementing a random number package with splitting facilities", ACM Transactions on Mathematical Software, 17:98-111 (1991).

      rand(0)     returns a pseudo random number in the open interval (0:1)
                  generated from the current value of two internal
                  32-bit seeds.
      rand(-1)    resets both seeds to a standard value.
      rand(x)     for integer 0 < x < 2^31-1 sets both internal seeds
                  to x.
      rand({x,y}) for integer 0 < x,y < 2^31-1 sets seed1 to x and
                  seed2 to y. using specifier functions

These functions are valid only in the context of data input. Usually this means use in an expression that provides an input field of the ‘using‘ specifier in a ‘plot‘, ‘splot‘, fit, or ‘stats‘ command. However the scope of the functions is actually the full clause of the plot command, including for example use of ‘columnhead‘ in constructing the plot title.


The ‘column(x)‘ function may be used only in the ‘using‘ specifier of a plot, splot, fit, or stats command. It evaluates to the numerical value of the content of column x. If the column is expected to hold a string, use instead stringcolumn(x) or timecolumn(x, "timeformat"). See ‘plot datafile using‘, ‘stringcolumn‘, ‘timecolumn‘.


The ‘columnhead(x)‘ function may only be used as part of a plot, splot, or stats command. It evaluates to a string containing the content of column x in the first line of a data file. This is typically used to extract the column header for use in a plot title. See ‘plot datafile using‘. Example:

     set datafile columnheader
     plot for [i=2:4] DATA using 1:i title columnhead(i)


The ‘stringcolumn(x)‘ function may be used only in the ‘using‘ specification of a data plot or fit command. It returns the content of column x as a string. ‘strcol(x)‘ is shorthand for ‘stringcolumn(x)‘. If the string is to be interpreted as a time or date, use instead timecolumn(x, "timeformat"). See ‘plot datafile using‘.


‘timecolumn(N,"timeformat")‘ reads string data starting at column N as a time/date value and uses "timeformat" to interpret this as "seconds since the epoch" to millisecond precision. If no format parameter is given, the format defaults to the string from timefmt. This function is valid only in the ‘using‘ specification of a plot or stats command. See ‘plot datafile using‘.


The ‘valid(x)‘ function may be used only in expressions that are part of a ‘using‘ specification. It can be used to detect explicit NaN values or unexpected garbage in a field of the input stream, perhaps to substitute a default value or to prevent further arithmetic operations using NaN. Both "missing" and NaN (not-a-number) data values are considered to be invalid, but it is important to note that if the program recognizes that a field is truly missing or contains a "missing" flag then the input line is discarded before the expression invoking valid() would be called. See ‘plot datafile using‘, ‘missing‘.


     # Treat an unrecognized bin value as contributing some constant
     # prior expectation to the bin total rather than ignoring it.
     plot DATA using 1 : (valid(2) ? $2 : prior) smooth unique value

B = value("A") is effectively the same as B = A, where A is the name of a user-defined variable. This is useful when the name of the variable is itself held in a string variable. See variables. It also allows you to read the name of a variable from a data file. If the argument is a numerical expression, value() returns the value of that expression. If the argument is a string that does not correspond to a currently defined variable, value() returns NaN. Counting and extracting words

‘word("string",n)‘ returns the nth word in string. For example, ‘word("one two three",2)‘ returns the string "two".

‘words("string")‘ returns the number of words in string. For example, ‘words(" a b c d")‘ returns 4.

The ‘word‘ and words functions provide limited support for quoted strings, both single and double quotes can be used:

      print words("\"double quotes\" or 'single quotes'")   # 3

A starting quote must either be preceded by a white space, or start the string. This means that apostrophes in the middle or at the end of words are considered as parts of the respective word:

      print words("Alexis' phone doesn't work") # 4

Escaping quote characters is not supported. If you want to keep certain quotes, the respective section must be surrounded by the other kind of quotes:

      s = "Keep \"'single quotes'\" or '\"double quotes\"'"
      print word(s, 2) # 'single quotes'
      print word(s, 4) # "double quotes"

Note, that in this last example the escaped quotes are necessary only for the string definition.

‘trim(" padded string ")‘ returns the original string stripped of leading and trailing whitespace. This is useful for string comparisons of input data fields that may contain extra whitespace. For example

     plot FOO using 1:( trim(strcol(3)) eq "A" ? $2 : NaN )

1.16.4 Operators

The operators in ‘gnuplot‘ are the same as the corresponding operators in the C programming language, except that all operators accept integer, real, and complex arguments, unless otherwise noted. The ** operator (exponentiation) is supported, as in FORTRAN.

Parentheses may be used to change order of evaluation. Unary

The following is a list of all the unary operators and their usages:

    Symbol      Example    Explanation
      -           -a          unary minus
      +           +a          unary plus (no-operation)
      ~           ~a        * one's complement
      !           !a        * logical negation
      !           a!        * factorial
      $           $3        * call arg/column during `using` manipulation
      ||          |A|         cardinality of array A

(*) Starred explanations indicate that the operator requires an integer argument.

Operator precedence is the same as in Fortran and C. As in those languages, parentheses may be used to change the order of operation. Thus -2**2 = -4, but (-2)**2 = 4.

The factorial operator returns an integer when N! is sufficiently small (N <= 20 for 64-bit integers). It returns a floating point approximation for larger values of N.

This operator returns the number of elements |A| when applied to array A. It returns the number of data lines |$DATA| when applied to datablock $DATA. Binary

The following is a list of all the binary operators and their usages:

    Symbol       Example      Explanation
      **          a**b          exponentiation
      *           a*b           multiplication
      /           a/b           division
      %           a%b         * modulo
      +           a+b           addition
      -           a-b           subtraction
      ==          a==b          equality
      !=          a!=b          inequality
      <           a<b           less than
      <=          a<=b          less than or equal to
      >           a>b           greater than
      >=          a>=b          greater than or equal to
      <<          0xff<<1       left shift unsigned
      >>          0xff>>2       right shift unsigned
      &           a&b         * bitwise AND
      ^           a^b         * bitwise exclusive OR
      |           a|b         * bitwise inclusive OR
      &&          a&&b        * logical AND
      ||          a||b        * logical OR
      =           a = b         assignment
      ,           (a,b)         serial evaluation
      .           A.B           string concatenation
      eq          A eq B        string equality
      ne          A ne B        string inequality

(*) Starred explanations indicate that the operator requires integer arguments. Capital letters A and B indicate that the operator requires string arguments.

Logical AND (&&) and OR (||) short-circuit the way they do in C. That is, the second ‘&&‘ operand is not evaluated if the first is false; the second ‘||‘ operand is not evaluated if the first is true.

Serial evaluation occurs only in parentheses and is guaranteed to proceed in left to right order. The value of the rightmost subexpression is returned. Ternary

There is a single ternary operator:

    Symbol       Example      Explanation
      ?:          a?b:c     ternary operation

The ternary operator behaves as it does in C. The first argument (a), which must be an integer, is evaluated. If it is true (non-zero), the second argument (b) is evaluated and returned; otherwise the third argument (c) is evaluated and returned.

The ternary operator is very useful both in constructing piecewise functions and in plotting points only when certain conditions are met.


Plot a function that is to equal sin(x) for 0 <= x < 1, 1/x for 1 <= x < 2, and undefined elsewhere:

      f(x) = 0<=x && x<1 ? sin(x) : 1<=x && x<2 ? 1/x : 1/0
      plot f(x)

Note that ‘gnuplot‘ quietly ignores undefined values, so the final branch of the function (1/0) will produce no plottable points. Note also that f(x) will be plotted as a continuous function across the discontinuity if a line style is used. To plot it discontinuously, create separate functions for the two pieces. (Parametric functions are also useful for this purpose.)

For data in a file, plot the average of the data in columns 2 and 3 against the datum in column 1, but only if the datum in column 4 is non-negative:

      plot 'file' using 1:( $4<0 ? 1/0 : ($2+$3)/2 )

For an explanation of the ‘using‘ syntax, please see ‘plot datafile using‘.

1.16.5 Summation

A summation expression has the form

      sum [<var> = <start> : <end>] <expression>

<var> is treated as an integer variable that takes on successive integral values from <start> to <end>. For each of these, the current value of <expression> is added to a running total whose final value becomes the value of the summation expression. Examples:

      print sum [i=1:10] i
      # Equivalent to plot 'data' using 1:($2+$3+$4+$5+$6+...)
      plot 'data' using 1 : (sum [col=2:MAXCOL] column(col))

It is not necessary that <expression> contain the variable <var>. Although <start> and <end> can be specified as variables or expressions, their value cannot be changed dynamically as a side-effect of carrying out the summation. If <end> is less than <start> then the value of the summation is zero.

1.16.6 Gnuplot-defined variables

Gnuplot maintains a number of read-only variables that reflect the current internal state of the program and the most recent plot. These variables begin with the prefix "GPVAL_". Examples include GPVAL_TERM, GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN. Type ‘show variables all‘ to display the complete list and current values. Values related to axes parameters (ranges, log base) are values used during the last plot, not those currently ‘set‘.

Example: To calculate the fractional screen coordinates of the point [X,Y]


The read-only variable GPVAL_ERRNO is set to a non-zero value if any gnuplot command terminates early due to an error. The most recent error message is stored in the string variable GPVAL_ERRMSG. Both GPVAL_ERRNO and GPVAL_ERRMSG can be cleared using the command ‘reset errors‘.

Interactive terminals with ‘mouse‘ functionality maintain read-only variables with the prefix "MOUSE_". See variables for details.

The fit mechanism uses several variables with names that begin "FIT_". It is safest to avoid using such names. When using ‘set fit errorvariables‘, the error for each fitted parameter will be stored in a variable named like the parameter, but with "_err" appended. See the documentation on fit and fit for details.

See variables, ‘reset errors‘, variables, and fit.

1.16.7 User-defined variables and functions

New user-defined variables and functions of one through twelve variables may be declared and used anywhere, including on the ‘plot‘ command itself.

User-defined function syntax:

      <func-name>( <dummy1> {,<dummy2>} ... {,<dummy12>} ) = <expression>

where <expression> is defined in terms of <dummy1> through <dummy12>.

User-defined variable syntax:

      <variable-name> = <constant-expression>


      w = 2
      q = floor(tan(pi/2 - 0.1))
      f(x) = sin(w*x)
      sinc(x) = sin(pi*x)/(pi*x)
      delta(t) = (t == 0)
      ramp(t) = (t > 0) ? t : 0
      min(a,b) = (a < b) ? a : b
      comb(n,k) = n!/(k!*(n-k)!)
      len3d(x,y,z) = sqrt(x*x+y*y+z*z)
      plot f(x) = sin(x*a), a = 0.2, f(x), a = 0.4, f(x)

      file = "mydata.inp"
      file(n) = sprintf("run_%d.dat",n)

The final two examples illustrate a user-defined string variable and a user-defined string function.

Note that the variables ‘pi‘ (3.14159...) and NaN (IEEE "Not a Number") are already defined. You can redefine these to something else if you really need to. The original values can be recovered by setting:

      NaN = GPVAL_NaN
      pi  = GPVAL_pi

Other variables may be defined under various gnuplot operations like mousing in interactive terminals or fitting; see variables for details.

You can check for existence of a given variable V by the exists("V") expression. For example

      a = 10
      if (exists("a")) print "a is defined"
      if (!exists("b")) print "b is not defined"

Valid names are the same as in most programming languages: they must begin with a letter, but subsequent characters may be letters, digits, or "_".

Each function definition is made available as a special string-valued variable with the prefix ’GPFUN_’.


      set label GPFUN_sinc at graph .05,.95

See functions, functions, variables, macros, value.

1.16.8 Arrays

Arrays are implemented as indexed lists of user variables. The elements in an array are not limited to a single type of variable. Arrays must be created explicitly before being referenced. The size of an array cannot be changed after creation. All elements are initially undefined. In most places an array element can be used instead of a named user variable.

The cardinality (number of elements) of array A is given by the expression |A|.


     array A[6]
     A[1] = 1
     A[2] = 2.0
     A[3] = {3.0, 3.0}
     A[4] = "four"
     A[6] = A[2]**3
     array B[6] = [ 1, 2.0, A[3], "four", , B[2]**3 ]

     do for [i=1:6] { print A[i], B[i] }
         1 1
         2.0 2.0
         {3.0, 3.0} {3.0, 3.0}
         four four
         <undefined> <undefined>
         8.0 8.0

Note: Arrays and variables share the same namespace. For example, assignment of a string variable named FOO will destroy any previously created array with name FOO.

The name of an array can be used in a ‘plot‘, ‘splot‘, fit, or ‘stats‘ command. This is equivalent to providing a file in which column 1 holds the array index (from 1 to size), column 2 holds the value of real(A[i]) and column 3 holds the value of imag(A[i]).


     array A[200]
     do for [i=1:200] { A[i] = sin(i * pi/100.) }
     plot A title "sin(x) in centiradians"

When plotting the imaginary component of complex array values, it may be referenced either as imag(A[$1]) or as $3. These two commands are equivalent

     plot A using (real(A[$1])) : (imag(A[$1]))
     plot A using 2:3

1.17 Fonts

Gnuplot does not provide any fonts of its own. It relies on external font handling, the details of which unfortunately vary from one terminal type to another. Brief documentation of font mechanisms that apply to more than one terminal type is given here. For information on font use by other individual terminals, see the documentation for that terminal.

Although it is possible to include non-alphabetic symbols by temporarily switching to a special font, e.g. the Adobe Symbol font, the preferred method is now to choose UTF-8 encoding and treat the symbol like any other character. Alternatively you can specify the unicode entry point for the desired symbol as an escape sequence in enhanced text mode. See encoding, ‘unicode‘, locale, and ‘escape sequences‘.

1.17.1 cairo (pdfcairo, pngcairo, epscairo, wxt terminals)

These terminals find and access fonts using the external fontconfig tool set. Please see the fontconfig user manual. It is usually sufficient in gnuplot to request a font by a generic name and size, letting fontconfig substitute a similar font if necessary. The following will probably all work:

     set term pdfcairo font "sans,12"
     set term pdfcairo font "Times,12"
     set term pdfcairo font "Times-New-Roman,12"

1.17.2 gd (png, gif, jpeg, sixel terminals)

Font handling for the png, gif, jpeg, and sixelgd terminals is done by the library libgd. Five basic fonts are provided directly by libgd. These are ‘tiny‘ (5x8 pixels), ‘small‘ (6x12 pixels), ‘medium‘, (7x13 Bold), ‘large‘ (8x16) or ‘giant‘ (9x15 pixels). These fonts cannot be scaled or rotated. Use one of these keywords instead of the ‘font‘ keyword. E.g.

     set term png tiny

On most systems libgd also provides access to Adobe Type 1 fonts (*.pfa) and TrueType fonts (*.ttf). You must give the name of the font file, not the name of the font inside it, in the form "<face> {,<pointsize>}". <face> is either the full pathname to the font file, or the first part of a filename in one of the directories listed in the GDFONTPATH environmental variable. That is, ’set term png font "Face"’ will look for a font file named either <somedirectory>/Face.ttf or <somedirectory>/Face.pfa. For example, if GDFONTPATH contains ‘/usr/local/fonts/ttf:/usr/local/fonts/pfa‘ then the following pairs of commands are equivalent

     set term png font "arial"
     set term png font "/usr/local/fonts/ttf/arial.ttf"
     set term png font "Helvetica"
     set term png font "/usr/local/fonts/pfa/Helvetica.pfa"

To request a default font size at the same time:

     set term png font "arial,11"

Both TrueType and Adobe Type 1 fonts are fully scalable and rotatable. If no specific font is requested in the "set term" command, gnuplot checks the environmental variable GNUPLOT_DEFAULT_GDFONT to see if there is a preferred default font.

1.17.3 postscript (also encapsulated postscript *.eps)

PostScript font handling is done by the printer or viewing program. Gnuplot can create valid PostScript or encapsulated PostScript (*.eps) even if no fonts at all are installed on your computer. Gnuplot simply refers to the font by name in the output file, and assumes that the printer or viewing program will know how to find or approximate a font by that name.

All PostScript printers or viewers should know about the standard set of Adobe fonts ‘Times-Roman‘, ‘Helvetica‘, ‘Courier‘, and ‘Symbol‘. It is likely that many additional fonts are also available, but the specific set depends on your system or printer configuration. Gnuplot does not know or care about this; the output *.ps or *.eps files that it creates will simply refer to whatever font names you request.


     set term postscript eps font "Times-Roman,12"

will produce output that is suitable for all printers and viewers.

On the other hand

     set term postscript eps font "Garamond-Premier-Pro-Italic"

will produce an output file that contains valid PostScript, but since it refers to a specialized font, only some printers or viewers will be able to display the specific font that was requested. Most will substitute a different font.

However, it is possible to embed a specific font in the output file so that all printers will be able to use it. This requires that the a suitable font description file is available on your system. Note that some font files require specific licensing if they are to be embedded in this way. See ‘postscript fontfile‘ for more detailed description and examples.

1.18 Glossary

Throughout this document an attempt has been made to maintain consistency of nomenclature. This cannot be wholly successful because as ‘gnuplot‘ has evolved over time, certain command and keyword names have been adopted that preclude such perfection. This section contains explanations of the way some of these terms are used.

A "page" or "screen" or "canvas" is the entire area addressable by ‘gnuplot‘. On a desktop it is a full window; on a plotter, it is a single sheet of paper; in svga mode it is the full monitor screen.

A screen may contain one or more "plots". A plot is defined by an abscissa and an ordinate, although these need not actually appear on it, as well as the margins and any text written therein.

A plot contains one "graph". A graph is defined by an abscissa and an ordinate, although these need not actually appear on it.

A graph may contain one or more "lines". A line is a single function or data set. "Line" is also a plotting style. The word will also be used in sense "a line of text". Presumably the context will remove any ambiguity.

The lines on a graph may have individual names. These may be listed together with a sample of the plotting style used to represent them in the "key", sometimes also called the "legend".

The word "title" occurs with multiple meanings in ‘gnuplot‘. In this document, it will always be preceded by the adjective "plot", "line", or "key" to differentiate among them. A 2D graph may have up to four labeled axes. The names of the four axes are "x" for the axis along the bottom border of the plot, "y" for the axis along the left border, "x2" for the top border, and "y2" for the right border. See axes.

A 3D graph may have up to three labeled axes – "x", "y" and "z". It is not possible to say where on the graph any particular axis will fall because you can change the direction from which the graph is seen with view.

When discussing data files, the term "record" will be resurrected and used to denote a single line of text in the file, that is, the characters between newline or end-of-record characters. A "point" is the datum extracted from a single record. A "block" of data is a set of consecutive records delimited by blank records. A line, when referred to in the context of a data file, is a subset of a block. Note that the term "data block" may also be used to refer to a named block inline data (see ‘datablocks‘).

1.19 inline data and datablocks

There are two mechanisms for embedding data into a stream of gnuplot commands. If the special filename ’-’ appears in a plot command, then the lines immediately following the plot command are interpreted as inline data. See special-filenames. Data provided in this way can only be used once, by the plot command it follows.

The second mechanism defines a named data block as a here-document. The named data is persistent and may be referred to by more than one plot command. Example:

     $Mydata << EOD
     11 22 33 first line of data
     44 55 66 second line of data
     # comments work just as in a data file
     77 88 99
     stats $Mydata using 1:3
     plot $Mydata using 1:3 with points, $Mydata using 1:2 with impulses

Data block names must begin with a $ character, which distinguishes them from other types of persistent variables. The end-of-data delimiter (EOD in the example) may be any sequence of alphanumeric characters.

The storage associated with named data blocks can be released using ‘undefine‘ command. ‘undefine $*‘ frees all named data blocks at once.

1.20 iteration

gnuplot supports command iteration and block-structured if/else/while/do constructs. See ‘if‘, ‘while‘, and ‘do‘. Simple iteration is possible inside ‘plot‘ or ‘set‘ commands. See ‘plot for‘. General iteration spanning multiple commands is possible using a block construct as shown below. For a related new feature, see the ‘summation‘ expression type. Here is an example using several of these new syntax features:

      set multiplot layout 2,2
      fourier(k, x) = sin(3./2*k)/k * 2./3*cos(k*x)
      do for [power = 0:3] {
          TERMS = 10**power
          set title sprintf("%g term Fourier series",TERMS)
          plot 0.5 + sum [k=1:TERMS] fourier(k,x) notitle
      unset multiplot

Iteration is controlled by an iteration specifier with syntax

     for [<var> in "string of N elements"]


     for [<var> = <start> : <end> { : <increment> }]

In the first case <var> is a string variable that successively evaluates to single-word substrings 1 to N of the string in the iteration specifier. In the second case <start>, <end>, and <increment> are integers or integer expressions.

With one exception, gnuplot variables are global. There is a single, persistent, list of active variables indexed by name. Assignment to a variable creates or replaces an entry in that list. The only way to remove a variable from that list is the ‘undefine‘ command.

The single exception to this is the variable used in an iteration specifier. The scope of the iteration variable is private to that iteration. You cannot permanently change the value of the iteration variable inside the iterated clause. If the iteration variable has a value prior to iteration, that value will be retained or restored at the end of the iteration. For example, the following commands will print 1 2 3 4 5 6 7 8 9 10 A.

     i = "A"
     do for [i=1:10] { print i; i=10; }
     print i

1.21 linetypes, colors, and styles

In older gnuplot versions, each terminal type provided a set of distinct "linetypes" that could differ in color, in thickness, in dot/dash pattern, or in some combination of color and dot/dash. These colors and patterns were not guaranteed to be consistent across different terminal types although most used the color sequence red/green/blue/magenta/cyan/yellow. You can select this old behaviour via the command ‘set colorsequence classic‘, but by default gnuplot version 5 uses a terminal-independent sequence of 8 colors.

You can further customize the sequence of linetype properties interactively or in an initialization file. See ‘set linetype‘. Several sample initialization files are provided in the distribution package.

The current linetype properties for a particular terminal can be previewed by issuing the test command after setting the terminal type.

Successive functions or datafiles plotted by a single command will be assigned successive linetypes in the current default sequence. You can override this for any individual function, datafile, or plot element by giving explicit line properties in the plot command.


     plot "foo", "bar"                 # plot two files using linetypes 1, 2
     plot sin(x) linetype 4            # use linetype color 4

In general, colors can be specified using named colors, rgb (red, green, blue) components, hsv (hue, saturation, value) components, or a coordinate along the current pm3d palette.


     plot sin(x) lt rgb "violet"       # one of gnuplot's named colors
     plot sin(x) lt rgb "#FF00FF"      # explicit RGB triple in hexadecimal
     plot sin(x) lt palette cb -45     # whatever color corresponds to -45
                                       # in the current cbrange of the palette
     plot sin(x) lt palette frac 0.3   # fractional value along the palette

See colorspec, colornames, ‘hsv‘, palette, cbrange. See also monochrome.

Linetypes also have an associated dot-dash pattern although not all terminal types are capable of using it. Gnuplot version 5 allows you to specify the dot-dash pattern independent of the line color. See dashtype.

1.21.1 colorspec

Many commands allow you to specify a linetype with an explicit color.


      ... {linecolor | lc} {"colorname" | <colorspec> | <n>}
      ... {textcolor | tc} {<colorspec> | {linetype | lt} <n>}
      ... {fillcolor | fc} {<colorspec> | linetype <n> | linestyle <n>}

where <colorspec> has one of the following forms:

      rgbcolor "colorname"    # e.g. "blue"
      rgbcolor "0xRRGGBB"     # string containing hexadecimal constant
      rgbcolor "0xAARRGGBB"   # string containing hexadecimal constant
      rgbcolor "#RRGGBB"      # string containing hexadecimal in x11 format
      rgbcolor "#AARRGGBB"    # string containing hexadecimal in x11 format
      rgbcolor <integer val>  # integer value representing AARRGGBB
      rgbcolor variable       # integer value is read from input file
      palette frac <val>      # <val> runs from 0 to 1
      palette cb <value>      # <val> lies within cbrange
      palette z
      variable                # color index is read from input file
      bgnd                    # background color

The "<n>" is the linetype number the color of which is used, see test.

"colorname" refers to one of the color names built in to gnuplot. For a list of the available names, see colornames.

Hexadecimal constants can be given in quotes as "#RRGGBB" or "0xRRGGBB", where RRGGBB represents the red, green, and blue components of the color and must be between 00 and FF. For example, magenta = full-scale red + full-scale blue could be represented by "0xFF00FF", which is the hexadecimal representation of (255 << 16) + (0 << 8) + (255).

"#AARRGGBB" represents an RGB color with an alpha channel (transparency) value in the high bits. An alpha value of 0 represents a fully opaque color; i.e., "#00RRGGBB" is the same as "#RRGGBB". An alpha value of 255 (FF) represents full transparency.

The color palette is a linear gradient of colors that smoothly maps a single numerical value onto a particular color. Two such mappings are always in effect. ‘palette frac‘ maps a fractional value between 0 and 1 onto the full range of the color palette. ‘palette cb‘ maps the range of the color axis onto the same palette. See cbrange. See also ‘set colorbox‘. You can use either of these to select a constant color from the current palette.

"palette z" maps the z value of each plot segment or plot element into the cbrange mapping of the palette. This allows smoothly-varying color along a 3d line or surface. It also allows coloring 2D plots by palette values read from an extra column of data (not all 2D plot styles allow an extra column).

There are two special color specifiers: ‘bgnd‘ for background color and ‘black‘. background color

Most terminals allow you to set an explicit background color for the plot. The special linetype ‘bgnd‘ will draw in this color, and ‘bgnd‘ is also recognized as a color. Examples:

     # This will erase a section of the canvas by writing over it in the
     # background color
     set term wxt background rgb "gray75"
     set object 1 rectangle from x0,y0 to x1,y1 fillstyle solid fillcolor bgnd
     # This will draw an "invisible" line along the x axis
     plot 0 lt bgnd linecolor variable

‘lc variable‘ tells the program to use the value read from one column of the input data as a linetype index, and use the color belonging to that linetype. This requires a corresponding additional column in the ‘using‘ specifier. Text colors can be set similarly using ‘tc variable‘.


      # Use the third column of data to assign colors to individual points
      plot 'data' using 1:2:3 with points lc variable

      # A single data file may contain multiple sets of data, separated by two
      # blank lines.  Each data set is assigned as index value (see index)
      # that can be retrieved via the `using` specifier `column(-2)`.
      # See `pseudocolumns`.  This example uses to value in column -2 to
      # draw each data set in a different line color.
      plot 'data' using 1:2:(column(-2)) with lines lc variable rgbcolor variable

You can assign a separate color for each data point, line segment, or label in your plot. ‘lc rgbcolor variable‘ tells the program to read RGB color information for each line in the data file. This requires a corresponding additional column in the ‘using‘ specifier. The extra column is interpreted as a 24-bit packed RGB triple. If the value is provided directly in the data file it is easiest to give it as a hexadecimal value (see ‘rgbcolor‘). Alternatively, the ‘using‘ specifier can contain an expression that evaluates to a 24-bit RGB color as in the example below. Text colors are similarly set using ‘tc rgbcolor variable‘.


      # Place colored points in 3D at the x,y,z coordinates corresponding to
      # their red, green, and blue components
      rgb(r,g,b) = 65536 * int(r) + 256 * int(g) + int(b)
      splot "data" using 1:2:3:(rgb($1,$2,$3)) with points lc rgb variable

1.21.2 dashtype

In gnuplot version 5 the dash pattern (dashtype) is a separate property associated with each line, analogous to ‘linecolor‘ or ‘linewidth‘. It is not necessary to place the current terminal in a special mode just to draw dashed lines. I.e. the command ‘set term <termname> {solid|dashed}‘ is now ignored. If backwards compatibility with old scripts written for version 4 is required, the following lines can be used instead:

     if (GPVAL_VERSION >= 5.0) set for [i=1:9] linetype i dashtype i
     if (GPVAL_VERSION < 5.0) set termoption dashed

All lines have the property ‘dashtype solid‘ unless you specify otherwise. You can change the default for a particular linetype using the command ‘set linetype‘ so that it affects all subsequent commands, or you can include the desired dashtype as part of the ‘plot‘ or other command.


      dashtype N          # predefined dashtype invoked by number
      dashtype "pattern"  # string containing a combination of the characters
                          # dot (.) hyphen (-) underscore(_) and space.
      dashtype (s1,e1,s2,e2,s3,e3,s4,e4)  # dash pattern specified by 1 to 4
                          # numerical pairs <solid length>, <emptyspace length>


      # Two functions using linetype 1 but distinguished by dashtype
      plot f1(x) with lines lt 1 dt solid, f2(x) with lines lt 1 dt 3

Some terminals support user-defined dash patterns in addition to whatever set of predefined dash patterns they offer.


     plot f(x) dt 3            # use terminal-specific dash pattern 3
     plot f(x) dt ".. "        # construct a dash pattern on the spot
     plot f(x) dt (2,5,2,15)   # numerical representation of the same pattern
     set dashtype 11 (2,4,4,7) # define new dashtype to be called by index
     plot f(x) dt 11           # plot using our new dashtype

If you specify a dash pattern using a string the program will convert this to a sequence of <solid>,<empty> pairs. Dot "." becomes (2,5), dash "-" becomes (10,10), underscore "_" becomes (20,10), and each space character " " adds 10 to the previous <empty> value. The command dashtype will show both the original string and the converted numerical sequence.

1.21.3 linestyles vs linetypes

A ‘linestyle‘ is a temporary association of properties linecolor, linewidth, dashtype, and pointtype. It is defined using the command ‘set style line‘. Once you have defined a linestyle, you can use it in a plot command to control the appearance of one or more plot elements. In other words, it is just like a linetype except for its lifetime. Whereas ‘linetypes‘ are permanent (they last until you explicitly redefine them), ‘linestyles‘ last until the next reset of the graphics state.


     # define a new line style with terminal-independent color cyan,
     # linewidth 3, and associated point type 6 (a circle with a dot in it).
     set style line 5 lt rgb "cyan" lw 3 pt 6
     plot sin(x) with linespoints ls 5          # user-defined line style 5

1.22 layers

A gnuplot plot is built up by drawing its various components in a fixed order. This order can be modified by assigning some components to a specific layer using the keywords ‘behind‘, ‘back‘, or ‘front‘. For example, to replace the background color of the plot area you could define a colored rectangle with the attribute ‘behind‘.

     set object 1 rectangle from graph 0,0 to graph 1,1 fc rgb "gray" behind

The order of drawing is

     the plot itself
     the plot legend (`key`)

Within each layer elements are drawn in the order

     grid, axis, and border elements
     pixmaps in numerical order
     objects (rectangles, circles, ellipses, polygons) in numerical order
     labels in numerical order
     arrows in numerical order

In the case of multiple plots on a single page (multiplot mode) this order applies separately to each component plot, not to the multiplot as a whole.

1.23 mouse input

Many terminals allow interaction with the current plot using the mouse. Some also support the definition of hotkeys to activate pre-defined functions by hitting a single key while the mouse focus is in the active plot window. It is even possible to combine mouse input with ‘batch‘ command scripts, by invoking the command ‘pause mouse‘ and then using the mouse variables returned by mouse clicking as parameters for subsequent scripted actions. See ‘bind‘ and variables. See also the command ‘set mouse‘.

1.23.1 bind


      bind {allwindows} [<key-sequence>] ["<gnuplot commands>"]
      bind <key-sequence> ""
      reset bind

The ‘bind‘ allows defining or redefining a hotkey, i.e. a sequence of gnuplot commands which will be executed when a certain key or key sequence is pressed while the driver’s window has the input focus. Note that ‘bind‘ is only available if gnuplot was compiled with ‘mouse‘ support and it is used by all mouse-capable terminals. A user-specified binding supersedes any builtin bindings, except that <space> and ’q’ cannot normally be rebound. For an exception, see ‘bind space‘.

Only mouse button 1 can be bound, and only for 2D plots.

You get the list of all hotkeys by typing ‘show bind‘ or ‘bind‘ or by typing the hotkey ’h’ in the graph window.

Key bindings are restored to their default state by ‘reset bind‘.

Note that multikey-bindings with modifiers must be given in quotes.

Normally hotkeys are only recognized when the currently active plot window has focus. ‘bind allwindows <key> ...‘ (short form: ‘bind all <key> ...‘) causes the binding for <key> to apply to all gnuplot plot windows, active or not. In this case gnuplot variable MOUSE_KEY_WINDOW is set to the ID of the originating window, and may be used by the bound command.


- set bindings:

    bind a "replot"
    bind "ctrl-a" "plot x*x"
    bind "ctrl-alt-a" 'print "great"'
    bind Home "set view 60,30; replot"
    bind all Home 'print "This is window ",MOUSE_KEY_WINDOW'

- show bindings:

    bind "ctrl-a"          # shows the binding for ctrl-a
    bind                   # shows all bindings
    show bind              # show all bindings

- remove bindings:

    bind "ctrl-alt-a" ""   # removes binding for ctrl-alt-a
                             (note that builtins cannot be removed)
    reset bind             # installs default (builtin) bindings

- bind a key to toggle something:

  bind "ctrl-r" "v=v+1;if(v%2)set term x11 noraise; else set term x11 raise"

Modifiers (ctrl / alt) are case insensitive, keys not:

    ctrl-alt-a == CtRl-alT-a
    ctrl-alt-a != ctrl-alt-A

List of modifiers (alt == meta):

    ctrl, alt, shift (only valid for Button1 Button2 Button3)

List of supported special keys:

   "BackSpace", "Tab", "Linefeed", "Clear", "Return", "Pause", "Scroll_Lock",
   "Sys_Req", "Escape", "Delete", "Home", "Left", "Up", "Right", "Down",
   "PageUp", "PageDown", "End", "Begin",

   "KP_Space", "KP_Tab", "KP_Enter", "KP_F1", "KP_F2", "KP_F3", "KP_F4",
   "KP_Home", "KP_Left", "KP_Up", "KP_Right", "KP_Down", "KP_PageUp",
   "KP_PageDown", "KP_End", "KP_Begin", "KP_Insert", "KP_Delete", "KP_Equal",
   "KP_Multiply", "KP_Add", "KP_Separator", "KP_Subtract", "KP_Decimal",

   "KP_1" - "KP_9", "F1" - "F12"

The following are window events rather than actual keys

   "Button1" "Button2" "Button3" "Close"

See also help for ‘mouse‘. bind space

If gnuplot was built with configuration option –enable-raise-console, then typing <space> in the plot window raises gnuplot’s command window. This hotkey can be changed to ctrl-space by starting gnuplot as ’gnuplot -ctrlq’, or by setting the XResource ’gnuplot*ctrlq’. See ‘x11 command-line-options‘.

1.23.2 Mouse variables

When ‘mousing‘ is active, clicking in the active window will set several user variables that can be accessed from the gnuplot command line. The coordinates of the mouse at the time of the click are stored in MOUSE_X MOUSE_Y MOUSE_X2 and MOUSE_Y2. The mouse button clicked, and any meta-keys active at that time, are stored in MOUSE_BUTTON MOUSE_SHIFT MOUSE_ALT and MOUSE_CTRL. These variables are set to undefined at the start of every plot, and only become defined in the event of a mouse click in the active plot window. To determine from a script if the mouse has been clicked in the active plot window, it is sufficient to test for any one of these variables being defined.

      plot 'something'
      pause mouse
      if (exists("MOUSE_BUTTON")) call 'something_else'; \
      else print "No mouse click."

It is also possible to track keystrokes in the plot window using the mousing code.

      plot 'something'
      pause mouse keypress
      print "Keystroke ", MOUSE_KEY, " at ", MOUSE_X, " ", MOUSE_Y

When ‘pause mouse keypress‘ is terminated by a keypress, then MOUSE_KEY will contain the ascii character value of the key that was pressed. MOUSE_CHAR will contain the character itself as a string variable. If the pause command is terminated abnormally (e.g. by ctrl-C or by externally closing the plot window) then MOUSE_KEY will equal -1.

Note that after a zoom by mouse, you can read the new ranges as GPVAL_X_MIN, GPVAL_X_MAX, GPVAL_Y_MIN, and GPVAL_Y_MAX, see variables.

1.24 Persist

Many gnuplot terminals (aqua, pm, qt, x11, windows, wxt, ...) open separate display windows on the screen into which plots are drawn. The ‘persist‘ option tells gnuplot to leave these windows open when the main program exits. It has no effect on non-interactive terminal output. For example if you issue the command

     gnuplot -persist -e 'plot [-5:5] sinh(x)'

gnuplot will open a display window, draw the plot into it, and then exit, leaving the display window containing the plot on the screen. You can also specify ‘persist‘ or ‘nopersist‘ when you set a new terminal.

     set term qt persist size 700,500

Depending on the terminal type, some mousing operations may still be possible in the persistent window. However operations like zoom/unzoom that require redrawing the plot are not possible because the main program has exited. If you want to leave a plot window open and fully mouseable after creating the plot, for example when running gnuplot from a script file rather than interactively, see ‘pause mouse close‘.

1.25 Plotting

There are four ‘gnuplot‘ commands which actually create a plot: ‘plot‘, ‘splot‘, replot, and refresh. Other commands control the layout, style, and content of the plot that will eventually be created. ‘plot‘ generates 2D plots. ‘splot‘ generates 3D plots (actually 2D projections, of course). replot reexecutes the previous ‘plot‘ or ‘splot‘ command. refresh is similar to replot but it reuses any previously stored data rather than rereading data from a file or input stream.

Each time you issue one of these four commands it will redraw the screen or generate a new page of output containing all of the currently defined axes, labels, titles, and all of the various functions or data sources listed in the original plot command. If instead you need to place several complete plots next to each other on the same page, e.g. to make a panel of sub-figures or to inset a small plot inside a larger plot, use the command multiplot to suppress generation of a new page for each plot command.

Much of the general information about plotting can be found in the discussion of ‘plot‘; information specific to 3D can be found in the ‘splot‘ section.

‘plot‘ operates in either rectangular or polar coordinates – see ‘set polar‘. ‘splot‘ operates in Cartesian coordinates, but will accept azimuthal or cylindrical coordinates on input. See mapping.

‘plot‘ also lets you use each of the four borders – x (bottom), x2 (top), y (left) and y2 (right) – as an independent axis. The axes option lets you choose which pair of axes a given function or data set is plotted against. A full complement of ‘set‘ commands exists to give you complete control over the scales and labeling of each axis. Some commands have the name of an axis built into their names, such as xlabel. Other commands have one or more axis names as options, such as ‘set logscale xy‘. Commands and options controlling the z axis have no effect on 2D graphs.

‘splot‘ can plot surfaces and contours in addition to points and/or lines. See isosamples for information about defining the grid for a 3D function. See datafile for information about the requisite file structure for 3D data. For contours see contour, cntrlabel, and cntrparam.

In ‘splot‘, control over the scales and labels of the axes are the same as with ‘plot‘ except that there is also a z axis and labeling the x2 and y2 axes is possible only for pseudo-2D plots created using ‘set view map‘.

1.26 Plugins

The set of functions available for plotting or for evaluating expressions can be extended through a plugin mechanism that imports executable functions from a shared library. For example, gnuplot versions through 5.4 do not provide a built-in implementation of the upper incomplete gamma function Q(a,x). You could define an approximation directly in gnuplot like this:

      Q(a,x) = 1. - igamma(a,x)

However this has inherently limited precision as igamma(a,x) approaches 1. If you need a more accurate implementation, it would be better to provide one via a plugin (see below). Once imported, the function can be used just as any other built-in or user-defined function in gnuplot. See import.

The gnuplot distribution includes source code and instructions for creating a plugin library in the directory demo/plugin. You can modify the simple example file ‘demo_plugin.c‘ by replacing one or more of the toy example functions with an implementation of the function you are interested in. This could include invocation of functions from an external mathematical library.

The demo/plugin directory also contains source for a plugin that implements Q(a,x). As noted above, this plugin allows earlier versions of gnuplot to provide the same function ‘uigamma‘ as the current development version.

     import Q(a,x) from "uigamma_plugin"
     uigamma(a,x) = ((x<1 || x<a) ? 1.0-igamma(a,x) : Q(a,x))

1.27 Start-up (initialization)

When gnuplot is run, it first looks for a system-wide initialization file ‘gnuplotrc‘. The location of this file is determined when the program is built and is reported by loadpath. The program then looks in the user’s HOME directory for a file called ‘.gnuplot‘ on Unix-like systems or ‘GNUPLOT.INI‘ on other systems. (OS/2 will look for it in the directory named in the environment variable ‘GNUPLOT‘; Windows will use ‘APPDATA‘). On Unix-like systems gnuplot additionally checks for the file $XDG_CONFIG_HOME/gnuplot/gnuplotrc. Note: The program can be configured to look first in the current directory, but this is not recommended because it is bad security practice.

1.28 String constants, string variables, and string functions

In addition to string constants, most gnuplot commands also accept a string variable, a string expression, or a function that returns a string. For example, the following four methods of creating a plot all result in the same plot title:

      four = "4"
      graph4 = "Title for plot #4"
      graph(n) = sprintf("Title for plot #%d",n)

      plot 'data.4' title "Title for plot #4"
      plot 'data.4' title graph4
      plot 'data.4' title "Title for plot #".four
      plot 'data.4' title graph(4)

Since integers are promoted to strings when operated on by the string concatenation operator (’.’ character), the following method also works:

      N = 4
      plot 'data.'.N title "Title for plot #".N

In general, elements on the command line will only be evaluated as possible string variables if they are not otherwise recognizable as part of the normal gnuplot syntax. So the following sequence of commands is legal, although probably should be avoided so as not to cause confusion:

      plot = "my_datafile.dat"
      title = "My Title"
      plot plot title title

1.28.1 substrings

Substrings can be specified by appending a range specifier to any string, string variable, or string-valued function. The range specifier has the form [begin:end], where begin is the index of the first character of the substring and end is the index of the last character of the substring. The first character has index 1. The begin or end fields may be empty, or contain ’*’, to indicate the true start or end of the original string. E.g. str[:] and str[*:*] both describe the full string str.

1.28.2 string operators

Three binary operators require string operands: the string concatenation operator ".", the string equality operator "eq" and the string inequality operator "ne". The following example will print TRUE.

     if ("A"."B" eq "AB") print "TRUE"

1.28.3 string functions

Gnuplot provides several built-in functions that operate on strings. General formatting functions: see gprintf sprintf. Time formatting functions: see strftime strptime. String manipulation: see ‘substr‘ strstrt trim ‘word‘ words.

1.28.4 string encoding

Gnuplot’s built-in string manipulation functions are sensitive to utf-8 encoding (see encoding). For example

 utf8string = "αβγ"
 strlen(utf8string) returns 3 (number of characters, not number of bytes)
 utf8string[2:2] evaluates to "β"
 strstrt(utf8string,"β") evaluates to 2

1.29 Substitution and Command line macros

When a command line to gnuplot is first read, i.e. before it is interpreted or executed, two forms of lexical substitution are performed. These are triggered by the presence of text in backquotes (ascii character 96) or preceded by @ (ascii character 64).

1.29.1 Substitution of system commands in backquotes

Command-line substitution is specified by a system command enclosed in backquotes. This command is spawned and the output it produces replaces the backquoted text on the command line. Exit status of the system command is returned in variables GPVAL_SYSTEM_ERRNO and GPVAL_SYSTEM_ERRMSG.

CHANGE (differs from versions 4 through 5.2): Internal carriage-return (’\r’) and newline (’\n’) characters are not stripped from the input stream during substitution. This change brings backquote substitution in line with the system() function.

Command-line substitution can be used anywhere on the ‘gnuplot‘ command line except inside strings delimited by single quotes.


This will run the program ‘leastsq‘ and replace ‘leastsq‘ (including backquotes) on the command line with its output:

      f(x) = `leastsq`

or, in VMS

      f(x) = `run leastsq`

These will generate labels with the current time and userid:

      set label "generated on `date +%Y-%m-%d` by `whoami`" at 1,1
      set timestamp "generated on %Y-%m-%d by `whoami`"

1.29.2 Substitution of string variables as macros

The character @ is used to trigger substitution of the current value of a string variable into the command line. The text in the string variable may contain any number of lexical elements. This allows string variables to be used as command line macros. Only string constants may be expanded using this mechanism, not string-valued expressions. For example:

      style1 = "lines lt 4 lw 2"
      style2 = "points lt 3 pt 5 ps 2"
      range1 = "using 1:3"
      range2 = "using 1:5"
      plot "foo" @range1 with @style1, "bar" @range2 with @style2

The line containing @ symbols is expanded on input, so that by the time it is executed the effect is identical to having typed in full

      plot "foo" using 1:3 with lines lt 4 lw 2, \
           "bar" using 1:5 with points lt 3 pt 5 ps 2

The function exists() may be useful in connection with macro evaluation. The following example checks that C can safely be expanded as the name of a user-defined variable:

      C = "pi"
      if (exists(C)) print C," = ", @C

Macro expansion does not occur inside either single or double quotes. However macro expansion does occur inside backquotes.

Macro expansion is handled as the very first thing the interpreter does when looking at a new line of commands and is only done once. Therefore, code like the following will execute correctly:

     A = "c=1"

but this line will not, since the macro is defined on the same line and will not be expanded in time

     A = "c=1"; @A   # will not expand to c=1

Macro expansion inside a bracketed iteration occurs before the loop is executed; i.e. @A will always act as the original value of A even if A itself is reassigned inside the loop.

For execution of complete commands the evaluate command may also be handy.

1.29.3 String variables, macros, and command line substitution

The interaction of string variables, backquotes and macro substitution is somewhat complicated. Backquotes do not block macro substitution, so

      filename = "mydata.inp"
      lines = ` wc --lines @filename | sed "s/ .*//" `

results in the number of lines in mydata.inp being stored in the integer variable lines. And double quotes do not block backquote substitution, so

      mycomputer = "`uname -n`"

results in the string returned by the system command ‘uname -n‘ being stored in the string variable mycomputer.

However, macro substitution is not performed inside double quotes, so you cannot define a system command as a macro and then use both macro and backquote substitution at the same time.

       machine_id = "uname -n"
       mycomputer = "`@machine_id`"  # doesn't work!!

This fails because the double quotes prevent @machine_id from being interpreted as a macro. To store a system command as a macro and execute it later you must instead include the backquotes as part of the macro itself. This is accomplished by defining the macro as shown below. Notice that the sprintf format nests all three types of quotes.

      machine_id = sprintf('"`uname -n`"')
      mycomputer = @machine_id

1.30 Syntax

Options and any accompanying parameters are separated by spaces whereas lists and coordinates are separated by commas. Ranges are separated by colons and enclosed in brackets [], text and file names are enclosed in quotes, and a few miscellaneous things are enclosed in parentheses.

Commas are used to separate coordinates on the ‘set‘ commands ‘arrow‘, ‘key‘, and ‘label‘; the list of variables being fitted (the list after the ‘via‘ keyword on the fit command); lists of discrete contours or the loop parameters which specify them on the cntrparam command; the arguments of the ‘set‘ commands dgrid3d, dummy, isosamples, offsets, origin, samples, size, ‘time‘, and view; lists of tics or the loop parameters which specify them; the offsets for titles and axis labels; parametric functions to be used to calculate the x, y, and z coordinates on the ‘plot‘, replot and ‘splot‘ commands; and the complete sets of keywords specifying individual plots (data sets or functions) on the ‘plot‘, replot and ‘splot‘ commands.

Parentheses are used to delimit sets of explicit tics (as opposed to loop parameters) and to indicate computations in the ‘using‘ filter of the fit, ‘plot‘, replot and ‘splot‘ commands.

(Parentheses and commas are also used as usual in function notation.)

Square brackets are used to delimit ranges given in ‘set‘, ‘plot‘ or ‘splot‘ commands.

Colons are used to separate extrema in ‘range‘ specifications (whether they are given on ‘set‘, ‘plot‘ or ‘splot‘ commands) and to separate entries in the ‘using‘ filter of the ‘plot‘, replot, ‘splot‘ and fit commands.

Semicolons are used to separate commands given on a single command line.

Curly braces are used in the syntax for enhanced text mode and to delimit blocks in if/then/else statements. They are also used to denote complex numbers: {3,2} = 3 + 2i.

1.30.1 Quote Marks

Gnuplot uses three forms of quote marks for delimiting text strings, double-quote (ascii 34), single-quote (ascii 39), and backquote (ascii 96).

Filenames may be entered with either single- or double-quotes. In this manual the command examples generally single-quote filenames and double-quote other string tokens for clarity.

String constants and text strings used for labels, titles, or other plot elements may be enclosed in either single quotes or double quotes. Further processing of the quoted text depends on the choice of quote marks.

Backslash processing of special characters like \n (newline) and \345 (octal character code) is performed only for double-quoted strings. In single-quoted strings, backslashes are just ordinary characters. To get a single-quote (ascii 39) in a single-quoted string, it must be doubled. Thus the strings "d\" s’ b\\" and ’d" s” b\’ are completely equivalent.

Text justification is the same for each line of a multi-line string. Thus the center-justified string

      "This is the first line of text.\nThis is the second line."

will produce

                       This is the first line of text.
                          This is the second line.


      'This is the first line of text.\nThis is the second line.'

will produce

          This is the first line of text.\nThis is the second line.

Enhanced text processing is performed for both double-quoted text and single-quoted text, but only by terminals supporting this mode. See ‘enhanced text‘.

Back-quotes are used to enclose system commands for substitution into the command line. See ‘substitution‘.

1.31 Time/Date data

‘gnuplot‘ supports the use of time and/or date information as input data. This feature is activated by the commands ‘set xdata time‘, ‘set ydata time‘, etc.

Internally all times and dates are converted to the number of seconds from the year 1970. The command timefmt defines the default format for all inputs: data files, ranges, tics, label positions – anything that accepts a time data value defaults to receiving it in this format. Only one default format can be in effect at a given time. Thus if both x and y data in a file are time/date, by default they are interpreted in the same format. However this default can be replaced when reading any particular file or column of input using the ‘timecolumn‘ function in the corresponding ‘using‘ specifier.

The conversion to and from seconds assumes Universal Time (which is the same as Greenwich Standard Time). There is no provision for changing the time zone or for daylight savings. If all your data refer to the same time zone (and are all either daylight or standard) you don’t need to worry about these things. But if the absolute time is crucial for your application, you’ll need to convert to UT yourself.

Commands like xrange will re-interpret the integer according to timefmt. If you change timefmt, and then ‘show‘ the quantity again, it will be displayed in the new timefmt. For that matter, if you reset the data type flag for that axis (e.g. xdata), the quantity will be shown in its numerical form.

The commands ‘set format‘ or ‘set tics format‘ define the format that will be used for tic labels, whether or not input for the specified axis is time/date.

If time/date information is to be plotted from a file, the ‘using‘ option _must_ be used on the ‘plot‘ or ‘splot‘ command. These commands simply use white space to separate columns, but white space may be embedded within the time/date string. If you use tabs as a separator, some trial-and-error may be necessary to discover how your system treats them.

The ‘time‘ function can be used to get the current system time. This value can be converted to a date string with the strftime function, or it can be used in conjunction with ‘timecolumn‘ to generate relative time/date plots. The type of the argument determines what is returned. If the argument is an integer, ‘time‘ returns the current time as an integer, in seconds from 1 Jan 1970. If the argument is real (or complex), the result is real as well. The precision of the fractional (sub-second) part depends on your operating system. If the argument is a string, it is assumed to be a format string, and it is passed to strftime to provide a formatted time/date string.

The following example demonstrates time/date plotting.

Suppose the file "data" contains records like

      03/21/95 10:00  6.02e23

This file can be plotted by

      set xdata time
      set timefmt "%m/%d/%y"
      set xrange ["03/21/95":"03/22/95"]
      set format x "%m/%d"
      set timefmt "%m/%d/%y %H:%M"
      plot "data" using 1:3

which will produce xtic labels that look like "03/21".

Gnuplot tracks time to millisecond precision. Time formats have been modified to match this. Example: print the current time to msec precision

     print strftime("%H:%M:%.3S %d-%b-%Y",time(0.0))
     18:15:04.253 16-Apr-2011

See ‘time_specifiers‘.

2 plotting styles

Many plotting styles are available in gnuplot. They are listed alphabetically below. The commands ‘set style data‘ and ‘set style function‘ change the default plotting style for subsequent ‘plot‘ and ‘splot‘ commands.

You can also specify the plot style explicitly as part of the ‘plot‘ or ‘splot‘ command. If you want to mix plot styles within a single plot, you must specify the plot style for each component.


     plot 'data' with boxes, sin(x) with lines

Each plot style has its own expected set of data entries in a data file. For example, by default the ‘lines‘ style expects either a single column of y values (with implicit x ordering) or a pair of columns with x in the first and y in the second. For more information on how to fine-tune how columns in a file are interpreted as plot data, see ‘using‘.

2.1 arrows

The 2D ‘arrows‘ style draws an arrow with specified length and orientation angle at each point (x,y). Additional input columns may be used to provide variable (per-datapoint) color information or arrow style. It is identical to the 2D style vectors except that each the arrow head is positioned using length + angle rather than delta_x + delta_y. See vectors.

     4 columns:  x  y  length  angle

The keywords ‘with arrows‘ may be followed by inline arrow style properties, a reference to a predefined arrow style, or ‘arrowstyle variable‘ to load the index of the desired arrow style for each arrow from a separate column.

‘length‘ > 0 is interpreted in x-axis coordinates. -1 < ‘length‘ < 0 is interpreted in horizontal graph coordinates; i.e. |length| is a fraction of the total graph width. The program will adjust for differences in x and y scaling or plot aspect ratio so that the visual length is independent of the orientation angle.

‘angle‘ is always specified in degrees.

2.2 Bee swarm plots

"Bee swarm" plots result from applying jitter to separate overlapping points. A typical use is to compare the distribution of y values exhibited by two or more categories of points, where the category determines the x coordinate. See the jitter command for how to control the overlap criteria and the displacement pattern used for jittering. The plots in the figure were created by the same plot command but different jitter settings.

     set jitter
     plot $data using 1:2:1 with points lc variable

2.3 boxerrorbars

The boxerrorbars style is only relevant to 2D data plotting. It is a combination of the boxes and yerrorbars styles. It requires 3, 4, or 5 columns of data. An additional (4th, 5th or 6th) input column may be used to provide variable (per-datapoint) color information (see ‘linecolor‘ and ‘rgbcolor variable‘). The error bar will be drawn in the same color as the border of the box.

     3 columns:  x  y  ydelta
     4 columns:  x  y  ydelta xdelta        # boxwidth != -2
     4 columns:  x  y  ylow  yhigh          # boxwidth == -2
     5 columns:  x  y  ylow  yhigh  xdelta

The boxwidth will come from the fourth column if the y errors are given as "ydelta" and the boxwidth was not previously set to -2.0 (‘set boxwidth -2.0‘) or from the fifth column if the y errors are in the form of "ylow yhigh". The special case ‘boxwidth = -2.0‘ is for four-column data with y errors in the form "ylow yhigh". In this case the boxwidth will be calculated so that each box touches the adjacent boxes. The width will also be calculated in cases where three-column data are used.

The box height is determined from the y error in the same way as it is for the yerrorbars style—either from y-ydelta to y+ydelta or from ylow to yhigh, depending on how many data columns are provided.

2.4 boxes

In 2D plots the boxes style draws a rectangle centered about the given x coordinate that extends from the x axis, i.e. from y=0 not from the graph border, to the given y coordinate. The width of the box can be provided in an additional input column or controlled by boxwidth. Otherwise each box extends to touch the adjacent boxes.

In 3D plots the boxes style draws a box centered at the given [x,y] coordinate that extends from the plane at z=0 to the given z coordinate. The width of the box on x can be provided in a separate input column or via boxwidth. The depth of the box on y is controlled by boxdepth. Boxes do not automatically expand to touch each other as in 2D plots.

2.4.1 2D boxes

boxes uses 2 or 3 columns of basic data. Additional input columns may be used to provide information such as variable line or fill color. See ‘rgbcolor variable‘.

     2 columns:  x  y
     3 columns:  x  y  x_width

The width of the box is obtained in one of three ways. If the input data has a third column, this will be used to set the box width. Otherwise if a width has been set using the boxwidth command, this will be used. If neither of these is available, the width of each box will be calculated so that it touches the adjacent boxes.

The box interiors are drawn using the current fillstyle. Alternatively a fillstyle may be specified in the plot command. See ‘set style fill‘. If no fillcolor is given in the plot command, the current line color is used.


To plot a data file with solid filled boxes with a small vertical space separating them (bargraph):

      set boxwidth 0.9 relative
      set style fill solid 1.0
      plot 'file.dat' with boxes

To plot a sine and a cosine curve in pattern-filled boxes style:

      set style fill pattern
      plot sin(x) with boxes, cos(x) with boxes

The sin plot will use pattern 0; the cos plot will use pattern 1. Any additional plots would cycle through the patterns supported by the terminal driver.

To specify explicit fillstyles and fillcolors for each dataset:

     plot 'file1' with boxes fs solid 0.25 fc 'cyan', \
          'file2' with boxes fs solid 0.50 fc 'blue', \
          'file3' with boxes fs solid 0.75 fc 'magenta', \
          'file4' with boxes fill pattern 1, \
          'file5' with boxes fill empty

2.4.2 3D boxes

boxes requires at least 3 columns of input data. Additional input columns may be used to provide information such as box width or fill color.

     3 columns:  x  y  z
     4 columns:  x  y  z  [x_width or color]
     5 columns:  x  y  z  x_width  color

The last column is used as a color only if the splot command specifies a variable color mode. Examples

     splot 'blue_boxes.dat' using 1:2:3 fc "blue"
     splot 'rgb_boxes.dat' using 1:2:3:4 fc rgb variable
     splot 'category_boxes.dat' using 1:2:3:4:5 lc variable

In the first example all boxes are blue and have the width previously set by boxwidth. In the second example the box width is still taken from boxwidth because the 4th column is interpreted as a 24-bit RGB color. The third example command reads box width from column 4 and interprets the value in column 5 as an integer linetype from which the color is derived.

By default boxes have no thickness; they consist of a single rectangle parallel to the xz plane at the specified y coordinate. You can change this to a true box with four sides and a top by setting a non-zero extent on y. See boxdepth.

3D boxes are processed as pm3d quadrangles rather than as surfaces. Because of this the front/back order of drawing is not affected by hidden3d. Similarly if you want each box face to have a border you must use border rather than border. See pm3d. For best results use a combination of ‘set pm3d depthorder base‘ and lighting.

2.5 boxplot

Boxplots are a common way to represent a statistical distribution of values. Quartile boundaries are determined such that 1/4 of the points have a value equal or less than the first quartile boundary, 1/2 of the points have a value equal or less than the second quartile (median) value, etc. A box is drawn around the region between the first and third quartiles, with a horizontal line at the median value. Whiskers extend from the box to user-specified limits. Points that lie outside these limits are drawn individually.


    # Place a boxplot at x coordinate 1.0 representing the y values in column 5
    plot 'data' using (1.0):5

    # Same plot but suppress outliers and force the width of the boxplot to 0.3
    set style boxplot nooutliers
    plot 'data' using (1.0):5:(0.3)

By default only one boxplot is produced that represents all y values from the second column of the using specification. However, an additional (fourth) column can be added to the specification. If present, the values of that column will be interpreted as the discrete levels of a factor variable. As many boxplots will be drawn as there are levels in the factor variable. The separation between these boxplots is 1.0 by default, but it can be changed by ‘set style boxplot separation‘. By default, the value of the factor variable is shown as a tic label below (or above) each boxplot.


    # Suppose that column 2 of 'data' contains either "control" or "treatment"
    # The following example produces two boxplots, one for each level of the
    # factor
    plot 'data' using (1.0):5:(0):2

The default width of the box can be set via ‘set boxwidth <width>‘ or may be specified as an optional 3rd column in the ‘using‘ clause of the plot command. The first and third columns (x coordinate and width) are normally provided as constants rather than as data columns.

By default the whiskers extend from the ends of the box to the most distant point whose y value lies within 1.5 times the interquartile range. By default outliers are drawn as circles (point type 7). The width of the bars at the end of the whiskers may be controlled using ‘set bars‘ or errorbars.

These default properties may be changed using the boxplot command. See boxplot, ‘bars‘, boxwidth, ‘fillstyle‘, candlesticks.

2.6 boxxyerror

The boxxyerror plot style is only relevant to 2D data plotting. It is similar to the xyerrorbars style except that it draws rectangular areas rather than crosses. It uses either 4 or 6 basic columns of input data. Additional input columns may be used to provide information such as variable line or fill color (see ‘rgbcolor variable‘).

     4 columns:  x  y  xdelta  ydelta
     6 columns:  x  y  xlow  xhigh  ylow  yhigh

The box width and height are determined from the x and y errors in the same way as they are for the xyerrorbars style—either from xlow to xhigh and from ylow to yhigh, or from x-xdelta to x+xdelta and from y-ydelta to y+ydelta, depending on how many data columns are provided.

The 6 column form of the command provides a convenient way to plot rectangles with arbitrary x and y bounds.

An additional (5th or 7th) input column may be used to provide variable (per-datapoint) color information (see ‘linecolor‘ and ‘rgbcolor variable‘).

The interior of the boxes is drawn according to the current fillstyle. See ‘set style fill‘ and boxes for details. Alternatively a new fillstyle may be specified in the plot command.

2.7 candlesticks

The candlesticks style can be used for 2D data plotting of financial data or for generating box-and-whisker plots of statistical data. The symbol is a rectangular box, centered horizontally at the x coordinate and limited vertically by the opening and closing prices. A vertical line segment at the x coordinate extends up from the top of the rectangle to the high price and another down to the low. The vertical line will be unchanged if the low and high prices are interchanged.

Five columns of basic data are required:

      financial data:   date  open  low  high  close
      whisker plot:     x  box_min  whisker_min  whisker_high  box_high

The width of the rectangle can be controlled by the boxwidth command. For backwards compatibility with earlier gnuplot versions, when the boxwidth parameter has not been set then the width of the candlestick rectangle is taken from ‘set errorbars <width>‘.

Alternatively, an explicit width for each box-and-whiskers grouping may be specified in an optional 6th column of data. The width must be given in the same units as the x coordinate.

An additional (6th, or 7th if the 6th column is used for width data) input column may be used to provide variable (per-datapoint) color information (see ‘linecolor‘ and ‘rgbcolor variable‘).

By default the vertical line segments have no crossbars at the top and bottom. If you want crossbars, which are typically used for box-and-whisker plots, then add the keyword ‘whiskerbars‘ to the plot command. By default these whiskerbars extend the full horizontal width of the candlestick, but you can modify this by specifying a fraction of the full width.

The usual convention for financial data is that the rectangle is empty if (open < close) and solid fill if (close < open). This is the behavior you will get if the current fillstyle is set to "empty". See ‘fillstyle‘. If you set the fillstyle to solid or pattern, then this will be used for all boxes independent of open and close values. See also errorbars and financebars. See also the candlestick and finance demos.

Note: To place additional symbols, such as the median value, on a box-and-whisker plot requires additional plot commands as in this example:

  # Data columns:X Min 1stQuartile Median 3rdQuartile Max
  set errorbars 4.0
  set style fill empty
  plot 'stat.dat' using 1:3:2:6:5 with candlesticks title 'Quartiles', \
       ''         using 1:4:4:4:4 with candlesticks lt -1 notitle

  # Plot with crossbars on the whiskers, crossbars are 50% of full width
  plot 'stat.dat' using 1:3:2:6:5 with candlesticks whiskerbars 0.5

See boxwidth, errorbars, ‘set style fill‘, and boxplot.

2.8 circles

The circles style plots a circle with an explicit radius at each data point. The radius is always interpreted in the units of the plot’s horizontal axis (x or x2). The scale on y and the aspect ratio of the plot are both ignored. If the radius is not given in a separate column for each point it is taken from ‘set style circle‘. In this case the radius may use graph or screen coordinates.

Many combinations of per-point and previously set properties are possible. For 2D plots these include

    using x:y
    using x:y:radius
    using x:y:color
    using x:y:radius:color
    using x:y:radius:arc_begin:arc_end
    using x:y:radius:arc_begin:arc_end:color

By default a full circle will be drawn. It is possible to instead plot arc segments by specifying a start and end angle (in degrees) in columns 4 and 5.

A per-circle color may be provided in the last column of the using specifier. In this case the plot command must include a corresponding variable color term such as ‘lc variable‘ or ‘fillcolor rgb variable‘.

For 3D plots the using specifier must contain

    splot DATA using x:y:z:radius:color

where the variable color column is options. See ‘set style circle‘ and ‘set style fill‘.


    # draws circles whose area is proportional to the value in column 3
    set style fill transparent solid 0.2 noborder
    plot 'data' using 1:2:(sqrt($3)) with circles, \
         'data' using 1:2 with linespoints

    # draws Pac-men instead of circles
    plot 'data' using 1:2:(10):(40):(320) with circles

    # draw a pie chart with inline data
    set xrange [-15:15]
    set style fill transparent solid 0.9 noborder
    plot '-' using 1:2:3:4:5:6 with circles lc var
    0    0    5    0    30    1
    0    0    5   30    70    2
    0    0    5   70   120    3
    0    0    5  120   230    4
    0    0    5  230   360    5

The result is similar to using a ‘points‘ plot with variable size points and pointstyle 7, except that the circles will scale with the x axis range. See also ‘set object circle‘ and ‘fillstyle‘.

2.9 ellipses

The ellipses style plots an ellipse at each data point. This style is only relevant for 2D plotting. Each ellipse is described in terms of its center, major and minor diameters, and the angle between its major diameter and the x axis.

     2 columns: x y
     3 columns: x y major_diam
     4 columns: x y major_diam minor_diam
     5 columns: x y major_diam minor_diam angle

If only two input columns are present, they are taken as the coordinates of the centers, and the ellipses will be drawn with the default extent (see ‘set style ellipse‘). The orientation of the ellipse, which is defined as the angle between the major diameter and the plot’s x axis, is taken from the default ellipse style (see ‘set style ellipse‘). If three input columns are provided, the third column is used for both diameters. The orientation angle defaults to zero. If four columns are present, they are interpreted as x, y, major diameter, minor diameter. Note that these are diameters, not radii. An optional 5th column may specify the orientation angle in degrees. The ellipses will also be drawn with their default extent if either of the supplied diameters in the 3-4-5 column form is negative.

In all of the above cases, optional variable color data may be given in an additional last (3th, 4th, 5th or 6th) column. See colorspec.

By default, the major diameter is interpreted in the units of the plot’s horizontal axis (x or x2) while the minor diameter in that of the vertical (y or y2). If the x and y axis scales are not equal, the major/minor diameter ratio will no longer be correct after rotation. This can be changed with the ‘units‘ keyword, however.

There are three alternatives: if ‘units xy‘ is included in the plot specification, the axes will be scaled as described above. ‘units xx‘ ensures that both diameters are interpreted in units of the x axis, while ‘units yy‘ means that both diameters are interpreted in units of the y axis. In the latter two cases the ellipses will have the correct aspect ratio, even if the plot is resized. If ‘units‘ is omitted from the plot command, the setting from ‘set style ellipse‘ will be used.

Example (draws ellipses, cycling through the available line types):

    plot 'data' using 1:2:3:4:(0):0 with ellipses

See also ‘set object ellipse‘, ‘set style ellipse‘ and ‘fillstyle‘.

2.10 dots

The dots style plots a tiny dot at each point; this is useful for scatter plots with many points. Either 1 or 2 columns of input data are required in 2D. Three columns are required in 3D.

For some terminals (post, pdf) the size of the dot can be controlled by changing the linewidth.

     1 column    y         # x is row number
     2 columns:  x  y
     3 columns:  x  y  z   # 3D only (splot)

2.11 filledcurves

The filledcurves style is only used for 2D plotting. It has three variants. The first two variants require either a single function or two columns (x,y) of input data, and may be further modified by the options listed below.


    plot ... with filledcurves [option]

where the option can be one of the following

    [closed | {above | below}
    {x1 | x2 | y | r}[=<a>] | xy=<x>,<y>]

The first variant, ‘closed‘, treats the curve itself as a closed polygon. This is the default if there are two columns of input data.

The second variant is to fill the area between the curve and a given axis, a horizontal or vertical line, or a point.

    filledcurves closed   ... just filled closed curve,
    filledcurves x1       ... x1 axis,
    filledcurves x2       ... x2 axis, etc for y1 and y2 axes,
    filledcurves y=42     ... line at y=42, i.e. parallel to x axis,
    filledcurves xy=10,20 ... point 10,20 of x1,y1 axes (arc-like shape).
    filledcurves above r=1.5  the area of a polar plot outside radius 1.5

The third variant fills the area between two curves sampled at the same set of x coordinates. It requires three columns of input data (x, y1, y2). This is the default if there are three or more columns of input data. If you have a y value in column 2 and an associated error value in column 3 the area of uncertainty can be represented by shading. See also the similar 3D plot style ‘zerrorfill‘.

    3 columns:  x  y  yerror

    plot $DAT using 1:($2-$3):($2+$3) with filledcurves, \
         $DAT using 1:2 smooth mcs with lines

The ‘above‘ and ‘below‘ options apply both to commands of the form

    ... filledcurves above {x1|x2|y|r}=<val>

and to commands of the form

    ... using 1:2:3 with filledcurves below

In either case the option limits the filled area to one side of the bounding line or curve.

Notes: Not all terminal types support this plotting mode.

       The x= and y= keywords are ignored for 3 columns data plots

Zooming a filled curve drawn from a datafile may produce empty or incorrect areas because gnuplot is clipping points and lines, and not areas.

If the values <x>, <y>, or <a> are outside the drawing boundary they are moved to the graph boundary. Then the actual fill area in the case of option xy=<x>,<y> will depend on xrange and yrange.

2.11.1 fill properties

Plotting filledcurves can be further customized by giving a fillstyle (solid/transparent/pattern) or a fillcolor. If no fillstyle (‘fs‘) is given in the plot command then the current default fill style is used. See ‘set style fill‘. If no fillcolor (‘fc‘) is given in the plot command, the usual linetype color sequence is followed.

The {{no}border} property of the fillstyle is honored by filledcurves mode ‘closed‘, the default. It is ignored by all other filledcurves modes. Example:

     plot 'data' with filledcurves fc "cyan" fs solid 0.5 border lc "blue"

2.12 financebars

The financebars style is only relevant for 2D data plotting of financial data. It requires 1 x coordinate (usually a date) and 4 y values (prices).

     5 columns:   date  open  low  high  close

An additional (6th) input column may be used to provide variable (per-record) color information (see ‘linecolor‘ and ‘rgbcolor variable‘).

The symbol is a vertical line segment, located horizontally at the x coordinate and limited vertically by the high and low prices. A horizontal tic on the left marks the opening price and one on the right marks the closing price. The length of these tics may be changed by errorbars. The symbol will be unchanged if the high and low prices are interchanged. See errorbars and candlesticks, and also the finance demo.

2.13 fsteps

The fsteps style is only relevant to 2D plotting. It connects consecutive points with two line segments: the first from (x1,y1) to (x1,y2) and the second from (x1,y2) to (x2,y2). The input column requires are the same as for plot styles ‘lines‘ and ‘points‘. The difference between fsteps and steps is that fsteps traces first the change in y and then the change in x. steps traces first the change in x and then the change in y.

See also steps demo.

2.14 fillsteps

     plot <data> with fillsteps [above|below] [y=<baseline>]

The fillsteps style is only relvant to 2D plotting. It is exactly like the style steps except that the area between the curve and the baseline (default y=0) is filled in the current fill style. The options ‘above‘ and ‘below‘ fill only the portion to one side of the baseline. Note that in moving from one data point to the next, both steps and fillsteps first trace the change in x coordinate and then the change in y coordinate. See steps.

2.15 histeps

The histeps style is only relevant to 2D plotting. It is intended for plotting histograms. Y-values are assumed to be centered at the x-values; the point at x1 is represented as a horizontal line from ((x0+x1)/2,y1) to ((x1+x2)/2,y1). The lines representing the end points are extended so that the step is centered on at x. Adjacent points are connected by a vertical line at their average x, that is, from ((x1+x2)/2,y1) to ((x1+x2)/2,y2). The input column requires are the same as for plot styles ‘lines‘ and ‘points‘.

If autoscale is in effect, it selects the xrange from the data rather than the steps, so the end points will appear only half as wide as the others. See also steps demo.

2.16 histograms

The histograms style is only relevant to 2D plotting. It produces a bar chart from a sequence of parallel data columns. Each element of the ‘plot‘ command must specify a single input data source (e.g. one column of the input file), possibly with associated tic values or key titles. Four styles of histogram layout are currently supported.

      set style histogram clustered {gap <gapsize>}
      set style histogram errorbars {gap <gapsize>} {<linewidth>}
      set style histogram rowstacked
      set style histogram columnstacked
      set style histogram {title font "name,size" tc <colorspec>}

The default style corresponds to ‘set style histogram clustered gap 2‘. In this style, each set of parallel data values is collected into a group of boxes clustered at the x-axis coordinate corresponding to their sequential position (row #) in the selected datafile columns. Thus if <n> datacolumns are selected, the first cluster is centered about x=1, and contains <n> boxes whose heights are taken from the first entry in the corresponding <n> data columns. This is followed by a gap and then a second cluster of boxes centered about x=2 corresponding to the second entry in the respective data columns, and so on. The default gap width of 2 indicates that the empty space between clusters is equivalent to the width of 2 boxes. All boxes derived from any one column are given the same fill color and/or pattern (see ‘set style fill‘).

Each cluster of boxes is derived from a single row of the input data file. It is common in such input files that the first element of each row is a label. Labels from this column may be placed along the x-axis underneath the appropriate cluster of boxes with the ‘xticlabels‘ option to ‘using‘.

The errorbars style is very similar to the ‘clustered‘ style, except that it requires additional columns of input for each entry. The first column holds the height (y value) of that box, exactly as for the ‘clustered‘ style.

     2 columns:        y yerr          bar extends from y-yerr to y+err
     3 columns:        y ymin ymax     bar extends from ymin to ymax

The appearance of the error bars is controlled by the current value of errorbars and by the optional <linewidth> specification.

Two styles of stacked histogram are supported, chosen by the command ‘set style histogram {rowstacked|columnstacked}‘. In these styles the data values from the selected columns are collected into stacks of boxes. Positive values stack upwards from y=0; negative values stack downwards. Mixed positive and negative values will produce both an upward stack and a downward stack. The default stacking mode is ‘rowstacked‘.

The ‘rowstacked‘ style places a box resting on the x-axis for each data value in the first selected column; the first data value results in a box a x=1, the second at x=2, and so on. Boxes corresponding to the second and subsequent data columns are layered on top of these, resulting in a stack of boxes at x=1 representing the first data value from each column, a stack of boxes at x=2 representing the second data value from each column, and so on. All boxes derived from any one column are given the same fill color and/or pattern (see ‘set style fill‘).

The ‘columnstacked‘ style is similar, except that each stack of boxes is built up from a single data column. Each data value from the first specified column yields a box in the stack at x=1, each data value from the second specified column yields a box in the stack at x=2, and so on. In this style the color of each box is taken from the row number, rather than the column number, of the corresponding data field.

Box widths may be modified using the boxwidth command. Box fill styles may be set using the ‘set style fill‘ command.

Histograms always use the x1 axis, but may use either y1 or y2. If a plot contains both histograms and other plot styles, the non-histogram plot elements may use either the x1 or the x2 axis.

One additional style option ‘set style histogram nokeyseparators‘ is relevant only to plots that contain multiple histograms. See newhistogram for additional discussion of this case.

Examples: Suppose that the input file contains data values in columns 2, 4, 6, ... and error estimates in columns 3, 5, 7, ... This example plots the values in columns 2 and 4 as a histogram of clustered boxes (the default style). Because we use iteration in the plot command, any number of data columns can be handled in a single command. See ‘plot for‘.

      set boxwidth 0.9 relative
      set style data histograms
      set style histogram cluster
      set style fill solid 1.0 border lt -1
      plot for [COL=2:4:2] 'file.dat' using COL

This will produce a plot with clusters of two boxes (vertical bars) centered at each integral value on the x axis. If the first column of the input file contains labels, they may be placed along the x-axis using the variant command

      plot for [COL=2:4:2] 'file.dat' using COL:xticlabels(1)

If the file contains both magnitude and range information for each value, then error bars can be added to the plot. The following commands will add error bars extending from (y-<error>) to (y+<error>), capped by horizontal bar ends drawn the same width as the box itself. The error bars and bar ends are drawn with linewidth 2, using the border linetype from the current fill style.

      set errorbars fullwidth
      set style fill solid 1 border lt -1
      set style histogram errorbars gap 2 lw 2
      plot for [COL=2:4:2] 'file.dat' using COL:COL+1

This shows how to plot the same data as a rowstacked histogram. Just to be different, this example lists the separate columns explicitly rather than using iteration.

      set style histogram rowstacked
      plot 'file.dat' using 2, '' using 4:xtic(1)

This will produce a plot in which each vertical bar corresponds to one row of data. Each vertical bar contains a stack of two segments, corresponding in height to the values found in columns 2 and 4 of the datafile. Finally, the commands

      set style histogram columnstacked
      plot 'file.dat' using 2, '' using 4

will produce two vertical stacks, one for each column of data. The stack at x=1 will contain a box for each entry in column 2 of the datafile. The stack at x=2 will contain a box for each parallel entry in column 4 of the datafile.

Because this interchanges gnuplot’s usual interpretation of input rows and columns, the specification of key titles and x-axis tic labels must also be modified accordingly. See the comments given below.

      set style histogram columnstacked
      plot '' u 5:key(1)            # uses first column to generate key titles
      plot '' u 5 title columnhead  # uses first row to generate xtic labels

Note that the two examples just given present exactly the same data values, but in different formats.

2.16.1 newhistogram


     newhistogram {"<title>" {font "name,size"} {tc <colorspec>}}
                  {lt <linetype>} {fs <fillstyle>} {at <x-coord>}

More than one set of histograms can appear in a single plot. In this case you can force a gap between them, and a separate label for each set, by using the newhistogram command. For example

      set style histogram  cluster
      plot newhistogram "Set A", 'a' using 1, '' using 2, '' using 3, \
           newhistogram "Set B", 'b' using 1, '' using 2, '' using 3

The labels "Set A" and "Set B" will appear beneath the respective sets of histograms, under the overall x axis label.

The newhistogram command can also be used to force histogram coloring to begin with a specific color (linetype). By default colors will continue to increment successively even across histogram boundaries. Here is an example using the same coloring for multiple histograms

      plot newhistogram "Set A" lt 4, 'a' using 1, '' using 2, '' using 3, \
           newhistogram "Set B" lt 4, 'b' using 1, '' using 2, '' using 3

Similarly you can force the next histogram to begin with a specified fillstyle. If the fillstyle is set to ‘pattern‘, then the pattern used for filling will be incremented automatically.

Starting a new histogram will normally add a blank entry to the key, so that titles from this set of histogram components will be separated from those of the previous histogram. This blank line may be undesirable if the components have no individual titles. It can be suppressed by modifying the style with ‘set style histogram nokeyseparators‘.

The ‘at <x-coord>‘ option sets the x coordinate position of the following histogram to <x-coord>. For example

       set style histogram cluster
       set style data histogram
       set style fill solid 1.0 border -1
       set xtic 1 offset character 0,0.3
       plot newhistogram "Set A", \
            'file.dat' u 1 t 1, '' u 2 t 2, \
            newhistogram "Set B" at 8, \
            'file.dat' u 2 t 2, '' u 2 t 2

will position the second histogram to start at x=8.

2.16.2 automated iteration over multiple columns

If you want to create a histogram from many columns of data in a single file, it is very convenient to use the plot iteration feature. See ‘plot for‘. For example, to create stacked histograms of the data in columns 3 through 8

      set style histogram columnstacked
      plot for [i=3:8] "datafile" using i title columnhead

2.17 image

The ‘image‘, rgbimage, and rgbalpha plotting styles all project a uniformly sampled grid of data values onto a plane in either 2D or 3D. The input data may be an actual bitmapped image, perhaps converted from a standard format such as PNG, or a simple array of numerical values.

This figure illustrates generation of a heat map from an array of scalar values. The current palette is used to map each value onto the color assigned to the corresponding pixel.

      plot '-' matrix with image
      5 4 3 1 0
      2 2 0 0 1
      0 0 0 1 0
      0 1 2 4 3

Each pixel (data point) of the input 2D image will become a rectangle or parallelipiped in the plot. The coordinates of each data point will determine the center of the parallelipiped. That is, an M x N set of data will form an image with M x N pixels. This is different from the pm3d plotting style, where an M x N set of data will form a surface of (M-1) x (N-1) elements. The scan directions for a binary image data grid can be further controlled by additional keywords. See ‘binary keywords flipx‘, ‘keywords center‘, and ‘keywords rotate‘.

Image data can be scaled to fill a particular rectangle within a 2D plot coordinate system by specifying the x and y extent of each pixel. See ‘binary keywords dx‘ and ‘dy‘. To generate the figure at the right, the same input image was placed multiple times, each with a specified dx, dy, and origin. The input PNG image of a building is 50x128 pixels. The tall building was drawn by mapping this using ‘dx=0.5 dy=1.5‘. The short building used a mapping ‘dx=0.5 dy=0.35‘.

The ‘image‘ style handles input pixels containing a grayscale or color palette value. Thus 2D plots (‘plot‘ command) require 3 columns of data (x,y,value), while 3D plots (‘splot‘ command) require 4 columns of data (x,y,z,value).

The rgbimage style handles input pixels that are described by three separate values for the red, green, and blue components. Thus 5D data (x,y,r,g,b) is needed for ‘plot‘ and 6D data (x,y,z,r,g,b) for ‘splot‘. The individual red, green, and blue components are assumed to lie in the range [0:255]. This matches the convention used in PNG and JPEG files (see filetype). However some data files use an alternative convention in which RGB components are floating point values in the range [0:1]. To use the rgbimage style with such data, first use the command ‘set rgbmax 1.0‘.

The rgbalpha style handles input pixels that contain alpha channel (transparency) information in addition to the red, green, and blue components. Thus 6D data (x,y,r,g,b,a) is needed for ‘plot‘ and 7D data (x,y,z,r,g,b,a) for ‘splot‘. The r, g, b, and alpha components are assumed to lie in the range [0:255]. To plot data for which RGBA components are floating point values in the range [0:1], first use the command ‘set rgbmax 1.0‘.

If only a single data column is provided for the color components of either rgbimage or rgbalpha plots, it is interpreted as containing 32 bit packed ARGB data using the convention that alpha=0 means opaque and alpha=255 means fully transparent. Note that this is backwards from the alpha convention if alpha is supplied in a separate column, but matches the ARGB packing convention for individual commands to set color. See colorspec.

2.17.1 transparency

The rgbalpha plotting style assumes that each pixel of input data contains an alpha value in the range [0:255]. A pixel with alpha = 0 is purely transparent and does not alter the underlying contents of the plot. A pixel with alpha = 255 is purely opaque. All terminal types can handle these two extreme cases. A pixel with 0 < alpha < 255 is partially transparent. Terminal types that do not support partial transparency will round this value to 0 or 255.

2.17.2 image pixels

Some terminals use device- or library-specific optimizations to render image data within a rectangular 2D area. This sometimes produces undesirable output, e.g. bad clipping or scaling, missing edges. The ‘pixels‘ keyword tells gnuplot to use generic code that renders the image pixel-by-pixel instead. This rendering mode is slower and may result in much larger output files, but should produce a consistent rendered view on all terminals. Example:

      plot 'data' with image pixels

2.18 impulses

The impulses style displays a vertical line from y=0 to the y value of each point (2D) or from z=0 to the z value of each point (3D). Note that the y or z values may be negative. Data from additional columns can be used to control the color of each impulse. To use this style effectively in 3D plots, it is useful to choose thick lines (linewidth > 1). This approximates a 3D bar chart.

     1 column:   y
     2 columns:  x  y     # line from [x,0] to [x,y]  (2D)
     3 columns:  x  y  z  # line from [x,y,0] to [x,y,z] (3D)

2.19 labels

The labels style reads coordinates and text from a data file and places the text string at the corresponding 2D or 3D position. 3 or 4 input columns of basic data are required. Additional input columns may be used to provide properties that vary point by point such as text rotation angle (keywords ‘rotate variable‘) or color (see ‘textcolor variable‘).

     3 columns:  x  y  string    # 2D version
     4 columns:  x  y  z  string # 3D version

The font, color, rotation angle and other properties of the printed text may be specified as additional command options (see ‘set label‘). The example below generates a 2D plot with text labels constructed from the city whose name is taken from column 1 of the input file, and whose geographic coordinates are in columns 4 and 5. The font size is calculated from the value in column 3, in this case the population.

  CityName(String,Size) = sprintf("{/=%d %s}", Scale(Size), String)
  plot 'cities.dat' using 5:4:(CityName(stringcolumn(1),$3)) with labels

If we did not want to adjust the font size to a different size for each city name, the command would be much simpler:

  plot 'cities.dat' using 5:4:1 with labels font "Times,8"

If the labels are marked as hypertext then the text only appears if the mouse is hovering over the corresponding anchor point. See hypertext. In this case you must enable the label’s ‘point‘ attribute so that there is a point to act as the hypertext anchor:

  plot 'cities.dat' using 5:4:1 with labels hypertext point pt 7

The labels style can also be used in place of the ‘points‘ style when the set of predefined point symbols is not suitable or not sufficiently flexible. For example, here we define a set of chosen single-character symbols and assign one of them to each point in a plot based on the value in data column 3:

  set encoding utf8
  symbol(z) = "∙□+⊙♠♣♡♢"[int(z):int(z)]
  splot 'file' using 1:2:(symbol($3)) with labels

This example shows use of labels with variable rotation angle in column 4 and textcolor ("tc") in column 5. Note that variable color is always taken from the last column in the ‘using‘ specifier.

  plot $Data using 1:2:3:4:5 with labels tc variable rotate variable

2.20 lines

The ‘lines‘ style connects adjacent points with straight line segments. It may be used in either 2D or 3D plots. The basic form requires 1, 2, or 3 columns of input data. Additional input columns may be used to provide information such as variable line color (see ‘rgbcolor variable‘).

2D form (no "using" spec)

     1 column:   y       # implicit x from row number
     2 columns:  x  y

3D form (no "using" spec)

     1 column:   z       # implicit x from row, y from index
     3 columns:  x  y  z

See also ‘linetype‘, ‘linewidth‘, and ‘linestyle‘.

2.21 linespoints

The linespoints style (short form ‘lp‘) connects adjacent points with straight line segments and then goes back to draw a small symbol at each point. Points are drawn with the default size determined by pointsize unless a specific point size is given in the plot command or a variable point size is provided in an additional column of input data. Additional input columns may also be used to provide information such as variable line color. See ‘lines‘ and ‘points‘.

Two keywords control whether or not every point in the plot is marked with a symbol, ‘pointinterval‘ (short form ‘pi‘) and ‘pointnumber‘ (short form ‘pn‘).

‘pi N‘ or ‘pi -N‘ tells gnuplot to only place a symbol on every Nth point. A negative value for N will erase the portion of line segment that passes underneath the symbol. The size of the erased portion is controlled by pointintervalbox.

‘pn N‘ or ‘pn -N‘ tells gnuplot to label only N of the data points, evenly spaced over the data set. As with ‘pi‘, a negative value for N will erase the portion of line segment that passes underneath the symbol.

2.22 parallelaxes

Parallel axis plots can highlight correlation in a multidimensional data set. Individual columns of input data are each associated with a separately scaled vertical axis. If all columns are drawn from a single file then each line on the plot represents values from a single row of data in that file. It is common to use some discrete categorization to assign line colors, allowing visual exploration of the correlation between this categorization and the axis dimensions.


    set style data parallelaxes
    plot $DATA using col1{:varcol1} {at <xpos>} {<line properties}, \
         $DATA using col2, ...

CHANGE: Version 5.4 of gnuplot introduces a change in the syntax for plot style parallelaxes. The revised syntax allows an unlimited number of parallel axes.

     gnuplot 5.2:   plot $DATA using 1:2:3:4:5 with parallelaxes
     gnuplot 5.4:   plot for [col=1:5] $DATA using col with parallelaxes

The new syntax also allows explicit placement of the parallel vertical axes along the x axis as in the example below. If no explicit x coordinate is provide axis N will be placed at x=N.

     array xpos[5] = [1, 5, 6, 7, 11, 12]
     plot for [col=1:5] $DATA using col with parallelaxes at xpos[col]

By default gnuplot will automatically determine the range and scale of the individual axes from the input data, but the usual ‘set axis range‘ commands can be used to customize this. See paxis.

2.23 Polar plots

Polar plots are generated by changing the current coordinate system to polar before issuing a plot command. The option ‘set polar‘ tells gnuplot to interpret input 2D coordinates as <angle>,<radius> rather than <x>,<y>. Many, but not all, of the 2D plotting styles work in polar mode. The figure shows a combination of plot styles ‘lines‘ and filledcurves. See ‘set polar‘, rrange, ‘set size square‘, theta, ttics.

2.24 points

The ‘points‘ style displays a small symbol at each point. The command pointsize may be used to change the default size of all points. The point type defaults to that of the linetype. See ‘linetype‘. If no ‘using‘ spec is found in the plot command, input data columns are interpreted implicitly in the order

     x y pointsize pointtype color

Any columns beyond the first two (x and y) are optional; they correspond to additional plot properties ‘pointsize variable‘, ‘pointtype variable‘, etc.

The first 8 point types are shared by all terminals. Individual terminals may provide a much larger number of distinct point types. Use the test command to show what is provided by the current terminal settings.

Alternatively any single printable character may be given instead of a numerical point type, as in the example below. You may use any unicode character as the pointtype (assumes utf8 support). See ‘escape sequences‘. Longer strings may be plotted using plot style labels rather than ‘points‘.

     plot f(x) with points pt "#"
     plot d(x) with points pt "\U+2299"

When using the keywords ‘pointtype‘, pointsize, or ‘linecolor‘ in a plot command, the additional keyword ‘variable‘ may be given instead of a number. In this case the corresponding properties of each point are assigned by additional columns of input data. Variable pointsize is always taken from the first additional column provided in a ‘using‘ spec. Variable color is always taken from the last additional column. See colorspec. If all three properties are specified for each point, the order of input data columns is thus

     plot DATA using x:y:pointsize:pointtype:color \
          with points lc variable pt variable ps variable

Note: for information on user-defined program variables, see variables.

2.25 polygons

2D plots:

     plot DATA {using 1:2} with polygons

polygons is currently treated as ‘plot with filledcurves closed‘. Each polygon may be assigned a separate color by providing a third using specifier and the keywords ‘lc variable‘ (value is interpreted as a linetype) or ‘lc rgb variable‘ (value is interpreted as a 24-bit RGB color). Only the color value from the first vertex of the polygon is used. The border line type, if any, is taken from the fill style.

3D plots:

     splot DATA {using x:y:z} with polygons
           {fillstyle <fillstyle spec>}
           {fillcolor <colorspec>}

polygons uses pm3d to render individual triangles, quadrangles, and larger polygons in 3D. These may be facets of a 3D surface or isolated shapes. The code assumes that the vertices lie in a plane. Vertices defining individual polygons are read from successive records of the input file. A blank line separates one polygon from the next. Due to limitations in the pm3d code, a single border line style from border is applied to all 3D polygons. This restriction may be removed in a later gnuplot version. pm3d sort order and lighting are applied to the faces. It is probably always desirable to use ‘set pm3d depthsort‘.

     set xyplane at 0
     set view equal xyz
     unset border
     unset tics
     set pm3d depth
     set pm3d border lc "black" lw 1.5
     splot 'icosahedron.dat' with polygons \
           fs transparent solid 0.8 fc bgnd

2.26 spiderplot

Spider plots are essentially parallel axis plots in which the axes are arranged radially rather than vertically. Such plots are sometimes called ‘rader charts‘. In gnuplot this requires working within a coordinate system established by the command spiderplot, analogous to ‘set polar‘ except that the angular coordinate is determined implicitly by the parallel axis number. The appearance, labelling, and tic placement of the axes is controlled by paxis. Further style choices are controlled using spiderplot, ‘set grid‘, and the individual components of the plot command.

Because each spider plot corresponds to a row of data rather than a column, it would make no sense to generate key entry titles in the normal way. Instead, if a plot component contains a title the text is used to label the corresponding axis. This overrides any previous ‘set paxis n label "Foo"‘. To place a title in the key, you can either use a separate ‘keyentry‘ command or extract text from a column in the input file with the ‘key(column)‘ using specifier. See ‘keyentry‘, ‘using key‘.

In this figure a spiderplot with 5 axes is used to compare multiple entities that are each characterized by five scores. Each line (row) in $DATA generates a new polygon on the plot.

     set spiderplot
     set style spiderplot fs transparent solid 0.2 border
     set for [p=1:5] paxis p range [0:100]
     set for [p=2:5] paxis p tics format ""
     set             paxis 1 tics font ",9"
     set for [p=1:5] paxis p label sprintf("Score %d",p)
     set grid spiderplot
     plot for [i=1:5] $DATA using i:key(1)

2.26.1 newspiderplot

Normally the sequential elements of a plot command spiderplot each correspond to one vertex of a single polygon. In order to describe multiple polygons in the same plot command, they must be separated by newspiderplot. Example:

     # One polygon with 10 vertices
     plot for [i=1:5] 'A' using i, for [j=1:5] 'B' using j
     # Two polygons with 5 vertices
     plot for [i=1:5] 'A' using i, newspiderplot, for [j=1:5] 'B' using j

2.27 steps

The steps style is only relevant to 2D plotting. It connects consecutive points with two line segments: the first from (x1,y1) to (x2,y1) and the second from (x2,y1) to (x2,y2). The input column requires are the same as for plot styles ‘lines‘ and ‘points‘. The difference between fsteps and steps is that fsteps traces first the change in y and then the change in x. steps traces first the change in x and then the change in y. To fill the area between the curve and the baseline at y=0, use fillsteps. See also steps demo.

2.28 rgbalpha

See ‘image‘.

2.29 rgbimage

See ‘image‘.

2.30 vectors

The 2D vectors style draws a vector from (x,y) to (x+xdelta,y+ydelta). The 3D vectors style is similar, but requires six columns of basic data. In both cases, an additional input column (5th in 2D, 7th in 3D) may be used to provide variable (per-datapoint) color information. (see ‘linecolor‘ and ‘rgbcolor variable‘). A small arrowhead is drawn at the end of each vector.

     4 columns:  x  y  xdelta  ydelta
     6 columns:  x  y  z  xdelta  ydelta  zdelta

The keywords "with vectors" may be followed by inline arrow style properties, by reference to a predefined arrow style, or by a request to read the index of the desired arrow style for each vector from a separate input column. See the first three examples below.


     plot ... using 1:2:3:4 with vectors filled heads
     plot ... using 1:2:3:4 with vectors arrowstyle 3
     plot ... using 1:2:3:4:5 with vectors arrowstyle variable
     splot 'file.dat' using 1:2:3:(1):(1):(1) with vectors filled head lw 2

Notes: You cannot mix the ‘arrowstyle‘ keyword with other line style qualifiers in the plot command. An additional column of color values is required if the arrow style includes ‘lc variable‘ or ‘lc rgb variable‘.

splot with vectors is supported only for ‘set mapping cartesian‘. ‘set clip one‘ and ‘set clip two‘ affect vectors drawn in 2D. See ‘set clip‘ and ‘arrowstyle‘.

See also the 2D plot style ‘with arrows‘ that is identical to vectors except that each arrow is specified using x:y:length:angle.

2.31 xerrorbars

The xerrorbars style is only relevant to 2D data plots. xerrorbars is like ‘points‘, except that a horizontal error bar is also drawn. At each point (x,y), a line is drawn from (xlow,y) to (xhigh,y) or from (x-xdelta,y) to (x+xdelta,y), depending on how many data columns are provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. The basic style requires either 3 or 4 columns:

     3 columns:  x  y  xdelta
     4 columns:  x  y  xlow  xhigh

An additional input column (4th or 5th) may be used to provide variable color. This style does not permit variable point properties.

2.32 xyerrorbars

The xyerrorbars style is only relevant to 2D data plots. xyerrorbars is like ‘points‘, except that horizontal and vertical error bars are also drawn. At each point (x,y), lines are drawn from (x,y-ydelta) to (x,y+ydelta) and from (x-xdelta,y) to (x+xdelta,y) or from (x,ylow) to (x,yhigh) and from (xlow,y) to (xhigh,y), depending upon the number of data columns provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. Either 4 or 6 input columns are required.

     4 columns:  x  y  xdelta  ydelta
     6 columns:  x  y  xlow  xhigh  ylow  yhigh

If data are provided in an unsupported mixed form, the ‘using‘ filter on the ‘plot‘ command should be used to set up the appropriate form. For example, if the data are of the form (x,y,xdelta,ylow,yhigh), then you can use

      plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

An additional input column (5th or 7th) may be used to provide variable color. This style does not permit variable point properties.

2.33 yerrorbars

The yerrorbars (or errorbars) style is only relevant to 2D data plots. yerrorbars is like ‘points‘, except that a vertical error bar is also drawn. At each point (x,y), a line is drawn from (x,y-ydelta) to (x,y+ydelta) or from (x,ylow) to (x,yhigh), depending on how many data columns are provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. The clearance between the point and the error bars is controlled by pointintervalbox.

     2 columns:  [implicit x] y ydelta
     3 columns:  x  y  ydelta
     4 columns:  x  y  ylow  yhigh

Additional input columns may be used to provide information such as variable point size, point type, or color.

See also errorbar demo.

2.34 xerrorlines

The xerrorlines style is only relevant to 2D data plots. xerrorlines is like linespoints, except that a horizontal error line is also drawn. At each point (x,y), a line is drawn from (xlow,y) to (xhigh,y) or from (x-xdelta,y) to (x+xdelta,y), depending on how many data columns are provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. The basic style requires either 3 or 4 columns:

     3 columns:  x  y  xdelta
     4 columns:  x  y  xlow  xhigh

An additional input column (4th or 5th) may be used to provide variable color. This style does not permit variable point properties.

2.35 xyerrorlines

The xyerrorlines style is only relevant to 2D data plots. xyerrorlines is like linespoints, except that horizontal and vertical error bars are also drawn. At each point (x,y), lines are drawn from (x,y-ydelta) to (x,y+ydelta) and from (x-xdelta,y) to (x+xdelta,y) or from (x,ylow) to (x,yhigh) and from (xlow,y) to (xhigh,y), depending upon the number of data columns provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. Either 4 or 6 input columns are required.

     4 columns:  x  y  xdelta  ydelta
     6 columns:  x  y  xlow  xhigh  ylow  yhigh

If data are provided in an unsupported mixed form, the ‘using‘ filter on the ‘plot‘ command should be used to set up the appropriate form. For example, if the data are of the form (x,y,xdelta,ylow,yhigh), then you can use

      plot 'data' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines

An additional input column (5th or 7th) may be used to provide variable color. This style does not permit variable point properties.

2.36 yerrorlines

The yerrorlines (or errorlines) style is only relevant to 2D data plots. yerrorlines is like linespoints, except that a vertical error line is also drawn. At each point (x,y), a line is drawn from (x,y-ydelta) to (x,y+ydelta) or from (x,ylow) to (x,yhigh), depending on how many data columns are provided. The appearance of the tic mark at the ends of the bar is controlled by errorbars. Either 3 or 4 input columns are required.

     3 columns:  x  y  ydelta
     4 columns:  x  y  ylow  yhigh

Additional input columns may be used to provide information such as variable point size, point type, or color.

See also errorbar demo.

2.37 3D plots

3D plots are generated using the command ‘splot‘ rather than ‘plot‘. Many of the 2D plot styles (points, images, impulse, labels, vectors) can also be used in 3D by providing an extra column of data containing z coordinate. Some plot types (pm3d coloring, surfaces, contours) must be generated using the ‘splot‘ command even if only a 2D projection is wanted.

2.37.1 Surface plots

The styles ‘splot with lines‘ and surface both generate a surface made from a grid of lines. Solid surfaces can be generated using the style pm3d. Usually the surface is displayed at some convenient viewing angle, such that it clearly represents a 3D surface. See view. In this case the X, Y, and Z axes are all visible in the plot. The illusion of 3D is enhanced by choosing hidden line removal. See hidden3d. The ‘splot‘ command can also calculate and draw contour lines corresponding to constant Z values. These contour lines may be drawn onto the surface itself, or projected onto the XY plane. See contour.

2.37.2 2D projection (set view map)

An important special case of the ‘splot‘ command is to map the Z coordinate onto a 2D surface by projecting the plot along the Z axis onto the xy plane. See ‘set view map‘. This plot mode is useful for contour plots and heat maps. This figure shows contours plotted once with plot style ‘lines‘ and once with style labels.

2.37.3 PM3D plots

3D surfaces can also be drawn using solid pm3d quadrangles rather than lines. In this case there is no hidden surface removal, but if the component facets are drawn back-to-front then a similar effect is achieved. See ‘set pm3d depthorder‘. While pm3d surfaces are by default colored using a smooth color palette (see palette), it is also possible to specify a solid color surface or to specify distinct solid colors for the top and bottom surfaces as in the figure shown here. See fillcolor. Unlike the line-trimming in hidden3d mode, pm3d surfaces can be smoothly clipped to the current zrange. See clipping.

2.38 Fence plots

Fence plots combine several 2D plots by aligning their Y coordinates and separating them from each other by a displacement along X. Filling the area between a base value and each plot’s series of Z values enhances the visual impact of the alignment on Y and comparison on Z. There are several ways such plots can be created in gnuplot. The simplest is to use the 5 column variant of the ‘zerrorfill‘ style. Suppose there are separate curves z = Fi(y) indexed by i. A fence plot is generated by ‘splot with zerrorfill‘ using input columns

     i y z_base z_base Fi(y)

2.39 isosurface

This 3D plot style requires a populated voxel grid (see vgrid, vfill). Linear interpolation of voxel grid values is used to estimate fractional grid coordinates corresponding to the requested isolevel. These points are then used to generate a tessellated surface. The facets making up the surface are rendered as pm3d polygons, so the surface coloring, transparency, and border properties are controlled by pm3d. In general the surface is easier to interpret visually if facets are given a thin border that is darker than the fill color. By default the tessellation uses a mixture of quadrangles and triangles. To use triangle only, see isosurface. Example:

     set style fill solid 0.3
     set pm3d depthorder border lc "blue" lw 0.2
     splot $helix with isosurface level 10 fc "cyan"

2.40 Zerrorfill


     splot DATA using 1:2:3:4[:5] with zerrorfill {fc|fillcolor <colorspec>}
                {lt|linetype <n>} {<line properties>}

The ‘zerrorfill‘ plot style is similar to one variant of the 2D plot style filledcurves. It fills the area between two functions or data lines that are sampled at the same x and y points. It requires 4 or 5 input columns:

     4 columns:  x  y  z  zdelta
     5 columns:  x  y  z  zlow  zhigh

The area between zlow and zhigh is filled and then a line is drawn through the z values. By default both the line and the fill area use the same color, but you can change this in the splot command. The fill area properties are also affected by the global fill style; see ‘set style fill‘.

If there are multiple curves in the splot command each new curve may occlude all previous curves. To get proper depth sorting so that curves can only be occluded by curves closer to the viewer, use ‘set pm3d depthorder base‘. Unfortunately this causes all the filled areas to be drawn after all of the corresponding lines of z values. In order to see both the lines and the depth-sorted fill areas you probably will need to make the fill areas partially transparent or use pattern fill rather than solid fill.

The fill area in the first two examples below is the same.

     splot 'data' using 1:2:3:4 with zerrorfill fillcolor "grey" lt black
     splot 'data' using 1:2:3:($3-$4):($3+$4) with zerrorfill
     splot '+' using 1:(const):(func1($1)):(func2($1)) with zerrorfill
     splot for [k=1:5] datafile[k] with zerrorfill lt black fc lt (k+1)

This plot style can also be used to create fence plots. See ‘fenceplots‘.

3 Commands

This section lists the commands acceptable to ‘gnuplot‘ in alphabetical order. Printed versions of this document contain all commands; the text available interactively may not be complete. Indeed, on some systems there may be no commands at all listed under this heading.

Note that in most cases unambiguous abbreviations for command names and their options are permissible, i.e., "‘p f(x) w li‘" instead of "‘plot f(x) with lines‘".

In the syntax descriptions, braces ({}) denote optional arguments and a vertical bar (|) separates mutually exclusive choices.

3.1 Break

The ‘break‘ command is only meaningful inside the bracketed iteration clause of a ‘do‘ or ‘while‘ statement. It causes the remaining statements inside the bracketed clause to be skipped and iteration is terminated. Execution resumes at the statement following the closing bracket. See also ‘continue‘.

3.2 cd

The ‘cd‘ command changes the working directory.


      cd '<directory-name>'

The directory name must be enclosed in quotes.


      cd 'subdir'
      cd ".."

It is recommended that Windows users use single-quotes, because backslash [\] has special significance inside double-quotes and has to be escaped. For example,

      cd "c:\newdata"

fails, but

      cd 'c:\newdata'
      cd "c:\\newdata"

work as expected.

3.3 call

The call command is identical to the ‘load‘ command with one exception: the name of the file being loaded may be followed by up to nine parameters.

     call "inputfile" <param-1> <param-2> <param-3> ... <param-9>

Previous versions of gnuplot performed macro-like substitution of the special tokens $0, $1, ... $9 with the literal contents of these parameters. This mechanism is now deprecated (see old-style).

Gnuplot now provides a set of string variables ARG0, ARG1, ..., ARG9 and an integer variable ARGC. When a call command is executed ARG0 is set to the name of the input file, ARGC is set to the number of parameters present, and ARG1 to ARG9 are loaded from the parameters that follow it on the command line. Any existing contents of the ARG variables are saved and restored across a call command.

Because the parameters ARG1 ... ARG9 are stored in ordinary string variables they may be dereferenced by macro expansion (analogous to the older deprecated syntax). However in many cases it is more natural to use them as you would any other variable.

In parallel to the string parameters ARG1 ... ARG9, the passed parameters are stored in an array ARGV[9]. See ‘argv‘.

3.3.1 argv[ ]

When a gnuplot script is entered via the call command any parameters passed by the caller are available via two mechanisms. Each parameter is stored as a string in variables ARG1, ARG2, ... ARG9. Each parameter is also stored as one element of the array ARGV[9]. Numerical values are stored as complex variables. All other values are stored as strings. Thus after a call

     call ''  1 pi "title"

The three arguments are available inside as follows

     ARG1 = "1"         ARGV[1] = 1.0
     ARG2 = "3.14159"   ARGV[2] = 3.14159265358979...
     ARG3 = "title"     ARGV[3] = "title"

In this example ARGV[1] and ARGV[2] have the full precision of a floating point variable. ARG2 lost precision in being stored as a string using format "%g".

3.3.2 Example

     Call site
         MYFILE = ""
         FUNC = "sin(x)"
         call MYFILE FUNC 1.23 "This is a plot title"
     Upon entry to the called script
         ARG0 holds ""
         ARG1 holds the string "sin(x)"
         ARG2 holds the string "1.23"
         ARG3 holds the string "This is a plot title"
         ARGC is 3
     The script itself can now execute
         plot @ARG1 with lines title ARG3
         print ARG2 * 4.56, @ARG2 * 4.56
         print "This plot produced by script ", ARG0

Notice that because ARG1 is a string it must be dereferenced as a macro, but ARG2 may be dereferenced either as a macro (yielding a numerical constant) or a variable (yielding that same numerical value after auto-promotion of the string "1.23" to a real).

The same result could be obtained directly from a shell script by invoking gnuplot with the ‘-c‘ command line option:

     gnuplot -persist -c "" "sin(x)" 1.23 "This is a plot title"

3.3.3 old-style

This describes the deprecated call mechanism used by old versions of gnuplot.

      call "<input-file>" <param-0> <param-1> ... <param-9>

The name of the input file must be enclosed in quotes. As each line is read from the input file, it is scanned for the following special character sequences: $0 $1 $2 $3 $4 $5 $6 $7 $8 $9 $#. If found, the sequence ‘$‘+digit is replaced by the corresponding parameter from the call command line. Quote characters are not copied and string variable substitution is not performed. The character sequence ‘$#‘ is replaced by the number of passed parameters. ‘$‘ followed by any other character is treated as an escape sequence; use ‘$$‘ to get a single ‘$‘.


If the file ’’ contains the line:

      print "argc=$# p0=$0 p1=$1 p2=$2 p3=$3 p4=$4 p5=$5 p6=$6 p7=x$7x"

entering the command:

      call '' "abcd" 1.2 + "'quoted'" -- "$2"

will display:

      argc=7 p0=abcd p1=1.2 p2=+ p3='quoted' p4=- p5=- p6=$2 p7=xx

NOTES: This use of the ‘$‘ character conflicts both with gnuplot’s own syntax for datafile columns and with the use of ‘$‘ to indicate environmental variables in a unix-like shell. The special sequence ‘$#‘ was mis-interpreted as a comment delimiter in gnuplot versions 4.5 through 4.6.3. Quote characters are ignored during substitution, so string constants are easily corrupted.

3.4 clear

The clear command erases the current screen or output device as specified by terminal and output. This usually generates a formfeed on hardcopy devices.

For some terminals clear erases only the portion of the plotting surface defined by size, so for these it can be used in conjunction with multiplot to create an inset.


      set multiplot
      plot sin(x)
      set origin 0.5,0.5
      set size 0.4,0.4
      plot cos(x)
      unset multiplot

Please see multiplot, size, and origin for details.

3.5 Continue

The ‘continue‘ command is only meaningful inside the bracketed iteration clause of a ‘do‘ or ‘while‘ statement. It causes the remaining statements inside the bracketed clause to be skipped. Execution resumes at the start of the next iteration (if any remain in the loop condition). See also ‘break‘.

3.6 Do


      do for <iteration-spec> {

Execute a sequence of commands multiple times. The commands must be enclosed in curly brackets, and the opening "{" must be on the same line as the ‘do‘ keyword. This command cannot be used with old-style (un-bracketed) if/else statements. See ‘if‘. For examples of iteration specifiers, see iteration. Example:

      set multiplot layout 2,2
      do for [name in "A B C D"] {
          filename = name . ".dat"
          set title sprintf("Condition %s",name)
          plot filename title name
      unset multiplot

See also ‘while‘, ‘continue‘, ‘break‘.

3.7 evaluate

The evaluate command executes the commands given as an argument string. Newline characters are not allowed within the string.


      eval <string expression>

This is especially useful for a repetition of similar commands.


      set_label(x, y, text) \
        = sprintf("set label '%s' at %f, %f point pt 5", text, x, y)
      eval set_label(1., 1., 'one/one')
      eval set_label(2., 1., 'two/one')
      eval set_label(1., 2., 'one/two')

Please see macros for another way to execute commands from a string.

3.8 exit

     exit message "error message text"
     exit status <integer error code>

The commands exit and quit, as well as the END-OF-FILE character (usually Ctrl-D) terminate input from the current input stream: terminal session, pipe, or file input (pipe). If input streams are nested (inherited ‘load‘ scripts), then reading will continue in the parent stream. When the top level stream is closed, the program itself will exit.

The command ‘exit gnuplot‘ will immediately and unconditionally cause gnuplot to exit even if the input stream is multiply nested. In this case any open output files may not be completed cleanly. Example of use:

      bind "ctrl-x" "unset output; exit gnuplot"

The command ‘exit error "error message"‘ simulates a program error. In interactive mode it prints the error message and returns to the command line, breaking out of all nested loops or calls. In non-interactive mode the program will exit.

When gnuplot exits to the controlling shell, the return value is not usually informative. This variant of the command allows you to return a specific value.

     exit status <value>

See help for ‘batch/interactive‘ for more details.

3.9 fit

The fit command fits a user-supplied real-valued expression to a set of data points, using the nonlinear least-squares Marquardt-Levenberg algorithm. There can be up to 12 independent variables, there is always 1 dependent variable, and any number of parameters can be fitted. Optionally, error estimates can be input for weighting the data points.

The basic use of fit is best explained by a simple example:

      f(x) = a + b*x + c*x**2
      fit f(x) 'measured.dat' using 1:2 via a,b,c
      plot 'measured.dat' u 1:2, f(x)


      fit {<ranges>} <expression>
          '<datafile>' {datafile-modifiers}
          {{unitweights} | {y|xy|z}error | errors <var1>{,<var2>,...}}
          via '<parameter file>' | <var1>{,<var2>,...}

Ranges may be specified to filter the data used in fitting. Out-of-range data points are ignored. The syntax is


analogous to ‘plot‘; see ranges.

<expression> can be any valid ‘gnuplot‘ expression, although the most common is a previously user-defined function of the form f(x) or f(x,y). It must be real-valued. The names of the independent variables are set by the dummy command, or in the <ranges> part of the command (see below); by default, the first two are called x and y. Furthermore, the expression should depend on one or more variables whose value is to be determined by the fitting procedure.

<datafile> is treated as in the ‘plot‘ command. All the datafile modifiers (‘using‘, every,...) except smooth are applicable to fit. See datafile.

The datafile contents can be interpreted flexibly by providing a ‘using‘ qualifier as with plot commands. For example to generate the independent variable x as the sum of columns 2 and 3, while taking z from column 6 and requesting equal weights:

      fit ... using ($2+$3):6

In the absence of a ‘using‘ specification, the fit implicitly assumes there is only a single independent variable. If the file itself, or the using specification, contains only a single column of data, the line number is taken as the independent variable. If a ‘using‘ specification is given, there can be up to 12 independent variables (and more if specially configured at compile time).

The ‘unitweights‘ option, which is the default, causes all data points to be weighted equally. This can be changed by using the ‘errors‘ keyword to read error estimates of one or more of the variables from the data file. These error estimates are interpreted as the standard deviation s of the corresponding variable value and used to compute a weight for the datum as 1/s**2.

In case of error estimates of the independent variables, these weights are further multiplied by fitting function derivatives according to the "effective variance method" (Jay Orear, Am. J. Phys., Vol. 50, 1982).

The ‘errors‘ keyword is to be followed by a comma-separated list of one or more variable names for which errors are to be input; the dependent variable z must always be among them, while independent variables are optional. For each variable in this list, an additional column will be read from the file, containing that variable’s error estimate. Again, flexible interpretation is possible by providing the ‘using‘ qualifier. Note that the number of independent variables is thus implicitly given by the total number of columns in the ‘using‘ qualifier, minus 1 (for the dependent variable), minus the number of variables in the ‘errors‘ qualifier.

As an example, if one has 2 independent variables, and errors for the first independent variable and the dependent variable, one uses the ‘errors x,z‘ qualifier, and a ‘using‘ qualifier with 5 columns, which are interpreted as x:y:z:sx:sz (where x and y are the independent variables, z the dependent variable, and sx and sz the standard deviations of x and z).

A few shorthands for the ‘errors‘ qualifier are available: ‘yerrors‘ (for fits with 1 column of independent variable), and ‘zerrors‘ (for the general case) are all equivalent to ‘errors z‘, indicating that there is a single extra column with errors of the dependent variable.

‘xyerrors‘, for the case of 1 independent variable, indicates that there are two extra columns, with errors of both the independent and the dependent variable. In this case the errors on x and y are treated by Orear’s effective variance method.

Note that ‘yerror‘ and ‘xyerror‘ are similar in both form and interpretation to the yerrorlines and xyerrorlines 2D plot styles.

With the command ‘set fit v4‘ the fit command syntax is compatible with ‘gnuplot‘ version 4. In this case there must be two more ‘using‘ qualifiers (z and s) than there are independent variables, unless there is only one variable. ‘gnuplot‘ then uses the following formats, depending on the number of columns given in the ‘using‘ specification:

      z                           # 1 independent variable (line number)
      x:z                         # 1 independent variable (1st column)
      x:z:s                       # 1 independent variable (3 columns total)
      x:y:z:s                     # 2 independent variables (4 columns total)
      x1:x2:x3:z:s                # 3 independent variables (5 columns total)
      x1:x2:x3:...:xN:z:s         # N independent variables (N+2 columns total)

Please beware that this means that you have to supply z-errors s in a fit with two or more independent variables. If you want unit weights you need to supply them explicitly by using e.g. then format x:y:z:(1).

The dummy variable names may be changed when specifying a range as noted above. The first range corresponds to the first ‘using‘ spec, and so on. A range may also be given for z (the dependent variable), in which case data points for which f(x,...) is out of the z range will not contribute to the residual being minimized.

Multiple datasets may be simultaneously fit with functions of one independent variable by making y a ’pseudo-variable’, e.g., the dataline number, and fitting as two independent variables. See multi-branch.

The ‘via‘ qualifier specifies which parameters are to be optimized, either directly, or by referencing a parameter file.


      f(x) = a*x**2 + b*x + c
      g(x,y) = a*x**2 + b*y**2 + c*x*y
      set fit limit 1e-6
      fit f(x) 'measured.dat' via 'start.par'
      fit f(x) 'measured.dat' using 3:($7-5) via 'start.par'
      fit f(x) './data/trash.dat' using 1:2:3 yerror via a, b, c
      fit g(x,y) 'surface.dat' using 1:2:3 via a, b, c
      fit a0 + a1*x/(1 + a2*x/(1 + a3*x)) 'measured.dat' via a0,a1,a2,a3
      fit a*x + b*y 'surface.dat' using 1:2:3 via a,b
      fit [*:*][yaks=*:*] a*x+b*yaks 'surface.dat' u 1:2:3 via a,b

      fit [][][t=*:*] a*x + b*y + c*t 'foo.dat' using 1:2:3:4 via a,b,c

      set dummy x1, x2, x3, x4, x5
      h(x1,x2,x3,x4,s5) = a*x1 + b*x2 + c*x3 + d*x4 + e*x5
      fit h(x1,x2,x3,x4,x5) 'foo.dat' using 1:2:3:4:5:6 via a,b,c,d,e

After each iteration step, detailed information about the current state of the fit is written to the display. The same information about the initial and final states is written to a log file, "fit.log". This file is always appended to, so as to not lose any previous fit history; it should be deleted or renamed as desired. By using the command ‘set fit logfile‘, the name of the log file can be changed.

If activated by using ‘set fit errorvariables‘, the error for each fitted parameter will be stored in a variable named like the parameter, but with "_err" appended. Thus the errors can be used as input for further computations.

If ‘set fit prescale‘ is activated, fit parameters are prescaled by their initial values. This helps the Marquardt-Levenberg routine converge more quickly and reliably in cases where parameters differ in size by several orders of magnitude.

The fit may be interrupted by pressing Ctrl-C (Ctrl-Break in wgnuplot). After the current iteration completes, you have the option to (1) stop the fit and accept the current parameter values, (2) continue the fit, (3) execute a ‘gnuplot‘ command as specified by ‘set fit script‘ or the environment variable ‘FIT_SCRIPT‘. The default is replot, so if you had previously plotted both the data and the fitting function in one graph, you can display the current state of the fit.

Once fit has finished, the fit command may be used to store final values in a file for subsequent use as a parameter file. See fit for details.

3.9.1 adjustable parameters

There are two ways that ‘via‘ can specify the parameters to be adjusted, either directly on the command line or indirectly, by referencing a parameter file. The two use different means to set initial values.

Adjustable parameters can be specified by a comma-separated list of variable names after the ‘via‘ keyword. Any variable that is not already defined is created with an initial value of 1.0. However, the fit is more likely to converge rapidly if the variables have been previously declared with more appropriate starting values.

In a parameter file, each parameter to be varied and a corresponding initial value are specified, one per line, in the form

      varname = value

Comments, marked by ’#’, and blank lines are permissible. The special form

      varname = value       # FIXED

means that the variable is treated as a ’fixed parameter’, initialized by the parameter file, but not adjusted by fit. For clarity, it may be useful to designate variables as fixed parameters so that their values are reported by fit. The keyword ‘# FIXED‘ has to appear in exactly this form.

3.9.2 short introduction

fit is used to find a set of parameters that ’best’ fits your data to your user-defined function. The fit is judged on the basis of the sum of the squared differences or ’residuals’ (SSR) between the input data points and the function values, evaluated at the same places. This quantity is often called ’chisquare’ (i.e., the Greek letter chi, to the power of 2). The algorithm attempts to minimize SSR, or more precisely, WSSR, as the residuals are ’weighted’ by the input data errors (or 1.0) before being squared; see ‘fit error_estimates‘ for details.

That’s why it is called ’least-squares fitting’. Let’s look at an example to see what is meant by ’non-linear’, but first we had better go over some terms. Here it is convenient to use z as the dependent variable for user-defined functions of either one independent variable, z=f(x), or two independent variables, z=f(x,y). A parameter is a user-defined variable that fit will adjust, i.e., an unknown quantity in the function declaration. Linearity/non-linearity refers to the relationship of the dependent variable, z, to the parameters which fit is adjusting, not of z to the independent variables, x and/or y. (To be technical, the second {and higher} derivatives of the fitting function with respect to the parameters are zero for a linear least-squares problem).

For linear least-squares (LLS), the user-defined function will be a sum of simple functions, not involving any parameters, each multiplied by one parameter. NLLS handles more complicated functions in which parameters can be used in a large number of ways. An example that illustrates the difference between linear and nonlinear least-squares is the Fourier series. One member may be written as

     z=a*sin(c*x) + b*cos(c*x).

If a and b are the unknown parameters and c is constant, then estimating values of the parameters is a linear least-squares problem. However, if c is an unknown parameter, the problem is nonlinear.

In the linear case, parameter values can be determined by comparatively simple linear algebra, in one direct step. However LLS is a special case which is also solved along with more general NLLS problems by the iterative procedure that ‘gnuplot‘ uses. fit attempts to find the minimum by doing a search. Each step (iteration) calculates WSSR with a new set of parameter values. The Marquardt-Levenberg algorithm selects the parameter values for the next iteration. The process continues until a preset criterion is met, either (1) the fit has "converged" (the relative change in WSSR is less than a certain limit, see ‘set fit limit‘), or (2) it reaches a preset iteration count limit (see ‘set fit maxiter‘). The fit may also be interrupted and subsequently halted from the keyboard (see fit). The user variable FIT_CONVERGED contains 1 if the previous fit command terminated due to convergence; it contains 0 if the previous fit terminated for any other reason. FIT_NITER contains the number of iterations that were done during the last fit.

Often the function to be fitted will be based on a model (or theory) that attempts to describe or predict the behaviour of the data. Then fit can be used to find values for the free parameters of the model, to determine how well the data fits the model, and to estimate an error range for each parameter. See ‘fit error_estimates‘.

Alternatively, in curve-fitting, functions are selected independent of a model (on the basis of experience as to which are likely to describe the trend of the data with the desired resolution and a minimum number of parameters*functions.) The fit solution then provides an analytic representation of the curve.

However, if all you really want is a smooth curve through your data points, the smooth option to ‘plot‘ may be what you’ve been looking for rather than fit.

3.9.3 error estimates

In fit, the term "error" is used in two different contexts, data error estimates and parameter error estimates.

Data error estimates are used to calculate the relative weight of each data point when determining the weighted sum of squared residuals, WSSR or chisquare. They can affect the parameter estimates, since they determine how much influence the deviation of each data point from the fitted function has on the final values. Some of the fit output information, including the parameter error estimates, is more meaningful if accurate data error estimates have been provided.

The ‘statistical overview‘ describes some of the fit output and gives some background for the ’practical guidelines’. statistical overview

The theory of non-linear least-squares (NLLS) is generally described in terms of a normal distribution of errors, that is, the input data is assumed to be a sample from a population having a given mean and a Gaussian (normal) distribution about the mean with a given standard deviation. For a sample of sufficiently large size, and knowing the population standard deviation, one can use the statistics of the chisquare distribution to describe a "goodness of fit" by looking at the variable often called "chisquare". Here, it is sufficient to say that a reduced chisquare (chisquare/degrees of freedom, where degrees of freedom is the number of datapoints less the number of parameters being fitted) of 1.0 is an indication that the weighted sum of squared deviations between the fitted function and the data points is the same as that expected for a random sample from a population characterized by the function with the current value of the parameters and the given standard deviations.

If the standard deviation for the population is not constant, as in counting statistics where variance = counts, then each point should be individually weighted when comparing the observed sum of deviations and the expected sum of deviations.

At the conclusion fit reports ’stdfit’, the standard deviation of the fit, which is the rms of the residuals, and the variance of the residuals, also called ’reduced chisquare’ when the data points are weighted. The number of degrees of freedom (the number of data points minus the number of fitted parameters) is used in these estimates because the parameters used in calculating the residuals of the datapoints were obtained from the same data. If the data points have weights, ‘gnuplot‘ calculates the so-called p-value, i.e. one minus the cumulative distribution function of the chisquare-distribution for the number of degrees of freedom and the resulting chisquare, see ‘practical_guidelines‘. These values are exported to the variables

      FIT_NDF = Number of degrees of freedom
      FIT_WSSR = Weighted sum-of-squares residual
      FIT_STDFIT = sqrt(WSSR/NDF)
      FIT_P = p-value

To estimate confidence levels for the parameters, one can use the minimum chisquare obtained from the fit and chisquare statistics to determine the value of chisquare corresponding to the desired confidence level, but considerably more calculation is required to determine the combinations of parameters which produce such values.

Rather than determine confidence intervals, fit reports parameter error estimates which are readily obtained from the variance-covariance matrix after the final iteration. By convention, these estimates are called "standard errors" or "asymptotic standard errors", since they are calculated in the same way as the standard errors (standard deviation of each parameter) of a linear least-squares problem, even though the statistical conditions for designating the quantity calculated to be a standard deviation are not generally valid for the NLLS problem. The asymptotic standard errors are generally over-optimistic and should not be used for determining confidence levels, but are useful for qualitative purposes.

The final solution also produces a correlation matrix indicating correlation of parameters in the region of the solution; The main diagonal elements, autocorrelation, are always 1; if all parameters were independent, the off-diagonal elements would be nearly 0. Two variables which completely compensate each other would have an off-diagonal element of unit magnitude, with a sign depending on whether the relation is proportional or inversely proportional. The smaller the magnitudes of the off-diagonal elements, the closer the estimates of the standard deviation of each parameter would be to the asymptotic standard error. practical guidelines

If you have a basis for assigning weights to each data point, doing so lets you make use of additional knowledge about your measurements, e.g., take into account that some points may be more reliable than others. That may affect the final values of the parameters.

Weighting the data provides a basis for interpreting the additional fit output after the last iteration. Even if you weight each point equally, estimating an average standard deviation rather than using a weight of 1 makes WSSR a dimensionless variable, as chisquare is by definition.

Each fit iteration will display information which can be used to evaluate the progress of the fit. (An ’*’ indicates that it did not find a smaller WSSR and is trying again.) The ’sum of squares of residuals’, also called ’chisquare’, is the WSSR between the data and your fitted function; fit has minimized that. At this stage, with weighted data, chisquare is expected to approach the number of degrees of freedom (data points minus parameters). The WSSR can be used to calculate the reduced chisquare (WSSR/ndf) or stdfit, the standard deviation of the fit, sqrt(WSSR/ndf). Both of these are reported for the final WSSR.

If the data are unweighted, stdfit is the rms value of the deviation of the data from the fitted function, in user units.

If you supplied valid data errors, the number of data points is large enough, and the model is correct, the reduced chisquare should be about unity. (For details, look up the ’chi-squared distribution’ in your favorite statistics reference.) If so, there are additional tests, beyond the scope of this overview, for determining how well the model fits the data.

A reduced chisquare much larger than 1.0 may be due to incorrect data error estimates, data errors not normally distributed, systematic measurement errors, ’outliers’, or an incorrect model function. A plot of the residuals, e.g., ‘plot ’datafile’ using 1:($2-f($1))‘, may help to show any systematic trends. Plotting both the data points and the function may help to suggest another model.

Similarly, a reduced chisquare less than 1.0 indicates WSSR is less than that expected for a random sample from the function with normally distributed errors. The data error estimates may be too large, the statistical assumptions may not be justified, or the model function may be too general, fitting fluctuations in a particular sample in addition to the underlying trends. In the latter case, a simpler function may be more appropriate.

The p-value of the fit is one minus the cumulative distribution function of the chisquare-distribution for the number of degrees of freedom and the resulting chisquare. This can serve as a measure of the goodness-of-fit. The range of the p-value is between zero and one. A very small or large p-value indicates that the model does not describe the data and its errors well. As described above, this might indicate a problem with the data, its errors or the model, or a combination thereof. A small p-value might indicate that the errors have been underestimated and the errors of the final parameters should thus be scaled. See also ‘set fit errorscaling‘.

You’ll have to get used to both fit and the kind of problems you apply it to before you can relate the standard errors to some more practical estimates of parameter uncertainties or evaluate the significance of the correlation matrix.

Note that fit, in common with most NLLS implementations, minimizes the weighted sum of squared distances (y-f(x))**2. It does not provide any means to account for "errors" in the values of x, only in y. Also, any "outliers" (data points outside the normal distribution of the model) will have an exaggerated effect on the solution.

3.9.4 control

There are a number of environment variables that can be defined to affect fit before starting ‘gnuplot‘, see ‘fit control environment‘. At run time adjustments to the fit command operation can be controlled by fit. See variables. control variables

DEPRECATED in version 5. These user variables used to affect fit behaviour.

    FIT_LIMIT - use `set fit limit <epsilon>`
    FIT_MAXITER - use `set fit maxiter <number_of_cycles>`
    FIT_START_LAMBDA - use `set fit start-lambda <value>`
    FIT_LAMBDA_FACTOR - use `set fit lambda-factor <value>`
    FIT_SKIP - use the datafile every modifier
    FIT_INDEX - See multi-branch environment variables

The environment variables must be defined before ‘gnuplot‘ is executed; how to do so depends on your operating system.


changes the name (and/or path) of the file to which the fit log will be written from the default of "fit.log" in the working directory. The default value can be overwritten using the command ‘set fit logfile‘.


specifies a command that may be executed after an user interrupt. The default is replot, but a ‘plot‘ or ‘load‘ command may be useful to display a plot customized to highlight the progress of the fit. This setting can also be changed using ‘set fit script‘.

3.9.5 multi-branch

In multi-branch fitting, multiple data sets can be simultaneously fit with functions of one independent variable having common parameters by minimizing the total WSSR. The function and parameters (branch) for each data set are selected by using a ’pseudo-variable’, e.g., either the dataline number (a ’column’ index of -1) or the datafile index (-2), as the second independent variable.

Example: Given two exponential decays of the form, z=f(x), each describing a different data set but having a common decay time, estimate the values of the parameters. If the datafile has the format x:z:s, then

     f(x,y) = (y==0) ? a*exp(-x/tau) : b*exp(-x/tau)
     fit f(x,y) 'datafile' using  1:-2:2:3  via a, b, tau

For a more complicated example, see the file "hexa.fnc" used by the "fit.dem" demo.

Appropriate weighting may be required since unit weights may cause one branch to predominate if there is a difference in the scale of the dependent variable. Fitting each branch separately, using the multi-branch solution as initial values, may give an indication as to the relative effect of each branch on the joint solution.

3.9.6 starting values

Nonlinear fitting is not guaranteed to converge to the global optimum (the solution with the smallest sum of squared residuals, SSR), and can get stuck at a local minimum. The routine has no way to determine that; it is up to you to judge whether this has happened.

fit may, and often will get "lost" if started far from a solution, where SSR is large and changing slowly as the parameters are varied, or it may reach a numerically unstable region (e.g., too large a number causing a floating point overflow) which results in an "undefined value" message or ‘gnuplot‘ halting.

To improve the chances of finding the global optimum, you should set the starting values at least roughly in the vicinity of the solution, e.g., within an order of magnitude, if possible. The closer your starting values are to the solution, the less chance of stopping at a false minimum. One way to find starting values is to plot data and the fitting function on the same graph and change parameter values and replot until reasonable similarity is reached. The same plot is also useful to check whether the fit found a false minimum.

Of course finding a nice-looking fit does not prove there is no "better" fit (in either a statistical sense, characterized by an improved goodness-of-fit criterion, or a physical sense, with a solution more consistent with the model.) Depending on the problem, it may be desirable to fit with various sets of starting values, covering a reasonable range for each parameter.

3.9.7 tips

Here are some tips to keep in mind to get the most out of fit. They’re not very organized, so you’ll have to read them several times until their essence has sunk in.

The two forms of the ‘via‘ argument to fit serve two largely distinct purposes. The ‘via "file"‘ form is best used for (possibly unattended) batch operation, where you supply the starting parameter values in a file.

The ‘via var1, var2, ...‘ form is best used interactively, where the command history mechanism may be used to edit the list of parameters to be fitted or to supply new startup values for the next try. This is particularly useful for hard problems, where a direct fit to all parameters at once won’t work without good starting values. To find such, you can iterate several times, fitting only some of the parameters, until the values are close enough to the goal that the final fit to all parameters at once will work.

Make sure that there is no mutual dependency among parameters of the function you are fitting. For example, don’t try to fit a*exp(x+b), because a*exp(x+b)=a*exp(b)*exp(x). Instead, fit either a*exp(x) or exp(x+b).

A technical issue: The larger the ratio of the largest and the smallest absolute parameter values, the slower the fit will converge. If the ratio is close to or above the inverse of the machine floating point precision, it may take next to forever to converge, or refuse to converge at all. You will either have to adapt your function to avoid this, e.g., replace ’parameter’ by ’1e9*parameter’ in the function definition, and divide the starting value by 1e9 or use ‘set fit prescale‘ which does this internally according to the parameter starting values.

If you can write your function as a linear combination of simple functions weighted by the parameters to be fitted, by all means do so. That helps a lot, because the problem is no longer nonlinear and should converge with only a small number of iterations, perhaps just one.

Some prescriptions for analysing data, given in practical experimentation courses, may have you first fit some functions to your data, perhaps in a multi-step process of accounting for several aspects of the underlying theory one by one, and then extract the information you really wanted from the fitting parameters of those functions. With fit, this may often be done in one step by writing the model function directly in terms of the desired parameters. Transforming data can also quite often be avoided, though sometimes at the cost of a more difficult fit problem. If you think this contradicts the previous paragraph about simplifying the fit function, you are correct.

A "singular matrix" message indicates that this implementation of the Marquardt-Levenberg algorithm can’t calculate parameter values for the next iteration. Try different starting values, writing the function in another form, or a simpler function.

Finally, a nice quote from the manual of another fitting package (fudgit), that kind of summarizes all these issues: "Nonlinear fitting is an art!"

3.10 help

The help command displays built-in help. To specify information on a particular topic use the syntax:

      help {<topic>}

If <topic> is not specified, a short message is printed about ‘gnuplot‘. After help for the requested topic is given, a menu of subtopics is given; help for a subtopic may be requested by typing its name, extending the help request. After that subtopic has been printed, the request may be extended again or you may go back one level to the previous topic. Eventually, the ‘gnuplot‘ command line will return.

If a question mark (?) is given as the topic, the list of topics currently available is printed on the screen.

3.11 history

The ‘history‘ command prints or saves previous commands in the history list, or reexecutes a previous entry in the list. To modify the behavior of this command, see ‘set history‘.

Input lines with ‘history‘ as their first command are not stored in the command history.


      history               # show the complete history
      history 5             # show last 5 entries in the history
      history quiet 5       # show last 5 entries without entry numbers
      history ""     # write the complete history to file
      history "" append # append the complete history to file
      history 10 ""  # write last 10 commands to file
      history 10 "|head -5 >>" # write 5 history commands using pipe
      history ?load         # show all history entries starting with "load"
      history ?"set c"      # like above, several words enclosed in quotes
      hist !"set xr"        # like above, several words enclosed in quotes
      hist !55              # reexecute the command at history entry 55

3.12 if

New syntax:

      if (<condition>) { <commands>;
      } else {

Old syntax:

      if (<condition>) <command-line> [; else if (<condition>) ...; else ...]

This version of gnuplot supports block-structured if/else statements. If the keyword ‘if‘ or ‘else‘ is immediately followed by an opening "{", then conditional execution applies to all statements, possibly on multiple input lines, until a matching "}" terminates the block. If commands may be nested.

The old single-line if/else syntax is still supported, but can not be mixed with the new block-structured syntax. See if-old.

3.12.1 if-old

Through gnuplot version 4.4, the scope of the if/else commands was limited to a single input line. Now a multi-line clause may be enclosed in curly brackets. The old syntax is still honored but cannot be used inside a bracketed clause.

If no opening "{" follows the ‘if‘ keyword, the command(s) in <command-line> will be executed if <condition> is true (non-zero) or skipped if <condition> is false (zero). Either case will consume commands on the input line until the end of the line or an occurrence of ‘else‘. Note that use of ‘;‘ to allow multiple commands on the same line will _not_ end the conditionalized commands.


      if (pi!=acos(-1)) print "?Fixing pi!"; pi=acos(-1); print pi

will display:

      ?Fixing pi!


      if (1==2) print "Never see this"; print "Or this either"

will not display anything.


      v=v+1; if (v%2) print "2" ; else if (v%3) print "3"; else print "fred"

(repeat the last line repeatedly!)

3.13 for

The ‘plot‘, ‘splot‘, ‘set‘ and unset commands may optionally contain an iteration for clause. This has the effect of executing the basic command multiple times, each time re-evaluating any expressions that make use of the iteration control variable. Iteration of arbitrary command sequences can be requested using the ‘do‘ command. Two forms of iteration clause are currently supported:

      for [intvar = start:end{:increment}]
      for [stringvar in "A B C D"]


      plot for [filename in "A.dat B.dat C.dat"] filename using 1:2 with lines
      plot for [basename in "A B C"] basename.".dat" using 1:2 with lines
      set for [i = 1:10] style line i lc rgb "blue"
      unset for [tag = 100:200] label tag

Nested iteration is supported:

      set for [i=1:9] for [j=1:9] label i*10+j sprintf("%d",i*10+j) at i,j

See additional documentation for iteration, ‘do‘.

3.14 import

The import command associates a user-defined function name with a function exported by an external shared object. This constitutes a plugin mechanism that extends the set of functions available in gnuplot. See ‘plugins‘.


      import func(x[,y,z,...]) from "sharedobj[:symbol]"


      # make the function myfun, exported by "" or "mylib.dll"
      # available for plotting or numerical calculation in gnuplot
      import myfun(x) from "mylib"
      import myfun(x) from "mylib:myfun"    # same as above

      # make the function theirfun, defined in "" or "theirlib.dll"
      # available under a different name
      import myfun(x,y,z) from "theirlib:theirfun"

The program extends the name given for the shared object by either ".so" or ".dll" depending on the operating system, and searches for it first as a full path name and then as a path relative to the current directory. The operating system itself may also search any directories in LD_LIBRARY_PATH or DYLD_LIBRARY_PATH.

3.15 load

The ‘load‘ command executes each line of the specified input file as if it had been typed in interactively. Files created by the save command can later be ‘load‘ed. Any text file containing valid commands can be created and then executed by the ‘load‘ command. Files being ‘load‘ed may themselves contain ‘load‘ or call commands. See ‘comments‘ for information about comments in commands. To ‘load‘ with arguments, see call.


      load "<input-file>"

The name of the input file must be enclosed in quotes.

The special filename "-" may be used to ‘load‘ commands from standard input. This allows a ‘gnuplot‘ command file to accept some commands from standard input. Please see help for ‘batch/interactive‘ for more details.

On some systems which support a popen function (Unix), the load file can be read from a pipe by starting the file name with a ’<’.


      load 'work.gnu'
      load "func.dat"
      load "<"

The ‘load‘ command is performed implicitly on any file names given as arguments to ‘gnuplot‘. These are loaded in the order specified, and then ‘gnuplot‘ exits.

3.16 lower

See raise.

3.17 pause

The ‘pause‘ command displays any text associated with the command and then waits a specified amount of time or until the carriage return is pressed. ‘pause‘ is especially useful in conjunction with ‘load‘ files.


      pause <time> {"<string>"}
      pause mouse {<endcondition>}{, <endcondition>} {"<string>"}
      pause mouse close

<time> may be any constant or floating-point expression. ‘pause -1‘ will wait until a carriage return is hit, zero (0) won’t pause at all, and a positive number will wait the specified number of seconds.

If the current terminal supports ‘mousing‘, then ‘pause mouse‘ will terminate on either a mouse click or on ctrl-C. For all other terminals, or if mousing is not active, ‘pause mouse‘ is equivalent to ‘pause -1‘.

If one or more end conditions are given after ‘pause mouse‘, then any one of the conditions will terminate the pause. The possible end conditions are ‘keypress‘, ‘button1‘, ‘button2‘, ‘button3‘, ‘close‘, and ‘any‘. If the pause terminates on a keypress, then the ascii value of the key pressed is returned in MOUSE_KEY. The character itself is returned as a one character string in MOUSE_CHAR. Hotkeys (bind command) are disabled if keypress is one of the end conditions. Zooming is disabled if button3 is one of the end conditions.

In all cases the coordinates of the mouse are returned in variables MOUSE_X, MOUSE_Y, MOUSE_X2, MOUSE_Y2. See variables.

Note: Since ‘pause‘ communicates with the operating system rather than the graphics, it may behave differently with different device drivers (depending upon how text and graphics are mixed).


      pause -1    # Wait until a carriage return is hit
      pause 3     # Wait three seconds
      pause -1  "Hit return to continue"
      pause 10  "Isn't this pretty?  It's a cubic spline."
      pause mouse "Click any mouse button on selected data point"
      pause mouse keypress "Type a letter from A-F in the active window"
      pause mouse button1,keypress
      pause mouse any "Any key or button will terminate"

The variant "pause mouse key" will resume after any keypress in the active plot window. If you want to wait for a particular key to be pressed, you can use a loop such as:

      print "I will resume after you hit the Tab key in the plot window"
      plot <something>
      pause mouse key
      while (MOUSE_KEY != 9) {
          pause mouse key

3.17.1 pause mouse close

The command ‘pause mouse close‘ is a specific example of pausing to wait for an external event. In this case the program waits for a "close" event from the plot window. Exactly how to generate such an event varies with your desktop environment and configuration, but usually you can close the plot window by clicking on some widget on the window border or by typing a hot-key sequence such as <alt><F4> or <ctrl>q. If you are unsure whether a suitable widget or hot-key is available to the user, you may also want to define a hot-key sequence using gnuplot’s own mechanism. See ‘bind‘.

The command sequence below may be useful when running gnuplot from a script rather than from the command line.

     plot <...whatever...>
     bind all "alt-End" "exit gnuplot"
     pause mouse close

3.18 plot

‘plot‘ is the primary command for drawing plots with ‘gnuplot‘. It offers many different graphical representations for functions and data. ‘plot‘ is used to draw 2D functions and data. ‘splot‘ draws 2D projections of 3D surfaces and data.


      plot {<ranges>} <plot-element> {, <plot-element>, <plot-element>}

Each plot element consists of a definition, a function, or a data source together with optional properties or modifiers:

           <definition> | {sampling-range} <function> | <data source>
                        | keyentry
           {axes <axes>} {<title-spec>}
           {with <style>}

The graphical representation of each plot element is determined by the keyword with, e.g. ‘with lines‘ or boxplot. See ‘plotting styles‘.

The data to be plotted is either generated by a function (two functions if in parametric mode), read from a data file, or read from a named data block that was defined previously. Multiple datafiles, data blocks, and/or functions may be plotted in a single plot command separated by commas. See ‘data‘, ‘inline data‘, functions.

A plot-element that contains the definition of a function or variable does not create any visible output, see third example below.


      plot sin(x)
      plot sin(x), cos(x)
      plot f(x) = sin(x*a), a = .2, f(x), a = .4, f(x)
      plot "datafile.1" with lines, "datafile.2" with points
      plot [t=1:10] [-pi:pi*2] tan(t), \
           "data.1" using (tan($2)):($3/$4) smooth csplines \
                    axes x1y2 notitle with lines 5
      plot for [datafile in "spinach.dat broccoli.dat"] datafile

See also ‘show plot‘.

3.18.1 axes

There are four possible sets of axes available; the keyword <axes> is used to select the axes for which a particular line should be scaled. ‘x1y1‘ refers to the axes on the bottom and left; ‘x2y2‘ to those on the top and right; ‘x1y2‘ to those on the bottom and right; and ‘x2y1‘ to those on the top and left. Ranges specified on the ‘plot‘ command apply only to the first set of axes (bottom left).

3.18.2 binary


It is necessary to provide the keyword binary after the filename. Adequate details of the file format must be given on the command line or extracted from the file itself for a supported binary filetype. In particular, there are two structures for binary files, binary matrix format and binary general format.

The matrix format contains a two dimensional array of 32 bit IEEE float values plus an additional column and row of coordinate values. In the ‘using‘ specifier of a plot command, column 1 refers to the matrix row coordinate, column 2 refers to the matrix column coordinate, and column 3 refers to the value stored in the array at those coordinates.

The general format contains an arbitrary number of columns for which information must be specified at the command line. For example, array, record, ‘format‘ and ‘using‘ can indicate the size, format and dimension of data. There are a variety of useful commands for skipping file headers and changing endianess. There are a set of commands for positioning and translating data since often coordinates are not part of the file when uniform sampling is inherent in the data. Unlike reading from a text or matrix binary file, general binary does not treat the generated columns as 1, 2 or 3 in the ‘using‘ list. Instead column 1 refers to column 1 of the file, or as specified in the ‘format‘ list.

There are global default settings for the various binary options which may be set using the same syntax as the options when used as part of the ‘(s)plot <filename> binary ...‘ command. This syntax is ‘set datafile binary ...‘. The general rule is that common command-line specified parameters override file-extracted parameters which override default parameters.

matrix is the default binary format when no keywords specific to general are given, i.e., array, record, ‘format‘, filetype.

General binary data can be entered at the command line via the special file name ’-’. However, this is intended for use through a pipe where programs can exchange binary data, not for keyboards. There is no "end of record" character for binary data. Gnuplot continues reading from a pipe until it has read the number of points declared in the array qualifier. See matrix or general for more details.

The index keyword is not supported, since the file format allows only one surface per file. The every and ‘using‘ filters are supported. ‘using‘ operates as if the data were read in the above triplet form. Binary File Splot Demo. general

The binary keyword appearing alone indicates a binary data file that contains both coordinate information describing a non-uniform grid and the value of each grid point (see matrix). Binary data in any other format requires additional keywords to describe the layout of the data. Unfortunately the syntax of these required additional keywords is convoluted. Nevertheless the general binary mode is particularly useful for application programs sending large amounts of data to gnuplot.


      plot '<file_name>' {binary <binary list>} ...
      splot '<file_name>' {binary <binary list>} ...

General binary format is activated by keywords in <binary list> pertaining to information about file structure, i.e., array, record, ‘format‘ or filetype. Otherwise, non-uniform matrix binary format is assumed. (See matrix for more details.)

Gnuplot knows how to read a few standard binary file types that are fully self-describing, e.g. PNG images. Type binary at the command line for a list. Apart from these, you can think of binary data files as conceptually the same as text data. Each point has columns of information which are selected via the ‘using‘ specification. If no ‘format‘ string is specified, gnuplot will read in a number of binary values equal to the largest column given in the ‘<using list>‘. For example, ‘using 1:3‘ will result in three columns being read, of which the second will be ignored. Certain plot types have an associated default using specification. For example, ‘with image‘ has a default of ‘using 1‘, while rgbimage has a default of ‘using 1:2:3‘. array

Describes the sampling array dimensions associated with the binary file. The coordinates will be generated by gnuplot. A number must be specified for each dimension of the array. For example, ‘array=(10,20)‘ means the underlying sampling structure is two-dimensional with 10 points along the first (x) dimension and 20 points along the second (y) dimension. A negative number indicates that data should be read until the end of file. If there is only one dimension, the parentheses may be omitted. A colon can be used to separate the dimensions for multiple records. For example, ‘array=25:35‘ indicates there are two one-dimensional records in the file. record

This keyword serves the same function as array and has the same syntax. However, record causes gnuplot to not generate coordinate information. This is for the case where such information may be included in one of the columns of the binary data file. format

The default binary format is a float. For more flexibility, the format can include details about variable sizes. For example, ‘format="%uchar%int%float"‘ associates an unsigned character with the first using column, an int with the second column and a float with the third column. If the number of size specifications is less than the greatest column number, the size is implicitly taken to be similar to the last given variable size.

Furthermore, similar to the ‘using‘ specification, the format can include discarded columns via the ‘*‘ character and have implicit repetition via a numerical repeat-field. For example, ‘format="%*2int%3float"‘ causes gnuplot to discard two ints before reading three floats. To list variable sizes, type ‘show datafile binary datasizes‘. There are a group of names that are machine dependent along with their sizes in bytes for the particular compilation. There is also a group of names which attempt to be machine independent. endian

Often the endianess of binary data in the file does not agree with the endianess used by the platform on which gnuplot is running. Several words can direct gnuplot how to arrange bytes. For example ‘endian=little‘ means treat the binary file as having byte significance from least to greatest. The options are

              little:  least significant to greatest significance
                 big:  greatest significance to least significance
             default:  assume file endianess is the same as compiler
         swap (swab):  Interchange the significance.  (If things
                       don't look right, try this.)

Gnuplot can support "middle" ("pdp") endian if it is compiled with that option. filetype

For some standard binary file formats gnuplot can extract all the necessary information from the file in question. As an example, "format=edf" will read ESRF Header File format files. For a list of the currently supported file formats, type ‘show datafile binary filetypes‘.

There is a special file type called ‘auto‘ for which gnuplot will check if the binary file’s extension is a quasi-standard extension for a supported format.

Command line keywords may be used to override settings extracted from the file. The settings from the file override any defaults. See binary.

— AVS —

‘avs‘ is one of the automatically recognized binary file types for images. AVS is an extremely simple format, suitable mostly for streaming between applications. It consists of 2 longs (xwidth, ywidth) followed by a stream of pixels, each with four bytes of information alpha/red/green/blue.

— EDF —

‘edf‘ is one of the automatically recognized binary file types for images. EDF stands for ESRF Data Format, and it supports both edf and ehf formats (the latter means ESRF Header Format). More information on specifications can be found at

— PNG —

If gnuplot was configured to use the libgd library for png/gif/jpeg output, then it can also be used to read these same image types as binary files. You can use an explicit command

      plot 'file.png' binary filetype=png

Or the file type will be recognized automatically from the extension if you have previously requested

      set datafile binary filetype=auto keywords

The following keywords apply only when generating coordinates from binary data files. That is, the control mapping the individual elements of a binary array, matrix, or image to specific x/y/z positions.

— SCAN —

A great deal of confusion can arise concerning the relationship between how gnuplot scans a binary file and the dimensions seen on the plot. To lessen the confusion, conceptually think of gnuplot _always_ scanning the binary file point/line/plane or fast/medium/slow. Then this keyword is used to tell gnuplot how to map this scanning convention to the Cartesian convention shown in plots, i.e., x/y/z. The qualifier for scan is a two or three letter code representing where point is assigned (first letter), line is assigned (second letter), and plane is assigned (third letter). For example, ‘scan=yx‘ means the fastest, point-by-point, increment should be mapped along the Cartesian y dimension and the middle, line-by-line, increment should be mapped along the x dimension.

When the plotting mode is ‘plot‘, the qualifier code can include the two letters x and y. For ‘splot‘, it can include the three letters x, y and z.

There is nothing restricting the inherent mapping from point/line/plane to apply only to Cartesian coordinates. For this reason there are cylindrical coordinate synonyms for the qualifier codes where t (theta), r and z are analogous to the x, y and z of Cartesian coordinates.


Shorthand notation for ‘scan=yx‘ or ‘scan=yxz‘. I.e. it affects the assignment of pixels to scan lines during input. To instead transpose an image when it is displayed try

     plot 'imagefile' binary filetype=auto flipx rotate=90deg with rgbimage

— DX, DY, DZ —

When gnuplot generates coordinates, it uses the spacing described by these keywords. For example ‘dx=10 dy=20‘ would mean space samples along the x dimension by 10 and space samples along the y dimension by 20. ‘dy‘ cannot appear if ‘dx‘ does not appear. Similarly, ‘dz‘ cannot appear if ‘dy‘ does not appear. If the underlying dimensions are greater than the keywords specified, the spacing of the highest dimension given is extended to the other dimensions. For example, if an image is being read from a file and only ‘dx=3.5‘ is given gnuplot uses a delta x and delta y of 3.5.

The following keywords also apply only when generating coordinates. However they may also be used with matrix binary files.


Sometimes the scanning directions in a binary datafile are not consistent with that assumed by gnuplot. These keywords can flip the scanning direction along dimensions x, y, z.


When gnuplot generates coordinates based upon transposition and flip, it attempts to always position the lower left point in the array at the origin, i.e., the data lies in the first quadrant of a Cartesian system after transpose and flip.

To position the array somewhere else on the graph, the origin keyword directs gnuplot to position the lower left point of the array at a point specified by a tuple. The tuple should be a double for ‘plot‘ and a triple for ‘splot‘. For example, ‘origin=(100,100):(100,200)‘ is for two records in the file and intended for plotting in two dimensions. A second example, ‘origin=(0,0,3.5)‘, is for plotting in three dimensions.


Similar to origin, this keyword will position the array such that its center lies at the point given by the tuple. For example, ‘center=(0,0)‘. Center does not apply when the size of the array is ‘Inf‘.


The transpose and flip commands provide some flexibility in generating and orienting coordinates. However, for full degrees of freedom, it is possible to apply a rotational vector described by a rotational angle in two dimensions.

The ‘rotate‘ keyword applies to the two-dimensional plane, whether it be ‘plot‘ or ‘splot‘. The rotation is done with respect to the positive angle of the Cartesian plane.

The angle can be expressed in radians, radians as a multiple of pi, or degrees. For example, ‘rotate=1.5708‘, ‘rotate=0.5pi‘ and ‘rotate=90deg‘ are equivalent.

If origin is specified, the rotation is done about the lower left sample point before translation. Otherwise, the rotation is done about the array ‘center‘.


For ‘splot‘, the concept of a rotational vector is implemented by a triple representing the vector to be oriented normal to the two-dimensional x-y plane. Naturally, the default is (0,0,1). Thus specifying both rotate and perpendicular together can orient data myriad ways in three-space.

The two-dimensional rotation is done first, followed by the three-dimensional rotation. That is, if R’ is the rotational 2 x 2 matrix described by an angle, and P is the 3 x 3 matrix projecting (0,0,1) to (xp,yp,zp), let R be constructed from R’ at the upper left sub-matrix, 1 at element 3,3 and zeros elsewhere. Then the matrix formula for translating data is v’ = P R v, where v is the 3 x 1 vector of data extracted from the data file. In cases where the data of the file is inherently not three-dimensional, logical rules are used to place the data in three-space. (E.g., usually setting the z-dimension value to zero and placing 2D data in the x-y plane.)

3.18.3 data

Discrete data contained in a file can be displayed by specifying the name of the data file (enclosed in single or double quotes) on the ‘plot‘ command line.


      plot '<file_name>' {binary <binary list>}
                         {{nonuniform} matrix}
                         {index <index list> | index "<name>"}
                         {every <every list>}
                         {skip <number-of-lines>}
                         {using <using list>}
                         {smooth <option>}
                         {bins <options>}
                         {volatile} {noautoscale}

The modifiers binary, index, every, skip, ‘using‘, bins, and smooth are discussed separately. In brief

  • ‘skip N‘ tells the program to ignore N lines at the start of the input file
  • binary indicates that the file contains binary data rather than text
  • index selects which data sets in a multi-data-set file are to be plotted
  • every specifies which points within a single data set are to be plotted
  • ‘using‘ specifies which columns in the file are to be used in which order
  • smooth performs simple filtering, interpolation, or curve-fitting of the data prior to plotting
  • bins sorts individual input points into equal-sized intervals along x and plots a single accumulated value per interval
  • volatile indicates that the content of the file may not be available to reread later and therefore it should be retained internally for re-use.

‘splot‘ has a similar syntax but does not support smooth or bins.

The ‘noautoscale‘ keyword means that the points making up this plot will be ignored when automatically determining axis range limits.


Each non-empty line in a data file describes one data point, except that records beginning with ‘#‘ (and also with ‘!‘ on VMS) will be treated as comments and ignored.

Depending on the plot style and options selected, from one to eight values are read from each line and associated with a single data point. See ‘using‘.

The individual records on a single line of data must be separated by white space (one or more blanks or tabs) a special field separator character is is specified by the datafile command. A single field may itself contain white space characters if the entire field is enclosed in a pair of double quotes, or if a field separator other than white space is in effect. Whitespace inside a pair of double quotes is ignored when counting columns, so the following datafile line has three columns:

      1.0 "second column" 3.0

Data may be written in exponential format with the exponent preceded by the letter e or E. The fortran exponential specifiers d, D, q, and Q may also be used if the command ‘set datafile fortran‘ is in effect.

Blank records in a data file are significant. Single blank records designate discontinuities in a ‘plot‘; no line will join points separated by a blank records (if they are plotted with a line style). Two blank records in a row indicate a break between separate data sets. See index.

If autoscaling has been enabled (autoscale), the axes are automatically extended to include all datapoints, with a whole number of tic marks if tics are being drawn. This has two consequences: i) For ‘splot‘, the corner of the surface may not coincide with the corner of the base. In this case, no vertical line is drawn. ii) When plotting data with the same x range on a dual-axis graph, the x coordinates may not coincide if the x2tics are not being drawn. This is because the x axis has been autoextended to a whole number of tics, but the x2 axis has not. The following example illustrates the problem:

      reset; plot '-', '-' axes x2y1
      1 1
      19 19
      1 1
      19 19

To avoid this, you can use the noextend modifier of the autoscale or ‘set [axis]range‘ commands. This turns off extension of the axis range to include the next tic mark.

Label coordinates and text can also be read from a data file (see labels). bins


     plot 'DATA' using <XCOL> {:<YCOL>} bins{=<NBINS>}
          {binrange [<LOW>:<HIGH>]} {binwidth=<width>}

The bins option to a ‘plot‘ command first assigns the original data to equal width bins on x and then plots a single value per bin. The default number of bins is controlled by samples, but this can be changed by giving an explicit number of bins in the command.

If no binrange is given, the range is taken from the extremes of the x values found in ’DATA’.

Given the range and the number of bins, bin width is calculated automatically and points are assigned to bins 0 to NBINS-1

     BINWIDTH = (HIGH - LOW) / (NBINS-1)
     xmin = LOW - BINWIDTH/2
     xmax = HIGH + BINWIDTH/2
     first bin holds points with (xmin <= x < xmin + BINWIDTH)
     last bin holds points with (xmax-BINWIDTH <= x < xman)
     each point is assigned to bin i = floor(NBINS * (x-xmin)/(xmax-xmin))

Alternatively you can provide a fixed bin width, in which case nbins is calculated as the smallest number of bins that will span the range.

On output bins are plotted or tabulated by midpoint. E.g. if the program calculates bin width as shown above, the x coordinate output for the first bin is x=LOW (not x=xmin).

If only a single column is given in the using clause then each data point contributes a count of 1 to the accumulation of total counts in the bin for that x coordinate value. If a second column is given then the value in that column is added to the accumulation for the bin. Thus the following two plot command are equivalent:

     plot 'DATA" using N bins=20
     set samples 20
     plot 'DATA' using (column(N)):(1)

The y value plotted for each bin is the sum of the y values over all points in that bin. This corresponds to ‘binvalue=sum‘. EXPERIMENTAL: ‘binvalue=avg‘ instead plots the mean y value for that bin.

For related plotting styles see ‘smooth frequency‘ and ‘smooth kdensity‘. columnheaders

Extra lines at the start of a data file may be explicitly ignored using the skip keyword in the plot command. A single additional line containing text column headers may be present. It is skipped automatically if the plot command refers explicitly to column headers, e.g. by using them for titles. Otherwise you may need to skip it explicitly either by adding one to the skip count or by setting the attribute columnheaders. See skip, ‘columnhead‘, ‘autotitle columnheader‘, datafile. csv files


     set datafile separator {whitespace | tab | comma | "chars"}

"csv" is short for "comma-separated values". The term "csv file" is loosely applied to files in which data fields are delimited by a specific character, not necessarily a comma. To read data from a csv file you must tell gnuplot what the field-delimiting character is. For instance to read from a file using semicolon as a field delimiter:

     set datafile separator ";"

See ‘set datafile separator‘. This applies only to files used for input. To create a csv file on output, use the corresponding ‘separator‘ option to table. every

The every keyword allows a periodic sampling of a data set to be plotted.

For ordinary files a "point" single record (line); a "block" of data is a set of consecutive records with blank lines before and after the block.

For matrix data a "block" and "point" correspond to "row" and "column". See every.


      plot 'file' every {<point_incr>}

The data points to be plotted are selected according to a loop from <‘start_point‘> to <‘end_point‘> with increment <‘point_incr‘> and the blocks according to a loop from <‘start_block‘> to <‘end_block‘> with increment <‘block_incr‘>.

The first datum in each block is numbered ’0’, as is the first block in the file.

Note that records containing unplottable information are counted.

Any of the numbers can be omitted; the increments default to unity, the start values to the first point or block, and the end values to the last point or block. ’:’ at the end of the every option is not permitted. If every is not specified, all points in all lines are plotted.


      every :::3::3    # selects just the fourth block ('0' is first)
      every :::::9     # selects the first 10 blocks
      every 2:2        # selects every other point in every other block
      every ::5::15    # selects points 5 through 15 in each block

See simple plot demos (simple.dem) , Non-parametric splot demos , and Parametric splot demos . example datafile

This example plots the data in the file "population.dat" and a theoretical curve:

      pop(x) = 103*exp((1965-x)/10)
      set xrange [1960:1990]
      plot 'population.dat', pop(x)

The file "population.dat" might contain:

      # Gnu population in Antarctica since 1965
         1965   103
         1970   55
         1975   34
         1980   24
         1985   10

Binary examples:

      # Selects two float values (second one implicit) with a float value
      # discarded between them for an indefinite length of 1D data.
      plot '<file_name>' binary format="%float%*float" using 1:2 with lines

      # The data file header contains all details necessary for creating
      # coordinates from an EDF file.
      plot '<file_name>' binary filetype=edf with image
      plot '<file_name>.edf' binary filetype=auto with image

      # Selects three unsigned characters for components of a raw RGB image
      # and flips the y-dimension so that typical image orientation (start
      # at top left corner) translates to the Cartesian plane.  Pixel
      # spacing is given and there are two images in the file.  One of them
      # is translated via origin.
      plot '<file_name>' binary array=(512,1024):(1024,512) format='%uchar' \
           dx=2:1 dy=1:2 origin=(0,0):(1024,1024) flipy u 1:2:3 w rgbimage

      # Four separate records in which the coordinates are part of the
      # data file.  The file was created with a endianess different from
      # the system on which gnuplot is running.
      splot '<file_name>' binary record=30:30:29:26 endian=swap u 1:2:3

      # Same input file, but this time we skip the 1st and 3rd records
      splot '<file_name>' binary record=30:26 skip=360:348 endian=swap u 1:2:3

See also matrix. index

The index keyword allows you to select specific data sets in a multi-data-set file for plotting.


      plot 'file' index { <m>{:<n>{:<p>}} | "<name>" }

Data sets are separated by pairs of blank records. ‘index <m>‘ selects only set <m>; ‘index <m>:<n>‘ selects sets in the range <m> to <n>; and ‘index <m>:<n>:<p>‘ selects indices <m>, <m>+<p>, <m>+2<p>, etc., but stopping at <n>. Following C indexing, the index 0 is assigned to the first data set in the file. Specifying too large an index results in an error message. If <p> is specified but <n> is left blank then every <p>-th dataset is read until the end of the file. If index is not specified, the entire file is plotted as a single data set.


      plot 'file' index 4:5

For each point in the file, the index value of the data set it appears in is available via the pseudo-column ‘column(-2)‘. This leads to an alternative way of distinguishing individual data sets within a file as shown below. This is more awkward than the index command if all you are doing is selecting one data set for plotting, but is very useful if you want to assign different properties to each data set. See ‘pseudocolumns‘, ‘lc variable‘.


      plot 'file' using 1:(column(-2)==4 ? $2 : NaN)        # very awkward
      plot 'file' using 1:2:(column(-2)) linecolor variable # very useful!

‘index ’<name>’‘ selects the data set with name ’<name>’. Names are assigned to data sets in comment lines. The comment character and leading white space are removed from the comment line. If the resulting line starts with <name>, the following data set is now named <name> and can be selected.


      plot 'file' index 'Population'

Please note that every comment that starts with <name> will name the following data set. To avoid problems it may be useful to choose a naming scheme like ’== Population ==’ or ’[Population]’.

splot with indices demo.</p> skip

The skip keyword tells the program to skip lines at the start of a text (i.e. not binary) data file. The lines that are skipped do not count toward the line count used in processing the every keyword. Note that ‘skip N‘ skips lines only at the start of the file, whereas ‘every ::N‘ skips lines at the start of every block of data in the file. See also skip for a similar option that applies to binary data files. smooth

‘gnuplot‘ includes a few general-purpose routines for filtering, interpolation and grouping data as it is input; these are grouped under the smooth option. More sophisticated data processing may be performed by preprocessing the data externally or by using fit with an appropriate model.


      smooth {unique | frequency | fnormal | cumulative | cnormal | bins
                     | kdensity {bandwidth} {period}
                     | csplines | acsplines | mcsplines | bezier | sbezier
                     | unwrap | zsort}

The ‘unique‘, ‘frequency‘, ‘fnormal‘, ‘cumulative‘ and ‘cnormal‘ sort the data on x and then plot some aspect of the distribution of x values.

The spline and Bezier options determine coefficients describing a continuous curve between the endpoints of the data. This curve is then plotted in the same manner as a function, that is, by finding its value at uniform intervals along the abscissa (see samples) and connecting these points with straight line segments. If the data set is interrupted by blank lines or undefined values a separate continuous curve is fit for each uninterrupted subset of the data. Adjacent separately fit segments may be separated by a gap or discontinuity.

‘unwrap‘ manipulates the data to avoid jumps of more than pi by adding or subtracting multiples of 2*pi.

‘zsort‘ uses a 3rd column of input to sort points prior to plotting.

If autoscale is in effect, axis ranges will be computed for the final curve rather than for the original data.

If autoscale is not in effect, and a spline curve is being generated, sampling of the spline fit is done across the intersection of the x range covered by the input data and the fixed abscissa range defined by xrange.

If too few points are available to apply the requested smoothing operation an error message is produced.

The smooth options have no effect on function plots.


The ‘smooth acsplines‘ option approximates the data with a natural smoothing spline. After the data are made monotonic in x (see ‘smooth unique‘), a curve is piecewise constructed from segments of cubic polynomials whose coefficients are found by fitting to the individual data points weighted by the value, if any, given in the third column of the using spec. The default is equivalent to

      plot 'data-file' using 1:2:(1.0) smooth acsplines

Qualitatively, the absolute magnitude of the weights determines the number of segments used to construct the curve. If the weights are large, the effect of each datum is large and the curve approaches that produced by connecting consecutive points with natural cubic splines. If the weights are small, the curve is composed of fewer segments and thus is smoother; the limiting case is the single segment produced by a weighted linear least squares fit to all the data. The smoothing weight can be expressed in terms of errors as a statistical weight for a point divided by a "smoothing factor" for the curve so that (standard) errors in the file can be used as smoothing weights.


      plot 'data_file' using 1:2:(sw($3,100)) smooth acsplines


The ‘smooth bezier‘ option approximates the data with a Bezier curve of degree n (the number of data points) that connects the endpoints.

— BINS —

bins is the same as bins. See bins. For related plotting styles see ‘smooth frequency‘ and ‘smooth kdensity‘.


The ‘smooth csplines‘ option connects consecutive points by natural cubic splines after rendering the data monotonic (see ‘smooth unique‘).


The ‘smooth mcsplines‘ option connects consecutive points by cubic splines constrained such that the smoothed function preserves the monotonicity and convexity of the original data points. This reduces the effect of outliers. FN Fritsch & RE Carlson (1980) "Monotone Piecewise Cubic Interpolation", SIAM Journal on Numerical Analysis 17: 238–246.


The ‘smooth sbezier‘ option first renders the data monotonic (‘unique‘) and then applies the ‘bezier‘ algorithm.


The ‘smooth unique‘ option makes the data monotonic in x; points with the same x-value are replaced by a single point having the average y-value. The resulting points are then connected by straight line segments.


The ‘smooth unwrap‘ option modifies the input data so that any two successive points will not differ by more than pi; a point whose y value is outside this range will be incremented or decremented by multiples of 2pi until it falls within pi of the previous point. This operation is useful for making wrapped phase measurements continuous over time.


The ‘smooth frequency‘ option makes the data monotonic in x; points with the same x-value are replaced by a single point having the summed y-values. To plot a histogram of the number of data values in equal size bins, set the y-value to 1.0 so that the sum is a count of occurrences in that bin. This is done implicitly if only a single column is provided. Example:

     binwidth = <something>  # set width of x values in each bin
     bin(val) = binwidth * floor(val/binwidth)
     plot "datafile" using (bin(column(1))):(1.0) smooth frequency
     plot "datafile" using (bin(column(1))) smooth frequency  # same result

See also smooth.dem


The ‘smooth fnormal‘ option work just like the ‘frequency‘ option, but produces a normalized histogram. It makes the data monotonic in x and normalises the y-values so they all sum to 1. Points with the same x-value are replaced by a single point containing the sumed y-values. To plot a histogram of the number of data values in equal size bins, set the y-value to 1.0 so that the sum is a count of occurrences in that bin. This is done implicitly if only a single column is provided. See also smooth.dem


The ‘smooth cumulative‘ option makes the data monotonic in x; points with the same x-value are replaced by a single point containing the cumulative sum of y-values of all data points with lower x-values (i.e. to the left of the current data point). This can be used to obtain a cumulative distribution function from data. See also smooth.dem


The ‘smooth cnormal‘ option makes the data monotonic in x and normalises the y-values onto the range [0:1]. Points with the same x-value are replaced by a single point containing the cumulative sum of y-values of all data points with lower x-values (i.e. to the left of the current data point) divided by the total sum of all y-values. This can be used to obtain a normalised cumulative distribution function from data (useful when comparing sets of samples with differing numbers of members). See also smooth.dem


The ‘smooth kdensity‘ option generates and plots a kernel density estimate using Gaussian kernels for the distribution from which a set of values was drawn. Values are taken from the first data column, optional weights are taken from the second column. A Gaussian is placed at the location of each point and the sum of all these Gaussians is plotted as a function. To obtain a normalized histogram, each weight should be 1/number-of-points.

Bandwidth: By default gnuplot calculates and uses the bandwidth which would be optimal for normally distributed data values.

     default_bandwidth = sigma * (4/3N) ** (0.2)

This will usually be a very conservative, i.e. broad bandwidth. Alternatively, you can provide an explicit bandwidth.

     plot $DATA smooth kdensity bandwidth <value> with boxes

The bandwidth used in the previous plot is stored in GPVAL_KDENSITY_BANDWIDTH.

Period: For periodic data individual Gaussian components should be treated as repeating at intervals of one period. One example is data measured as a function of angle, where the period is 2pi. Another example is data indexed by day-of-year and measured over multiple years, where the period is 365. In such cases the period should be provided in the plot command:

     plot $ANGULAR_DAT smooth kdensity period 2*pi with lines



     plot FOO using x:y:z:color smooth zsort with points lc palette

The intended use is to filter presentation of 2D scatter plots with a huge number of points so that the distribution of high-scoring points remains evident. Sorting the points on z guarantees that points with a high z-value will not be obscured by points with lower z-values. Limited to plot styles "with points" and "with linespoints". special-filenames

There are a few filenames that have a special meaning: ”, ’-’, ’+’ and ’++’.

The empty filename ” tells gnuplot to re-use the previous input file in the same plot command. So to plot two columns from the same input file:

      plot 'filename' using 1:2, '' using 1:3

The filename can also be reused over subsequent plot commands, however save then only records the name in a comment.

The special filenames ’+’ and ’++’ are a mechanism to allow the full range of ‘using‘ specifiers and plot styles with inline functions. Normally a function plot can only have a single y (or z) value associated with each sampled point. The pseudo-file ’+’ treats the sampled points as column 1, and allows additional column values to be specified via a ‘using‘ specification, just as for a true input file. The number of samples is controlled via samples. By default samples are generated over the range given by trange, or if trange has not been set than over the full range of xrange.

Note: The use of trange is a change from previous gnuplot versions. It allows the sampling range to differ from the x axis range.

      plot '+' using ($1):(sin($1)):(sin($1)**2) with filledcurves

An independent sampling range can be provided immediately before the ’+’. As in normal function plots, a name can be assigned to the independent variable. If given for the first plot element, the sampling range specifier has to be preceded by the ‘sample‘ keyword (see also sampling).

      plot sample [beta=0:2*pi] '+' using (sin(beta)):(cos(beta)) with lines

Additionally, the range specifier of ’+’ supports giving a sampling increment.

      plot $MYDATA, [t=-3:25:1] '+' using (t):(f(t))

The pseudo-file ’++’ returns 2 columns of data forming a regular grid of [u,v] coordinates with the number of points along u controlled by samples and the number of points along v controlled by isosamples. You must set urange and vrange before plotting ’++’. However the x and y ranges can be autoscaled or can be explicitly set to different values than urange and vrange. Use of u and v to sample ’++’ is a CHANGE introduced in version 5.2 Examples:

      splot '++' using 1:2:(sin($1)*sin($2)) with pm3d
      plot '++' using 1:2:(sin($1)*sin($2)) with image

The special filename ‘’-’‘ specifies that the data are inline; i.e., they follow the command. Only the data follow the command; ‘plot‘ options like filters, titles, and line styles remain on the ‘plot‘ command line. This is similar to << in unix shell script, and $DECK in VMS DCL. The data are entered as though they are being read from a file, one data point per record. The letter "e" at the start of the first column terminates data entry.

‘’-’‘ is intended for situations where it is useful to have data and commands together, e.g. when both are piped to ‘gnuplot‘ from another application. Some of the demos, for example, might use this feature. While ‘plot‘ options such as index and every are recognized, their use forces you to enter data that won’t be used. For all but the simplest cases it is probably easier to first define a datablock and then read from it rather than from ‘’-’‘. See ‘datablocks‘.

If you use ‘’-’‘ with replot, you may need to enter the data more than once. See replot, refresh. Here again it may be better to use a datablock.

A blank filename (”) specifies that the previous filename should be reused. This can be useful with things like

      plot 'a/very/long/filename' using 1:2, '' using 1:3, '' using 1:4

(If you use both ‘’-’‘ and ‘”‘ on the same ‘plot‘ command, you’ll need to have two sets of inline data, as in the example above.) piped-data

On systems with a popen function, the datafile can be piped through a shell command by starting the file name with a ’<’. For example,

      pop(x) = 103*exp(-x/10)
      plot "< awk '{print $1-1965, $2}' population.dat", pop(x)

would plot the same information as the first population example but with years since 1965 as the x axis. If you want to execute this example, you have to delete all comments from the data file above or substitute the following command for the first part of the command above (the part up to the comma):

      plot "< awk '$0 !~ /^#/ {print $1-1965, $2}' population.dat"

While this approach is most flexible, it is possible to achieve simple filtering with the ‘using‘ keyword.

On systems with an fdopen() function, data can be read from an arbitrary file descriptor attached to either a file or pipe. To read from file descriptor ‘n‘ use ‘’<&n’‘. This allows you to easily pipe in several data files in a single call from a POSIX shell:

      $ gnuplot -p -e "plot '<&3', '<&4'" 3<data-3 4<data-4
      $ ./gnuplot 5< <(myprogram -with -options)
      gnuplot> plot '<&5' using

The most common datafile modifier is ‘using‘. It tells the program which columns of data in the input file are to be plotted.


      plot 'file' using <entry> {:<entry> {:<entry> ...}} {'format'}

If a format is specified, it is used to read in each datafile record using the C library ’scanf’ function. Otherwise the record is interpreted as consisting of columns (fields) of data separated by whitespace (spaces and/or tabs), but see ‘datafile separator‘.

Each <entry> may be a simple column number that selects the value from one field of the input file, a string that matches a column label in the first line of a data set, an expression enclosed in parentheses, or a special function not enclosed in parentheses such as xticlabels(2).

If the entry is an expression in parentheses, then the function column(N) may be used to indicate the value in column N. That is, column(1) refers to the first item read, column(2) to the second, and so on. The special symbols $1, $2, ... are shorthand for column(1), column(2) ...

The special symbol $# evaluates to the total number of columns in the current line of input, so column($#) or stringcolumn($#) always returns the content of the final column even if the number of columns is unknown or different lines in the file contain different numbers of columns.

The function ‘valid(N)‘ tests whether column N contains a valid number.

If each column of data in the input file contains a label in the first row rather than a data value, this label can be used to identify the column on input and/or in the plot legend. The column() function can be used to select an input column by label rather than by column number. For example, if the data file contains

      Height    Weight    Age
      val1      val1      val1
      ...       ...       ...

then the following plot commands are all equivalent

      plot 'datafile' using 3:1, '' using 3:2
      plot 'datafile' using (column("Age")):(column(1)), \
                   '' using (column("Age")):(column(2))
      plot 'datafile' using "Age":"Height", '' using "Age":"Weight"

The full string must match. Comparison is case-sensitive. To use column labels in the plot legend, use ‘set key autotitle columnhead‘.

In addition to the actual columns 1...N in the input data file, gnuplot presents data from several "pseudo-columns" that hold bookkeeping information. E.g. $0 or column(0) returns the sequence number of this data record within a dataset. Please see ‘pseudocolumns‘.

An empty <entry> will default to its order in the list of entries. For example, ‘using ::4‘ is interpreted as ‘using 1:2:4‘.

If the ‘using‘ list has only a single entry, that <entry> will be used for y and the data point number (pseudo-column $0) is used for x; for example, "‘plot ’file’ using 1‘" is identical to "‘plot ’file’ using 0:1‘". If the ‘using‘ list has two entries, these will be used for x and y. See style and fit for details about plotting styles that make use of data from additional columns of input.

’scanf’ accepts several numerical specifications but ‘gnuplot‘ requires all inputs to be double-precision floating-point variables, so "%lf" is essentially the only permissible specifier. A format string given by the user must contain at least one such input specifier, and no more than seven of them. ’scanf’ expects to see white space—a blank, tab ("\t"), newline ("\n"), or formfeed ("\f")—between numbers; anything else in the input stream must be explicitly skipped.

Note that the use of "\t", "\n", or "\f" requires use of double-quotes rather than single-quotes.


This creates a plot of the sum of the 2nd and 3rd data against the first: The format string specifies comma- rather than space-separated columns. The same result could be achieved by specifying ‘set datafile separator comma‘.

      plot 'file' using 1:($2+$3) '%lf,%lf,%lf'

In this example the data are read from the file "MyData" using a more complicated format:

      plot 'MyData' using "%*lf%lf%*20[^\n]%lf"

The meaning of this format is:

      %*lf        ignore a number
      %lf         read a double-precision number (x by default)
      %*20[^\n]   ignore 20 non-newline characters
      %lf         read a double-precision number (y by default)

One trick is to use the ternary ‘?:‘ operator to filter data:

      plot 'file' using 1:($3>10 ? $2 : 1/0)

which plots the datum in column two against that in column one provided the datum in column three exceeds ten. ‘1/0‘ is undefined; ‘gnuplot‘ quietly ignores undefined points, so unsuitable points are suppressed. Or you can use the pre-defined variable NaN to achieve the same result.

In fact, you can use a constant expression for the column number, provided it doesn’t start with an opening parenthesis; constructs like ‘using 0+(complicated expression)‘ can be used. The crucial point is that the expression is evaluated once if it doesn’t start with a left parenthesis, or once for each data point read if it does.

If timeseries data are being used, the time can span multiple columns. The starting column should be specified. Note that the spaces within the time must be included when calculating starting columns for other data. E.g., if the first element on a line is a time with an embedded space, the y value should be specified as column three.

It should be noted that (a) ‘plot ’file’‘, (b) ‘plot ’file’ using 1:2‘, and (c) ‘plot ’file’ using ($1):($2)‘ can be subtly different. The exact behaviour has changed in version 5. See ‘missing‘.

It is often possible to plot a file with lots of lines of garbage at the top simply by specifying

      plot 'file' using 1:2

However, if you want to leave text in your data files, it is safer to put the comment character (#) in the first column of the text lines.


Expressions in the ‘using‘ clause of a plot statement can refer to additional bookkeeping values in addition to the actual data values contained in the input file. These are contained in "pseudocolumns".

      column(0)   The sequential order of each point within a data set.
                  The counter starts at 0, increments on each non-blank,
                  non-comment line, and is reset by two sequential blank
                  records.  The shorthand form $0 is available.
      column(-1)  This counter starts at 0, increments on a single blank line,
                  and is reset by two sequential blank lines.
                  This corresponds to the data line in array or grid data.
                  It can also be used to distinguish separate line segments
                  or polygons within a data set.
      column(-2)  Starts at 0 and increments on two sequential blank lines.
                  This is the index number of the current data set within a
                  file that contains multiple data sets.  See index.
      column($#)  The special symbol $# evaluates to the total number of
                  columns available, so column($#) refers to the last
                  (rightmost) field in the current input line.
                  column($# - 1) would refer to the last-but-one column, etc.

— KEY —

The layout of certain plot styles (column-stacked histograms, spider plots) is such that it would make no sense to generate plot titles from a data column header. Also it would make no sense to generate axis tic labels from the content of a data column (e.g. ‘using 2:3:xticlabels(1)‘). These plots styles instead use the form ‘using 2:3:key(1)‘ to generate plot titles for the key from the text content of a data column, usually a first column of row headers. See the example given for spiderplot.


Axis tick labels can be generated via a string function, usually taking a data column as an argument. The simplest form uses the data column itself as a string. That is, xticlabels(N) is shorthand for xticlabels(stringcolumn(N)). This example uses the contents of column 3 as x-axis tick labels.

      plot 'datafile' using <xcol>:<ycol>:xticlabels(3) with <plotstyle>

Axis tick labels may be generated for any of the plot axes: x x2 y y2 z. The ‘ticlabels(<labelcol>)‘ specifiers must come after all of the data coordinate specifiers in the ‘using‘ portion of the command. For each data point which has a valid set of X,Y[,Z] coordinates, the string value given to xticlabels() is added to the list of xtic labels at the same X coordinate as the point it belongs to. ‘xticlabels()‘ may be shortened to ‘xtic()‘ and so on.


      splot "data" using 2:4:6:xtic(1):ytic(3):ztic(6)

In this example the x and y axis tic labels are taken from different columns than the x and y coordinate values. The z axis tics, however, are generated from the z coordinate of the corresponding point.


      plot "data" using 1:2:xtic( $3 > 10. ? "A" : "B" )

This example shows the use of a string-valued function to generate x-axis tick labels. Each point in the data file generates a tick mark on x labeled either "A" or "B" depending on the value in column 3.


See ‘plot using xticlabels‘.


See ‘plot using xticlabels‘.


See ‘plot using xticlabels‘.


See ‘plot using xticlabels‘.


EXPERIMENTAL (details may change in a future release version) 2D plots: colorbar labels are placed at the palette coordinate used by the plot for variable coloring "lc palette z". 3D plots: colorbar labels are placed at the z coordinate of the point. Note that in the case of a 3D heat map with variable color that does not match z, this is probably not the correct label. See also ‘plot using xticlabels‘. volatile

The volatile keyword in a plot command indicates that the data previously read from the input stream or file may not be available for re-reading. This tells the program to use refresh rather than replot commands whenever possible. See refresh.

3.18.4 errorbars

Error bars are supported for 2D data file plots by reading one to four additional columns (or ‘using‘ entries); these additional values are used in different ways by the various errorbar styles.

In the default situation, ‘gnuplot‘ expects to see three, four, or six numbers on each line of the data file—either

      (x, y, ydelta),
      (x, y, ylow, yhigh),
      (x, y, xdelta),
      (x, y, xlow, xhigh),
      (x, y, xdelta, ydelta), or
      (x, y, xlow, xhigh, ylow, yhigh).

The x coordinate must be specified. The order of the numbers must be exactly as given above, though the ‘using‘ qualifier can manipulate the order and provide values for missing columns. For example,

      plot 'file' with errorbars
      plot 'file' using 1:2:(sqrt($1)) with xerrorbars
      plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorbars

The last example is for a file containing an unsupported combination of relative x and absolute y errors. The ‘using‘ entry generates absolute x min and max from the relative error.

The y error bar is a vertical line plotted from (x, ylow) to (x, yhigh). If ydelta is specified instead of ylow and yhigh, ylow = y - ydelta and yhigh = y + ydelta are derived. If there are only two numbers on the record, yhigh and ylow are both set to y. The x error bar is a horizontal line computed in the same fashion. To get lines plotted between the data points, ‘plot‘ the data file twice, once with errorbars and once with lines (but remember to use the ‘notitle‘ option on one to avoid two entries in the key). Alternately, use the errorlines command (see errorlines).

The tic marks at the ends of the bar are controlled by errorbars.

If autoscaling is on, the ranges will be adjusted to include the error bars.

See also errorbar demos.

See ‘plot using‘, with, and style for more information.

3.18.5 errorlines

Lines with error bars are supported for 2D data file plots by reading one to four additional columns (or ‘using‘ entries); these additional values are used in different ways by the various errorlines styles.

In the default situation, ‘gnuplot‘ expects to see three, four, or six numbers on each line of the data file—either

      (x, y, ydelta),
      (x, y, ylow, yhigh),
      (x, y, xdelta),
      (x, y, xlow, xhigh),
      (x, y, xdelta, ydelta), or
      (x, y, xlow, xhigh, ylow, yhigh).

The x coordinate must be specified. The order of the numbers must be exactly as given above, though the ‘using‘ qualifier can manipulate the order and provide values for missing columns. For example,

      plot 'file' with errorlines
      plot 'file' using 1:2:(sqrt($1)) with xerrorlines
      plot 'file' using 1:2:($1-$3):($1+$3):4:5 with xyerrorlines

The last example is for a file containing an unsupported combination of relative x and absolute y errors. The ‘using‘ entry generates absolute x min and max from the relative error.

The y error bar is a vertical line plotted from (x, ylow) to (x, yhigh). If ydelta is specified instead of ylow and yhigh, ylow = y - ydelta and yhigh = y + ydelta are derived. If there are only two numbers on the record, yhigh and ylow are both set to y. The x error bar is a horizontal line computed in the same fashion.

The tic marks at the ends of the bar are controlled by errorbars.

If autoscaling is on, the ranges will be adjusted to include the error bars.

See ‘plot using‘, with, and style for more information.

3.18.6 functions

Built-in or user-defined functions can be displayed by the ‘plot‘ and ‘splot‘ commands in addition to, or instead of, data read from a file. The requested function is evaluated by sampling at regular intervals spanning the independent axis range[s]. See samples and isosamples. Example:

      approx(ang) = ang - ang**3 / (3*2)
      plot sin(x) title "sin(x)", approx(x) title "approximation"

To set a default plot style for functions, see ‘set style function‘. For information on built-in functions, see functions. For information on defining your own functions, see ‘user-defined‘.

3.18.7 parametric

When in parametric mode (parametric) mathematical expressions must be given in pairs for ‘plot‘ and in triplets for ‘splot‘.


      plot sin(t),t**2
      splot cos(u)*cos(v),cos(u)*sin(v),sin(u)

Data files are plotted as before, except any preceding parametric function must be fully specified before a data file is given as a plot. In other words, the x parametric function (‘sin(t)‘ above) and the y parametric function (‘t**2‘ above) must not be interrupted with any modifiers or data functions; doing so will generate a syntax error stating that the parametric function is not fully specified.

Other modifiers, such as with and title, may be specified only after the parametric function has been completed:

      plot sin(t),t**2 title 'Parametric example' with linespoints

See also Parametric Mode Demos.

3.18.8 ranges

This section describes only the optional axis ranges that may appear as the very first items in a ‘plot‘ command. If present, these ranges override any range limits established by a previous ‘set range‘ statement. For optional ranges elsewhere in a ‘plot‘ command that limit sampling of an individual plot component see sampling.



The first form applies to the independent variable (xrange or trange, if in parametric mode). The second form applies to dependent variables. <dummy-var> optionally establishes a new name for the independent variable. (The default name may be changed with dummy.)

In non-parametric mode, ranges must be given in the order

      plot [<xrange>][<yrange>][<x2range>][<y2range>] ...

In parametric mode, ranges must be given in the order

      plot [<trange>][<xrange>][<yrange>][<x2range>][<y2range>] ...

The following ‘plot‘ command shows setting trange to [-pi:pi], xrange to [-1.3:1.3] and yrange to [-1:1] for the duration of the graph:

      plot [-pi:pi] [-1.3:1.3] [-1:1] sin(t),t**2

‘*‘ can be used to allow autoscaling of either of min and max. Use an empty range ‘[]‘ as a placeholder if necessary.

Ranges specified on the ‘plot‘ or ‘splot‘ command line affect only that one graph; use the xrange, yrange, etc., commands to change the default ranges for future graphs.

The use of on-the-fly range specifiers in a plot command may not yield the expected result for linked axes (see link).

For time data you must provide the range in quotes, using the same format used to read time from the datafile. See timefmt.


This uses the current ranges:

      plot cos(x)

This sets the x range only:

      plot [-10:30] sin(pi*x)/(pi*x)

This is the same, but uses t as the dummy-variable:

      plot [t = -10 :30]  sin(pi*t)/(pi*t)

This sets both the x and y ranges:

      plot [-pi:pi] [-3:3]  tan(x), 1/x

This sets only the y range:

      plot [ ] [-2:sin(5)*-8] sin(x)**besj0(x)

This sets xmax and ymin only:

      plot [:200] [-pi:]  $mydata using 1:2

This sets the x range for a timeseries:

      set timefmt "%d/%m/%y %H:%M"
      plot ["1/6/93 12:00":"5/6/93 12:00"] 'timedata.dat'

3.18.9 sampling 1D sampling (x or t axis)

By default, computed functions or data generated for the pseudo-file "+" are sampled over the entire range of the plot as set by a prior xrange command, by an explicit global range specifier at the very start of the plot or splot command, or by autoscaling the xrange to span data seen in all the elements of this plot. However, individual plot components can be assigned a more restricted sampling range.


This establishes a total range on x running from 0 to 1000 and then plots data from a file and two functions each spanning a portion of the total range:

      plot [0:1000] 'datafile', [0:200] func1(x), [200:500] func2(x)

This is similar except that the total range is established by the contents of the data file. In this case the sampled functions may or may not be entirely contained in the plot:

      set autoscale x
      plot 'datafile', [0:200] func1(x), [200:500] func2(x)

This command is ambiguous. The initial range will be interpreted as applying to the entire plot, not solely to the sampling of the first function as was probably the intent:

      plot [0:10] f(x), [10:20] g(x), [20:30] h(x)

This command removes the ambiguity of the previous example by inserting the keyword ‘sample‘ so that the range is not applied to the entire plot:

      plot sample [0:10] f(x), [10:20] g(x), [20:30] h(x)

This example shows one way of tracing out a helix in a 3D plot

      splot [-2:2][-2:2] sample [h=1:10] '+' using (cos(h)):(sin(h)):(h) 2D sampling (u and v axes)

Computed functions or data generated for the pseudo-file ’++’ use samples generated along the u and v axes. This is a CHANGE from versions prior to 5.2 which sampled along the x and y axes. See ‘special-filenames ++‘. 2D sampling can be used in either ‘plot‘ or ‘splot‘ commands.

Example of 2D sampling in a 2D ‘plot‘ command. These commands generated the plot shown for plotstyle vectors. See vectors.

     set urange [ -2.0 : 2.0 ]
     set vrange [ -2.0 : 2.0 ]
     plot '++' using ($1):($2):($2*0.4):(-$1*0.4) with vectors

Example of 2D sampling in a 3D ‘splot‘ command. These commands are similar to the ones used in ‘sampling.dem‘. Note that the two surfaces are sampled over u and v ranges smaller than the full x and y ranges of the resulting plot.

     set title "3D sampling range distinct from plot x/y range"
     set xrange [1:100]
     set yrange [1:100]
     splot sample [u=30:70][v=0:50] '++' using 1:2:(u*v) lt 3, \
           [u=40:80][v=30:60] '++' using (u):(v):(u*sqrt(v)) lt 4

The range specifiers for sampling on u and v can include an explicit sampling interval to control the number and spacing of samples:

     splot sample [u=30:70:1][v=0:50:5] '++' using 1:2:(func($1,$2))

3.18.10 for loops in plot command

If many similar files or functions are to be plotted together, it may be convenient to do so by iterating over a shared plot command.


      plot for [<variable> = <start> : <end> {:<increment>}]
      plot for [<variable> in "string of words"]

The scope of an iteration ends at the next comma or the end of the command, whichever comes first. An exception to this is that definitions are grouped with the following plot item even if there is an intervening comma. Note that iteration does not work for plots in parametric mode.


      plot for [j=1:3] sin(j*x)


      plot for [dataset in "apples bananas"] dataset."dat" title dataset

In this example iteration is used both to generate a file name and a corresponding title.


      file(n) = sprintf("dataset_%d.dat",n)
      splot for [i=1:10] file(i) title sprintf("dataset %d",i)

This example defines a string-valued function that generates file names, and plots ten such files together. The iteration variable (’i’ in this example) is treated as an integer, and may be used more than once.


      set key left
      plot for [n=1:4] x**n sprintf("%d",n)

This example plots a family of functions.


      list = "apple banana cabbage daikon eggplant"
      item(n) = word(list,n)
      plot for [i=1:words(list)] item[i].".dat" title item(i)
      list = "new stuff"

This example steps through a list and plots once per item. Because the items are retrieved dynamically, you can change the list and then replot.


      list = "apple banana cabbage daikon eggplant"
      plot for [i in list] i.".dat" title i
      list = "new stuff"

This example does exactly the same thing as the previous example, but uses the string iterator form of the command rather than an integer iterator.

If an iteration is to continue until all available data is consumed, use the symbol * instead of an integer <end>. This can be used to process all columns in a line, all datasets (separated by 2 blank lines) in a file, or all files matching a template.


      plot for [i=2:*] 'datafile' using 1:i with histogram
      splot for [i=0:*] 'datafile' index i using 1:2:3 with lines
      plot for [i=1:*] file=sprintf("File_%03d.dat",i) file using 2 title file

3.18.11 title

By default each plot is listed in the key by the corresponding function or file name. You can give an explicit plot title instead using the title option.


      title <text> | notitle [<ignored text>]
      title columnheader | title columnheader(N)
            {at {beginning|end}} {{no}enhanced}

where <text> is a quoted string or an expression that evaluates to a string. The quotes will not be shown in the key. Note: Starting with gnuplot version 5.4, if <text> is an expression or function it it evaluated after the corresponding function or data stream is plotted. This allows the title to reference quantities calculated or input during plotting, which was not possible in earlier gnuplot versions.

There is also an option that will interpret the first entry in a column of input data (i.e. the column header) as a text field, and use it as the key title. See ‘datastrings‘. This can be made the default by specifying ‘set key autotitle columnhead‘.

The line title and sample can be omitted from the key by using the keyword ‘notitle‘. A null title (‘title ”‘) is equivalent to ‘notitle‘. If only the sample is wanted, use one or more blanks (‘title ’ ’‘). If ‘notitle‘ is followed by a string this string is ignored.

If ‘key autotitles‘ is set (which is the default) and neither title nor ‘notitle‘ are specified the line title is the function name or the file name as it appears on the ‘plot‘ command. If it is a file name, any datafile modifiers specified will be included in the default title.

The layout of the key itself (position, title justification, etc.) can be controlled using ‘set key‘.

The ‘at‘ keyword allows you to place the plot title somewhere outside the auto-generated key box. The title can be placed immediately before or after the line in the graph itself by using ‘at {beginning|end}‘. This option may be useful when plotting ‘with lines‘ but makes little sense for most other styles.

To place the plot title at an arbitrary location on the page, use the form ‘at <x-position>,<y-position>‘. By default the position is interpreted in screen coordinates; e.g. ‘at 0.5, 0.5‘ is always the middle of the screen regardless of plot axis scales or borders. The format of titles placed in this way is still affected by key options. See ‘set key‘.


This plots y=x with the title ’x’:

      plot x

This plots x squared with title "x^2" and file "data.1" with title "measured data":

      plot x**2 title "x^2", 'data.1' t "measured data"

Plot multiple columns of data, each of which contains its own title on the first line of the file. Place the titles after the corresponding lines rather than in a separate key:

      unset key
      set offset 0, graph 0.1
      plot for [i=1:4] 'data' using i with lines title columnhead at end

Create a single key area for two separate plots:

      set key Left reverse
      set multiplot layout 2,2
      plot sin(x) with points pt 6 title "Left plot is sin(x)" at 0.5, 0.30
      plot cos(x) with points pt 7 title "Right plot is cos(x)" at 0.5, 0.27
      unset multiplot

3.18.12 with

Functions and data may be displayed in one of a large number of styles. The with keyword provides the means of selection.


      with <style> { {linestyle | ls <line_style>}
                     | {{linetype  | lt <line_type>}
                        {linewidth | lw <line_width>}
                        {linecolor | lc <colorspec>}
                        {pointtype | pt <point_type>}
                        {pointsize | ps <point_size>}
                        {arrowstyle | as <arrowstyle_index>}
                        {fill | fs <fillstyle>} {fillcolor | fc <colorspec>}
                        {nohidden3d} {nocontours} {nosurface}

where <style> is one of

     lines        dots       steps     vectors      yerrorlines
     points       impulses   fsteps    xerrorbar    xyerrorbars 
     linespoints  labels     histeps   xerrorlines  xyerrorlines
     financebars  surface    arrows    yerrorbar    parallelaxes


     boxes         boxplot        ellipses       histograms  rgbalpha
     boxerrorbars  candlesticks   filledcurves   image       rgbimage
     boxxyerror    circles        fillsteps      pm3d        polygons
     isosurface    zerrorfill



The first group of styles have associated line, point, and text properties. The second group of styles also have fill properties. See ‘fillstyle‘. Some styles have further sub-styles. See ‘plotting styles‘ for details of each. The table style produces tabular output rather than a plot. See table.

A default style may be chosen by ‘set style function‘ and ‘set style data‘.

By default, each function and data file will use a different line type and point type, up to the maximum number of available types. All terminal drivers support at least six different point types, and re-use them, in order, if more are required. To see the complete set of line and point types available for the current terminal, type test.

If you wish to choose the line or point type for a single plot, <line_type> and <point_type> may be specified. These are positive integer constants (or expressions) that specify the line type and point type to be used for the plot. Use test to display the types available for your terminal.

You may also scale the line width and point size for a plot by using <line_width> and <point_size>, which are specified relative to the default values for each terminal. The pointsize may also be altered globally—see pointsize for details. But note that both <point_size> as set here and as set by pointsize multiply the default point size—their effects are not cumulative. That is, ‘set pointsize 2; plot x w p ps 3‘ will use points three times default size, not six.

It is also possible to specify ‘pointsize variable‘ either as part of a line style or for an individual plot. In this case one extra column of input is required, i.e. 3 columns for a 2D plot and 4 columns for a 3D splot. The size of each individual point is determined by multiplying the global pointsize by the value read from the data file.

If you have defined specific line type/width and point type/size combinations with ‘set style line‘, one of these may be selected by setting <line_style> to the index of the desired style.

Both 2D and 3D plots (‘plot‘ and ‘splot‘ commands) can use colors from a smooth palette set previously with the command palette. The color value corresponds to the z-value of the point itself or to a separate color coordinate provided in an optional additional ‘using‘ colymn. Color values may be treated either as a fraction of the palette range (‘palette frac‘) or as a coordinate value mapped onto the colorbox range (palette or ‘palette z‘). See colorspec, palette, ‘linetype‘.

The keyword ‘nohidden3d‘ applies only to plots made with the ‘splot‘ command. Normally the global option hidden3d applies to all plots in the graph. You can attach the ‘nohidden3d‘ option to any individual plots that you want to exclude from the hidden3d processing. The individual elements other than surfaces (i.e. lines, dots, labels, ...) of a plot marked ‘nohidden3d‘ will all be drawn, even if they would normally be obscured by other plot elements.

Similarly, the keyword ‘nocontours‘ will turn off contouring for an individual plot even if the global property contour is active.

Similarly, the keyword ‘nosurface‘ will turn off the 3D surface for an individual plot even if the global property surface is active.

The keywords may be abbreviated as indicated.

Note that the ‘linewidth‘, pointsize and palette options are not supported by all terminals.


This plots sin(x) with impulses:

      plot sin(x) with impulses

This plots x with points, x**2 with the default:

      plot x w points, x**2

This plots tan(x) with the default function style, file "data.1" with lines:

      plot [ ] [-2:5] tan(x), 'data.1' with l

This plots "leastsq.dat" with impulses:

      plot 'leastsq.dat' w i

This plots the data file "population" with boxes:

      plot 'population' with boxes

This plots "exper.dat" with errorbars and lines connecting the points (errorbars require three or four columns):

      plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars

Another way to plot "exper.dat" with errorlines (errorbars require three or four columns):

      plot 'exper.dat' w errorlines

This plots sin(x) and cos(x) with linespoints, using the same line type but different point types:

      plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4

This plots file "data" with points of type 3 and twice usual size:

      plot 'data' with points pointtype 3 pointsize 2

This plots file "data" with variable pointsize read from column 4

      plot 'data' using 1:2:4 with points pt 5 pointsize variable

This plots two data sets with lines differing only by weight:

      plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1

This plots filled curve of x*x and a color stripe:

      plot x*x with filledcurve closed, 40 with filledcurve y=10

This plots x*x and a color box:

      plot x*x, (x>=-5 && x<=5 ? 40 : 1/0) with filledcurve y=10 lt 8

This plots a surface with color lines:

      splot x*x-y*y with line palette

This plots two color surfaces at different altitudes:

      splot x*x-y*y with pm3d, x*x+y*y with pm3d at t


      print <expression> {, <expression>, ...}

The ‘print‘ command prints the value of one or more expressions. Output is to the screen unless it has been redirected using a prior ‘set print‘ command. See ‘expressions‘. See also printerr.

An <expression> may be any valid gnuplot expression, including numeric or string constants, a function returning a number or string, an array, or the name of a variable. It is also possible to print a datablock. The sprintf and gprintf functions can be used in conjunction with ‘print‘ for additional flexibility in formmating output.


     print 123 + 456
     print sinh(pi/2)
     print "rms of residuals (FIT_STDFIT) is ", FIT_STDFIT
     print sprintf("rms of residuals is %.3f after fit.", FIT_STDFIT)
     print $DATA

3.20 printerr

printerr is the same as print except that output is always sent to stderr even if a prior ‘set print‘ command remains in effect.

3.21 pwd

The pwd command prints the name of the working directory to the screen.

Note that if you wish to store the current directory into a string variable or use it in string expressions, then you can use variable GPVAL_PWD, see ‘show variables all‘.

3.22 quit

The exit and quit commands and END-OF-FILE character will exit ‘gnuplot‘. Each of these commands will clear the output device (as does the clear command) before exiting.

3.23 raise


      raise {plot_window_id}
      lower {plot_window_id}

The raise and lower commands function only for a some terminal types and may depend also on your window manager and display preference settings. An example of use is shown here

      set term wxt 123     # create first plot window
      plot $FOO
      lower                # lower the only plot window that exists so far
      set term wxt 456     # create 2nd plot window may occlude the first one
      plot $BAZ
      raise 123            # raise first plot window

These commands are known to be unreliable.

3.24 refresh

The refresh command is similar to replot, with two major differences. refresh reformats and redraws the current plot using the data already read in. This means that you can use refresh for plots with inline data (pseudo-device ’-’) and for plots from datafiles whose contents are volatile. You cannot use the refresh command to add new data to an existing plot.

Mousing operations, in particular zoom and unzoom, will use refresh rather than replot if appropriate. Example:

      plot 'datafile' volatile with lines, '-' with labels
      100 200 "Special point"
      # Various mousing operations go here
      set title "Zoomed in view"
      set term post
      set output ''

3.25 replot

The replot command without arguments repeats the last ‘plot‘ or ‘splot‘ command. This can be useful for viewing a plot with different ‘set‘ options, or when generating the same plot for several devices.

Arguments specified after a replot command will be added onto the last ‘plot‘ or ‘splot‘ command (with an implied ’,’ separator) before it is repeated. replot accepts the same arguments as the ‘plot‘ and ‘splot‘ commands except that ranges cannot be specified. Thus you can use replot to plot a function against the second axes if the previous command was ‘plot‘ but not if it was ‘splot‘.

N.B.—use of

      plot '-' ; ... ; replot

is not recommended, because it will require that you type in the data all over again. In most cases you can use the refresh command instead, which will redraw the plot using the data previously read in.

Note that in multiplot mode, replot can only reproduce the most recent component plot, not the full set.

See also ‘command-line-editing‘ for ways to edit the last ‘plot‘ (‘splot‘) command.

See also ‘show plot‘ to show the whole current plotting command, and the possibility to copy it into the ‘history‘.

3.26 reread

[DEPRECATED in version 5.4]

This command is deprecated in favor of explicit iteration. See ‘iterate‘. The reread command causes the current ‘gnuplot‘ command file, as specified by a ‘load‘ command, to be reset to its starting point before further commands are read from it. This essentially implements an endless loop of the commands from the beginning of the command file to the reread command. The reread command has no effect when reading interactively (from stdin).

3.27 reset

     reset {bind | errors | session}

The reset command causes all graph-related options that can be set with the ‘set‘ command to return to their default values. This command can be used to restore the default settings after executing a loaded command file, or to return to a defined state after lots of settings have been changed.

The following are _not_ affected by reset:

Note that reset does not necessarily return settings to the state they were in at program entry, because the default values may have been altered by commands in the initialization files gnuplotrc, $HOME/.gnuplot, or $XDG_CONFIG_HOME/gnuplot/gnuplotrc. However, these commands can be re-executed by using the variant command ‘reset session‘.

‘reset session‘ deletes any user-defined variables and functions, restores default settings, and then re-executes the system-wide gnuplotrc initialization file and any private $HOME/.gnuplot or $XDG_CONFIG_HOME/gnuplot/gnuplotrc preferences file. See ‘initialization‘.

‘reset errors‘ clears only the error state variables GPVAL_ERRNO and GPVAL_ERRMSG.

‘reset bind‘ restores all hotkey bindings to their default state.

3.28 save


      save  {functions | variables | terminal | set | fit} '<filename>'

If no option is specified, ‘gnuplot‘ saves functions, variables, ‘set‘ options and the last ‘plot‘ (‘splot‘) command.

saved files are written in text format and may be read by the ‘load‘ command. For save with the ‘set‘ option or without any option, the terminal choice and the output filename are written out as a comment, to get an output file that works in other installations of gnuplot, without changes and without risk of unwillingly overwriting files.

terminal will write out just the terminal status, without the comment marker in front of it. This is mainly useful for switching the terminal setting for a short while, and getting back to the previously set terminal, afterwards, by loading the saved terminal status. Note that for a single gnuplot session you may rather use the other method of saving and restoring current terminal by the commands ‘set term push‘ and ‘set term pop‘, see ‘set term‘.

fit saves only the variables used in the most recent fit command. The saved file may be used as a parameter file to initialize future fit commands using the ‘via‘ keyword.

The filename must be enclosed in quotes.

The special filename "-" may be used to save commands to standard output. On systems which support a popen function (Unix), the output of save can be piped through an external program by starting the file name with a ’|’. This provides a consistent interface to ‘gnuplot‘’s internal settings to programs which communicate with ‘gnuplot‘ through a pipe. Please see help for ‘batch/interactive‘ for more details.


      save 'work.gnu'
      save functions 'func.dat'
      save var 'var.dat'
      save set 'options.dat'
      save term 'myterm.gnu'
      save '-'
      save '|grep title >'

3.29 set-show

The ‘set‘ command can be used to set _lots_ of options. No screen is drawn, however, until a ‘plot‘, ‘splot‘, or replot command is given.

The ‘show‘ command shows their settings; ‘show all‘ shows all the settings.

Options changed using ‘set‘ can be returned to the default state by giving the corresponding unset command. See also the reset command, which returns all settable parameters to default values.

The ‘set‘ and unset commands may optionally contain an iteration clause. See ‘plot for‘.

3.29.1 angles

By default, ‘gnuplot‘ assumes the independent variable in polar graphs is in units of radians. If ‘set angles degrees‘ is specified before ‘set polar‘, then the default range is [0:360] and the independent variable has units of degrees. This is particularly useful for plots of data files. The angle setting also applies to 3D mapping as set via the mapping command.


      set angles {degrees | radians}
      show angles

The angle specified in ‘set grid polar‘ is also read and displayed in the units specified by angles.

angles also affects the arguments of the machine-defined functions sin(x), cos(x) and tan(x), and the outputs of asin(x), acos(x), atan(x), atan2(x), and arg(x). It has no effect on the arguments of hyperbolic functions or Bessel functions. However, the output arguments of inverse hyperbolic functions of complex arguments are affected; if these functions are used, ‘set angles radians‘ must be in effect to maintain consistency between input and output arguments.

      set angles radians
      print y         #prints {1.16933, 0.154051}
      print asinh(y)  #prints {1.0, 0.1}


      set angles degrees
      print y         #prints {1.16933, 0.154051}
      print asinh(y)  #prints {57.29578, 5.729578}

See also poldat.dem: polar plot using angles demo.

3.29.2 arrow

Arbitrary arrows can be placed on a plot using the ‘set arrow‘ command.


      set arrow {<tag>} from <position> to <position>
      set arrow {<tag>} from <position> rto <position>
      set arrow {<tag>} from <position> length <coord> angle <ang>
      set arrow <tag> arrowstyle | as <arrow_style>
      set arrow <tag> {nohead | head | backhead | heads}
                      {size <headlength>,<headangle>{,<backangle>}} {fixed}
                      {filled | empty | nofilled | noborder}
                      {front | back}
                      {linestyle | ls <line_style>}
                      {linetype | lt <line_type>}
                      {linewidth | lw <line_width>}
                      {linecolor | lc <colorspec>}
                      {dashtype | dt <dashtype>}

      unset arrow {<tag>}
      show arrow {<tag>}

<tag> is an integer that identifies the arrow. If no tag is given, the lowest unused tag value is assigned automatically. The tag can be used to delete or change a specific arrow. To change any attribute of an existing arrow, use the ‘set arrow‘ command with the appropriate tag and specify the parts of the arrow to be changed.

The position of the first end point of the arrow is always specified by "from". The other end point can be specified using any of three different mechanisms. The <position>s are specified by either x,y or x,y,z, and may be preceded by ‘first‘, ‘second‘, ‘graph‘, ‘screen‘, or ‘character‘ to select the coordinate system. Unspecified coordinates default to 0. See ‘coordinates‘ for details. A coordinate system specifier does not carry over from the first endpoint description the second.

1) "to <position>" specifies the absolute coordinates of the other end.

2) "rto <position>" specifies an offset to the "from" position. For linear axes, ‘graph‘ and ‘screen‘ coordinates, the distance between the start and the end point corresponds to the given relative coordinate. For logarithmic axes, the relative given coordinate corresponds to the factor of the coordinate between start and end point. Thus, a negative relative value or zero are not allowed for logarithmic axes.

3) "length <coordinate> angle <angle>" specifies the orientation of the arrow in the plane of the graph. Again any of the coordinate systems can be used to specify the length. The angle is always in degrees.

Other characteristics of the arrow can either be specified as a pre-defined arrow style or by providing them in ‘set arrow‘ command. For a detailed explanation of arrow characteristics, see ‘arrowstyle‘.


To set an arrow pointing from the origin to (1,2) with user-defined linestyle 5, use:

      set arrow to 1,2 ls 5

To set an arrow from bottom left of plotting area to (-5,5,3), and tag the arrow number 3, use:

      set arrow 3 from graph 0,0 to -5,5,3

To change the preceding arrow to end at 1,1,1, without an arrow head and double its width, use:

      set arrow 3 to 1,1,1 nohead lw 2

To draw a vertical line from the bottom to the top of the graph at x=3, use:

      set arrow from 3, graph 0 to 3, graph 1 nohead

To draw a vertical arrow with T-shape ends, use:

      set arrow 3 from 0,-5 to 0,5 heads size screen 0.1,90

To draw an arrow relatively to the start point, where the relative distances are given in graph coordinates, use:

      set arrow from 0,-5 rto graph 0.1,0.1

To draw an arrow with relative end point in logarithmic x axis, use:

      set logscale x
      set arrow from 100,-5 rto 10,10

This draws an arrow from 100,-5 to 1000,5. For the logarithmic x axis, the relative coordinate 10 means "factor 10" while for the linear y axis, the relative coordinate 10 means "difference 10".

To delete arrow number 2, use:

      unset arrow 2

To delete all arrows, use:

      unset arrow

To show all arrows (in tag order), use:

      show arrow

arrows demos.

3.29.3 autoscale

Autoscaling may be set individually on the x, y or z axis or globally on all axes. The default is to autoscale all axes. If you want to autoscale based on a subset of the plots in the figure, you can mark the other ones with the flag ‘noautoscale‘. See datafile.


      set autoscale {<axis>{|min|max|fixmin|fixmax|fix} | fix | keepfix}
      set autoscale noextend
      unset autoscale {<axis>}
      show autoscale

where <axis> is ‘x‘, ‘y‘, ‘z‘, ‘cb‘, ‘x2‘, ‘y2‘, ‘xy‘, or ‘paxis <p>‘. Appending ‘min‘ or ‘max‘ to the axis name tells ‘gnuplot‘ to autoscale only the minimum or maximum of that axis.

If no axis name is given, all axes are autoscaled.

Autoscaling the independent axes (x for ‘plot‘ and x,y for ‘splot‘) adjusts the axis range to match the data being plotted. If the plot contains only functions (no input data), autoscaling these axes has no effect.

Autoscaling the dependent axis (y for a ‘plot‘ and z for ‘splot‘) adjusts the axis range to match the data or function being plotted.

Adjustment of the axis range includes extending it to the next tic mark; i.e. unless the extreme data coordinate exactly matches a tic mark, there will be some blank space between the data and the plot border. Addition of this extra space can be suppressed by noextend. It can be further increased by the command ‘set offset‘. Please see xrange and offsets for additional information.

The behavior of autoscaling remains consistent in parametric mode, (see parametric). However, there are more dependent variables and hence more control over x, y, and z axis scales. In parametric mode, the independent or dummy variable is t for ‘plot‘s and u,v for ‘splot‘s. autoscale in parametric mode, then, controls all ranges (t, u, v, x, y, and z) and allows x, y, and z to be fully autoscaled.

When tics are displayed on second axes but no plot has been specified for those axes, x2range and y2range are inherited from xrange and yrange. This is done _before_ applying offsets or autoextending the ranges to a whole number of tics, which can cause unexpected results. To prevent this you can explicitly link the secondary axis range to the primary axis range. See link. noextend

     set autoscale noextend

By default autoscaling sets the axis range limits to the nearest tic label position that includes all the plot data. Keywords ‘fixmin‘, ‘fixmax‘, ‘fix‘ or noextend tell gnuplot to disable extension of the axis range to the next tic mark position. In this case the axis range limit exactly matches the coordinate of the most extreme data point. noextend is a synonym for ‘set autoscale fix‘. Range extension for a single axis can be disabled by appending the noextend keyword to the corresponding range command, e.g.

     set yrange [0:*] noextend

‘set autoscale keepfix‘ autoscales all axes while leaving the fix settings unchanged. examples


This sets autoscaling of the y axis (other axes are not affected):

      set autoscale y

This sets autoscaling only for the minimum of the y axis (the maximum of the y axis and the other axes are not affected):

      set autoscale ymin

This disables extension of the x2 axis tics to the next tic mark, thus keeping the exact range as found in the plotted data and functions:

      set autoscale x2fixmin
      set autoscale x2fixmax

This sets autoscaling of the x and y axes:

      set autoscale xy

This sets autoscaling of the x, y, z, x2 and y2 axes:

      set autoscale

This disables autoscaling of the x, y, z, x2 and y2 axes:

      unset autoscale

This disables autoscaling of the z axis only:

      unset autoscale z polar mode

When in polar mode (‘set polar‘), the xrange and the yrange may be left in autoscale mode. If rrange is used to limit the extent of the polar axis, then xrange and yrange will adjust to match this automatically. However, explicit xrange and yrange commands can later be used to make further adjustments. See rrange.

See also polar demos.

3.29.4 bind

‘show bind‘ shows the current state of all hotkey bindings. See ‘bind‘.

3.29.5 bmargin

The command bmargin sets the size of the bottom margin. Please see margin for details.

3.29.6 border

The border and border commands control the display of the graph borders for the ‘plot‘ and ‘splot‘ commands. Note that the borders do not necessarily coincide with the axes; with ‘plot‘ they often do, but with ‘splot‘ they usually do not.


      set border {<integer>}
                 {front | back | behind}
                 {linestyle | ls <line_style>}
                 {linetype | lt <line_type>} {linewidth | lw <line_width>}
                 {linecolor | lc <colorspec>} {dashtype | dt <dashtype>}
      unset border
      show border

With a ‘splot‘ displayed in an arbitrary orientation, like ‘set view 56,103‘, the four corners of the x-y plane can be referred to as "front", "back", "left" and "right". A similar set of four corners exist for the top surface, of course. Thus the border connecting, say, the back and right corners of the x-y plane is the "bottom right back" border, and the border connecting the top and bottom front corners is the "front vertical". (This nomenclature is defined solely to allow the reader to figure out the table that follows.)

The borders are encoded in a 12-bit integer: the four low bits control the border for ‘plot‘ and the sides of the base for ‘splot‘; the next four bits control the verticals in ‘splot‘; the four high bits control the edges on top of an ‘splot‘. The border settings is thus the sum of the appropriate entries from the following table:

            Bit     plot        splot
              1   bottom      bottom left front
              2   left        bottom left back
              4   top         bottom right front
              8   right       bottom right back
             16   no effect   left vertical
             32   no effect   back vertical
             64   no effect   right vertical
            128   no effect   front vertical
            256   no effect   top left back
            512   no effect   top right back
           1024   no effect   top left front
           2048   no effect   top right front
           4096   polar       no effect

The default setting is 31, which is all four sides for ‘plot‘, and base and z axis for ‘splot‘.

In 2D plots the border is normally drawn on top of all plots elements (‘front‘). If you want the border to be drawn behind the plot elements, use ‘set border back‘.

In hidden3d plots the lines making up the border are normally subject to the same hidden3d processing as the plot elements. ‘set border behind‘ will override this default.

Using the optional <linestyle>, <linetype>, <linewidth>, <linecolor>, and <dashtype> specifiers, the way the border lines are drawn can be influenced (limited by what the current terminal driver supports). Besides the border itself, this line style is used for the tics, independent of whether they are plotted on the border or on the axes (see ‘set xtics‘).

For ‘plot‘, tics may be drawn on edges other than bottom and left by enabling the second axes – see ‘set xtics‘ for details.

If a ‘splot‘ draws only on the base, as is the case with "‘unset surface; set contour base‘", then the verticals and the top are not drawn even if they are specified.

The ‘set grid‘ options ’back’, ’front’ and ’layerdefault’ also control the order in which the border lines are drawn with respect to the output of the plotted data.

The ‘polar‘ keyword enables a circular border for polar plots.


Draw default borders:

      set border

Draw only the left and bottom (‘plot‘) or both front and back bottom left (‘splot‘) borders:

      set border 3

Draw a complete box around a ‘splot‘:

      set border 4095

Draw a topless box around a ‘splot‘, omitting the front vertical:

      set border 127+256+512 # or set border 1023-128

Draw only the top and right borders for a ‘plot‘ and label them as axes:

      unset xtics; unset ytics; set x2tics; set y2tics; set border 12

3.29.7 boxwidth

The boxwidth command is used to set the default width of boxes in the boxes, boxerrorbars, boxplot, candlesticks and histograms styles.


      set boxwidth {<width>} {absolute|relative}
      show boxwidth

By default, adjacent boxes are extended in width until they touch each other. A different default width may be specified using the boxwidth command. ‘Relative‘ widths are interpreted as being a fraction of this default width.

An explicit value for the boxwidth is interpreted as being a number of units along the current x axis (‘absolute‘) unless the modifier ‘relative‘ is given. If the x axis is a log-scale (see ‘set log‘) then the value of boxwidth is truly "absolute" only at x=1; this physical width is maintained everywhere along the axis (i.e. the boxes do not become narrower the value of x increases). If the range spanned by a log scale x axis is far from x=1, some experimentation may be required to find a useful value of boxwidth.

The default is superseded by explicit width information taken from an extra data column in styles boxes or boxerrorbars. In a four-column data set, the fourth column will be interpreted as the box width unless the width is set to -2.0, in which case the width will be calculated automatically. See boxes and boxerrorbars for more details.

To set the box width to automatic use the command

      set boxwidth

or, for four-column data,

      set boxwidth -2

The same effect can be achieved with the ‘using‘ keyword in ‘plot‘:

      plot 'file' using 1:2:3:4:(-2)

To set the box width to half of the automatic size use

      set boxwidth 0.5 relative

To set the box width to an absolute value of 2 use

      set boxwidth 2 absolute

3.29.8 boxdepth

The boxdepth command affects only 3D plots created by boxes. It sets the extent of each box along the y axis, i.e. its thickness.

3.29.9 color

Gnuplot supports two alternative sets of linetypes. The default set uses a different color for each linetype, although it also allows you to draw dotted or dashed lines in that color. The alternative monochrome set uses only dot/dash pattern or linewidth to distinguish linetypes. The ‘set color‘ command selects the color linetypes. See monochrome, ‘set linetype‘, and colorsequence.

3.29.10 colorsequence


     set colorsequence {default|classic|podo}

‘set colorsequence default‘ selects a terminal-independent repeating sequence of eight colors. See ‘set linetype‘, ‘colors‘.

‘set colorsequence classic‘ lets each separate terminal type provide its own sequence of line colors. The number provided varies from 4 to more than 100, but most start with red/green/blue/magenta/cyan/yellow. This was the default behaviour prior to version 5.

‘set colorsequence podo‘ selects eight colors drawn from a set recommended by Wong (2011) [Nature Methods 8:441] as being easily distinguished by color-blind viewers with either protanopia or deuteranopia.

In each case you can further customize the length of the sequence and the colors used. See ‘set linetype‘, ‘colors‘.

3.29.11 clabel

This command is deprecated. Use cntrlabel instead. clabel is replaced by ‘set cntrlabel onecolor‘. ‘set clabel "format"‘ is replaced by ‘set cntrlabel format "format"‘.

3.29.12 clip


      set clip {points|one|two|radial}
      unset clip {points|one|two|radial}
      show clip

Default state:

      unset clip points
      set clip one
      unset clip two
      unset clip radial

Data points whose center lies inside the plot boundaries are normally drawn even if the finite size of the point symbol causes it to extend past a boundary line. ‘set clip points‘ causes such points to be clipped (i.e. not drawn) even though the point center is inside the boundaries of a 2D plot. Data points whose center lies outside the plot boundaries are never drawn.

‘unset clip‘ causes a line segment in a plot not to be drawn if either end of that segment lies outside the plot boundaries (i.e. xrange and yrange).

‘set clip one‘ causes ‘gnuplot‘ to draw the in-range portion of line segments with one endpoint in range and one endpoint out of range. ‘set clip two‘ causes ‘gnuplot‘ to draw the in-range portion of line segments with both endpoints out of range. Line segments that lie entirely outside the plot boundaries are never drawn.

‘set clip radial‘ affects plotting only in polar mode. It clips lines against the radial bound established by ‘set rrange [0:MAX]‘. This criteria is applied in conjunction with ‘set clip {one|two}‘. I.e. the portion of a line between two points with R > RMAX that passes through the circle R = RMAX is drawn only if both ‘clip two‘ and ‘clip radial‘ are set.


* ‘set clip‘ affects only points and lines produced by plot styles ‘lines‘, linespoints, ‘points‘, ‘arrows‘, and vectors.

* Clipping of colored quadrangles drawn for pm3d surfaces and other solid objects is controlled clipping. The default is smooth clipping against the current zrange.

* Object clipping is controlled by the ‘clip‘ or ‘noclip‘ property of the individual object.

* In the current version of gnuplot, "plot with vectors" in polar mode does not test or clip against the maximum radius.

3.29.13 cntrlabel


      set cntrlabel {format "format"} {font "font"}
      set cntrlabel {start <int>} {interval <int>}
      set contrlabel onecolor

cntrlabel controls the labeling of contours, either in the key (default) or on the plot itself in the case of labels. In the latter case labels are placed along each contour line according to the ‘pointinterval‘ or ‘pointnumber‘ property of the label descriptor. By default a label is placed on the 5th line segment making up the contour line and repeated every 20th segment. These defaults are equivalent to

      set cntrlabel start 5 interval 20

They can be changed either via the cntrlabel command or by specifying the interval in the ‘splot‘ command itself

      set contours; splot $FOO with labels point pointinterval -1

Setting the interval to a negative value means that the label appear only once per contour line. However if samples or isosamples is large then many contour lines may be created, each with a single label.

A contour label is placed in the plot key for each linetype used. By default each contour level is given its own linetype, so a separate label appears for each. The command ‘set cntrlabel onecolor‘ causes all contours to be drawn using the same linetype, so only one label appears in the plot key. This command replaces an older command clabel.

3.29.14 cntrparam

cntrparam controls the generation of contours and their smoothness for a contour plot. contour displays current settings of cntrparam as well as contour.


      set cntrparam { { linear
                      | cubicspline
                      | bspline
                      | points <n>
                      | order <n>
                      | levels { <n> 
                                 | auto {<n>}
                                 | discrete <z1> {,<z2>{,<z3>...}}
                                 | incremental <start>, <incr> {,<end>}
                        {firstlinetype N}
      show contour

This command has two functions. First, it sets the values of z for which contours are to be determined. The number of contour levels <n> should be an integral constant expression. <z1>, <z2> ... are real-valued expressions. Second, it controls the appearance of the individual contour lines.

Keywords controlling the smoothness of contour lines:

‘linear‘, ‘cubicspline‘, ‘bspline‘— Controls type of approximation or interpolation. If ‘linear‘, then straight line segments connect points of equal z magnitude. If ‘cubicspline‘, then piecewise-linear contours are interpolated between the same equal z points to form somewhat smoother contours, but which may undulate. If ‘bspline‘, a guaranteed-smoother curve is drawn, which only approximates the position of the points of equal-z.

‘points‘— Eventually all drawings are done with piecewise-linear strokes. This number controls the number of line segments used to approximate the ‘bspline‘ or ‘cubicspline‘ curve. Number of cubicspline or bspline segments (strokes) = ‘points‘ * number of linear segments.

‘order‘— Order of the bspline approximation to be used. The bigger this order is, the smoother the resulting contour. (Of course, higher order bspline curves will move further away from the original piecewise linear data.) This option is relevant for ‘bspline‘ mode only. Allowed values are integers in the range from 2 (linear) to 10.

Keywords controlling the selection of contour levels:

‘levels auto‘— This is the default. <n> specifies a nominal number of levels; the actual number will be adjusted to give simple labels. If the surface is bounded by zmin and zmax, contours will be generated at integer multiples of dz between zmin and zmax, where dz is 1, 2, or 5 times some power of ten (like the step between two tic marks).

‘levels discrete‘— Contours will be generated at z = <z1>, <z2> ... as specified; the number of discrete levels sets the number of contour levels. In ‘discrete‘ mode, any ‘set cntrparam levels <n>‘ are ignored.

‘levels incremental‘— Contours are generated at values of z beginning at <start> and increasing by <increment>, until the number of contours is reached. <end> is used to determine the number of contour levels, which will be changed by any subsequent ‘set cntrparam levels <n>‘. If the z axis is logarithmic, <increment> will be interpreted as a multiplicative factor, as it is for ztics, and <end> should not be used.

Keywords controlling the assignment of linetype to contours:

By default the contours are generated in the reverse order specified (‘unsorted‘). Thus ‘set cntrparam levels increment 0, 10, 100‘ will create 11 contours levels starting with 100 and ending with 0. Adding the keyword ‘sorted‘ re-orders the contours by increasing numerical value, which in this case would mean the first contour is drawn at 0.

By default contours are drawn using successive linetypes starting with the next linetype after that used for the corresponding surface. Thus ‘splot x*y lt 5‘ would use lt 6 for the first contour generated. If hidden3d mode is active then each surface uses two linetypes. In this case using default settings would cause the first contour to use the same linetype as the hidden surface, which is undesirable. This can be avoided in either of two ways. (1) Use ‘set hidden3d offset N‘ to change the linetype used for the hidden surface. A good choice would be ‘offset -1‘ since that will avoid all the contour linetypes. (2) Use the ‘set cntrparam firstlinetype N‘ option to specify a block of linetypes used for contour lines independent of whatever was used for the surface. This is particularly useful if you want to customize the set of contour linetypes. N <= 0 restores the default.

If the command cntrparam is given without any arguments specified all options are reset to the default:

      set cntrparam order 4 points 5
      set cntrparam levels auto 5 unsorted
      set cntrparam firstlinetype 0 Examples


      set cntrparam bspline
      set cntrparam points 7
      set cntrparam order 10

To select levels automatically, 5 if the level increment criteria are met:

      set cntrparam levels auto 5

To specify discrete levels at .1, .37, and .9:

      set cntrparam levels discrete .1,1/exp(1),.9

To specify levels from 0 to 4 with increment 1:

      set cntrparam levels incremental  0,1,4

To set the number of levels to 10 (changing an incremental end or possibly the number of auto levels):

      set cntrparam levels 10

To set the start and increment while retaining the number of levels:

      set cntrparam levels incremental 100,50

To define and use a customized block of contour linetypes

      set linetype 100 lc "red" dt '....'
      do for [L=101:199] {
          if (L%10 == 0) {
              set linetype L lc "black" dt solid lw 2
          } else {
              set linetype L lc "gray" dt solid lw 1
      set cntrparam firstlinetype 100
      set cntrparam sorted levels incremental 0, 1, 100

See also contour for control of where the contours are drawn, and cntrlabel for control of the format of the contour labels and linetypes.

See also contours demo (contours.dem) and contours with user defined levels demo (discrete.dem).

3.29.15 color box

The color scheme, i.e. the gradient of the smooth color with min_z and max_z values of pm3d’s palette, is drawn in a color box unless ‘unset colorbox‘.

      set colorbox
      set colorbox {
                 { vertical | horizontal } {{no}invert}
                 { default | user }
                 { origin x, y }
                 { size x, y }
                 { front | back }
                 { noborder | bdefault | border [line style] }
      show colorbox
      unset colorbox

Color box position can be ‘default‘ or ‘user‘. If the latter is specified the values as given with the origin and size subcommands are used. The box can be drawn after (‘front‘) or before (‘back‘) the graph or the surface.

The orientation of the color gradient can be switched by options ‘vertical‘ and ‘horizontal‘.

‘origin x, y‘ and ‘size x, y‘ are used only in combination with the ‘user‘ option. The x and y values are interpreted as screen coordinates by default, and this is the only legal option for 3D plots. 2D plots, including splot with ‘set view map‘, allow any coordinate system to be specified. Try for example:

    set colorbox horiz user origin .1,.02 size .8,.04

which will draw a horizontal gradient somewhere at the bottom of the graph.

border turns the border on (this is the default). ‘noborder‘ turns the border off. If an positive integer argument is given after border, it is used as a line style tag which is used for drawing the border, e.g.:

    set style line 2604 linetype -1 linewidth .4
    set colorbox border 2604

will use line style ‘2604‘, a thin line with the default border color (-1) for drawing the border. ‘bdefault‘ (which is the default) will use the default border line style for drawing the border of the color box.

The axis of the color box is called ‘cb‘ and it is controlled by means of the usual axes commands, i.e. ‘set/unset/show‘ with cbrange, ‘[m]cbtics‘, ‘format cb‘, ‘grid [m]cb‘, cblabel, and perhaps even cbdata, ‘[no]cbdtics‘, ‘[no]cbmtics‘.

‘set colorbox‘ without any parameter switches the position to default. ‘unset colorbox‘ resets the default parameters for the colorbox and switches the colorbox off.

See also help for pm3d, palette, pm3d, and ‘set style line‘.

3.29.16 colornames

Gnuplot knows a limited number of color names. You can use these to define the color range spanned by a pm3d palette, or to assign a terminal-independent color to a particular linetype or linestyle. To see the list of known color names, use the command colornames. Example:

      set style line 1 linecolor "sea-green"

3.29.17 contour

contour enables contour drawing for surfaces. This option is available for ‘splot‘ only. It requires grid data, see ‘grid_data‘ for more details. If contours are desired from non-grid data, dgrid3d can be used to create an appropriate grid.


      set contour {base | surface | both}
      unset contour
      show contour

The three options specify where to draw the contours: ‘base‘ draws the contours on the grid base where the x/ytics are placed, surface draws the contours on the surfaces themselves, and ‘both‘ draws the contours on both the base and the surface. If no option is provided, the default is ‘base‘.

See also cntrparam for the parameters that affect the drawing of contours, and cntrlabel for control of labeling of the contours.

The surface can be switched off (see surface), giving a contour-only graph. Though it is possible to use size to enlarge the plot to fill the screen, more control over the output format can be obtained by writing the contour information to a datablock, and rereading it as a 2D datafile plot:

      unset surface
      set contour
      set cntrparam ...
      set table $datablock
      splot ...
      unset table
      # contour info now in $datablock
      set term <whatever>
      plot $datablock

In order to draw contours, the data should be organized as "grid data". In such a file all the points for a single y-isoline are listed, then all the points for the next y-isoline, and so on. A single blank line (a line containing no characters other than blank spaces and a carriage return and/or a line feed) separates one y-isoline from the next.

While contour is in effect, ‘splot with <style>‘ will place the style elements (points, lines, impulses, labels, etc) along the contour lines. pm3d will produce a pm3d surface and also contour lines. If you want to mix other plot elements, say labels read from a file, with the contours generated while contour is active you must append the keyword ‘nocontours‘ after that clause in the splot command.

See also datafile.

See also contours demo (contours.dem) and contours with user defined levels demo (discrete.dem).

3.29.18 dashtype

The dashtype command allows you to define a dash pattern that can then be referred to by its index. This is purely a convenience, as anywhere that would accept the dashtype by its numerical index would also accept an explicit dash pattern. Example:

     set dashtype 5 (2,4,2,6)   # define or redefine dashtype number 5
     plot f1(x) dt 5            # plot using the new dashtype
     plot f1(x) dt (2,4,2,6)    # exactly the same plot as above
     set linetype 5 dt 5        # always use this dash pattern with linetype 5
     set dashtype 66 "..-"      # define a new dashtype using a string

See also dashtype.

3.29.19 data style

This form of the command is deprecated. Please see ‘set style data‘.

3.29.20 datafile

The datafile command options control interpretation of fields read from input data files by the ‘plot‘, ‘splot‘, and fit commands. Several options are currently implemented. set datafile columnheaders

The columnheaders command guarantees that the first row of input will be interpreted as column headers rather than as data values. It affects all input data sources to plot, splot, fit, and stats commands. If this setting is disabled by columnheaders, the same effect is triggered on a per-file basis if there is an explicit columnheader() function in a using specifier or plot title associated with that file. See also ‘set key autotitle‘ and ‘columnheader‘. set datafile fortran

The ‘set datafile fortran‘ command enables a special check for values in the input file expressed as Fortran D or Q constants. This extra check slows down the input process, and should only be selected if you do in fact have datafiles containing Fortran D or Q constants. The option can be disabled again using ‘unset datafile fortran‘. set datafile nofpe_trap

The ‘set datafile nofpe_trap‘ command tells gnuplot not to re-initialize a floating point exception handler before every expression evaluation used while reading data from an input file. This can significantly speed data input from very large files at the risk of program termination if a floating-point exception is generated. set datafile missing


      set datafile missing "<string>"
      set datafile missing NaN
      show datafile missing
      unset datafile

The ‘set datafile missing‘ command tells ‘gnuplot‘ there is a special string used in input data files to denote a missing data entry. There is no default character for ‘missing‘. Gnuplot makes a distinction between missing data and invalid data (e.g. "NaN", 1/0.). For example invalid data causes a gap in a line drawn through sequential data points; missing data does not.

Non-numeric characters found in a numeric field will usually be interpreted as invalid rather than as a missing data point unless they happen to match the ‘missing‘ string.

Conversely NaN causes all data or expressions evaluating to not-a-number (NaN) to be treated as missing data.

The example below shows differences between gnuplot version 4 and version 5. Example:

      set style data linespoints
      plot '-' title "(a)"
         1 10
         2 20
         3 ?
         4 40
         5 50
      set datafile missing "?"
      plot '-' title "(b)"
         1 10
         2 20
         3 ?
         4 40
         5 50
      plot '-' using 1:2 title "(c)"
         1 10
         2 20
         3 NaN
         4 40
         5 50
      plot '-' using 1:($2) title "(d)"
         1 10
         2 20
         3 NaN
         4 40
         5 50

Plot (a) differs in gnuplot 4 and gnuplot 5 because the third line contains only one valid number. Version 4 switched to a single-datum-on-a-line convention that the line number is "x" and the datum is "y", erroneously placing the point at(2,3).

Both the old and new gnuplot versions handle the same data correctly if the ’?’ character is designated as a marker for missing data (b).

Old gnuplot versions handled NaN differently depending of the form of the ‘using‘ clause, as shown in plots (c) and (d). Gnuplot now handles NaN the same whether the input column was specified as N or ($N). See also the imageNaN demo. Similarly gnuplot 5.4 will notice the missing value flag in column N whether the plot command specifies ‘using N‘ or ‘using ($N)‘ or ‘using (func($N))‘. However if the "missing" value is encountered during evaluation of some more complicated expression, e.g. ‘using (column(strcol(1))‘, it may evaluate to NaN and be treated as invalid data rather than as a missing data point. If you nevertheless want to treat this as missing data, use the command NaN. set datafile separator

The command ‘set datafile separator‘ tells ‘gnuplot‘ that data fields in subsequent input files are separated by a specific character rather than by whitespace. The most common use is to read in csv (comma-separated value) files written by spreadsheet or database programs. By default data fields are separated by whitespace.


      set datafile separator {whitespace | tab | comma | "<chars>"}


      # Input file contains tab-separated fields
      set datafile separator "\t"

      # Input file contains comma-separated values fields
      set datafile separator comma

      # Input file contains fields separated by either * or |
      set datafile separator "*|" set datafile commentschars

The command ‘set datafile commentschars‘ specifies what characters can be used in a data file to begin comment lines. If the first non-blank character on a line is one of these characters then the rest of the data line is ignored. Default value of the string is "#!" on VMS and "#" otherwise.


      set datafile commentschars {"<string>"}
      show datafile commentschars
      unset commentschars

Then, the following line in a data file is completely ignored

    # 1 2 3 4

but the following

    1 # 3 4

will be interpreted as garbage in the 2nd column followed by valid data in the 3rd and 4th columns.


      set datafile commentschars "#!%" set datafile binary

The binary command is used to set the defaults when reading binary data files. The syntax matches precisely that used for commands ‘plot‘ and ‘splot‘. See matrix and general for details about the keywords that can be present in <binary list>.


      set datafile binary <binary list>
      show datafile binary
      show datafile
      unset datafile


      set datafile binary filetype=auto
      set datafile binary array=(512,512) format="%uchar"

      show datafile binary   # list current settings

3.29.21 decimalsign

The decimalsign command selects a decimal sign for numbers printed into tic labels or ‘set label‘ strings.


      set decimalsign {<value> | locale {"<locale>"}}
      unset decimalsign
      show decimalsign

The argument <value> is a string to be used in place of the usual decimal point. Typical choices include the period, ’.’, and the comma, ’,’, but others may be useful, too. If you omit the <value> argument, the decimal separator is not modified from the usual default, which is a period. Unsetting decimalsign has the same effect as omitting <value>.


Correct typesetting in most European countries requires:

      set decimalsign ','

Please note: If you set an explicit string, this affects only numbers that are printed using gnuplot’s gprintf() formatting routine, including axis tics. It does not affect the format expected for input data, and it does not affect numbers printed with the sprintf() formatting routine. To change the behavior of both input and output formatting, instead use the form

      set decimalsign locale

This instructs the program to use both input and output formats in accordance with the current setting of the LC_ALL, LC_NUMERIC, or LANG environmental variables.

      set decimalsign locale "foo"

This instructs the program to format all input and output in accordance with locale "foo", which must be installed. If locale "foo" is not found then an error message is printed and the decimal sign setting is unchanged. On linux systems you can get a list of the locales installed on your machine by typing "locale -a". A typical linux locale string is of the form "sl_SI.UTF-8". A typical Windows locale string is of the form "Slovenian_Slovenia.1250" or "slovenian". Please note that interpretation of the locale settings is done by the C library at runtime. Older C libraries may offer only partial support for locale settings such as the thousands grouping separator character.

      set decimalsign locale; set decimalsign "."

This sets all input and output to use whatever decimal sign is correct for the current locale, but over-rides this with an explicit ’.’ in numbers formatted using gnuplot’s internal gprintf() function.

3.29.22 dgrid3d

The dgrid3d command enables and sets parameters for mapping non-grid data onto a grid. See ‘splot grid_data‘ for details about the grid data structure. Aside from its use in fitting 3D surfaces, this process can also be used to generate 2D heatmaps, where the ’z’ value of each point contributes to a local weighted value.


      set dgrid3d {<rows>} {,{<cols>}}
                  { splines |
                    qnorm {<norm>} |
                    (gauss | cauchy | exp | box | hann)
                      {kdensity} {<dx>} {,<dy>} }
      unset dgrid3d
      show dgrid3d

By default dgrid3d is disabled. When enabled, 3D data points read from a file are treated as a scattered data set used to fit a gridded surface. The grid dimensions are derived from the bounding box of the scattered data subdivided by the row/col_size parameters from the dgrid3d statement. The grid is equally spaced in x (rows) and in y (columns); the z values are computed as weighted averages or spline interpolations of the scattered points’ z values. In other words, a regularly spaced grid is created and then a smooth approximation to the raw data is evaluated for each grid point. This surface is then plotted in place of the raw data.

While dgrid3d mode is enabled, if you want to plot individual points or lines without using them to create a gridded surface you must append the keyword ‘nogrid‘ to the corresponding splot command.

The number of columns defaults to the number of rows, which defaults to 10.

Several algorithms are available to calculate the approximation from the raw data. Some of these algorithms can take additional parameters. These interpolations are such that the closer the data point is to a grid point, the more effect it has on that grid point.

The ‘splines‘ algorithm calculates an interpolation based on thin plate splines. It does not take additional parameters.

The ‘qnorm‘ algorithm calculates a weighted average of the input data at each grid point. Each data point is weighted by the inverse of its distance from the grid point raised to some power. The power is specified as an optional integer parameter that defaults to 1. This algorithm is the default.

Finally, several smoothing kernels are available to calculate weighted averages: z = Sum_i w(d_i) * z_i / Sum_i w(d_i), where z_i is the value of the i-th data point and d_i is the distance between the current grid point and the location of the i-th data point. All kernels assign higher weights to data points that are close to the current grid point and lower weights to data points further away.

The following kernels are available:

      gauss :     w(d) = exp(-d*d)
      cauchy :    w(d) = 1/(1 + d*d)
      exp :       w(d) = exp(-d)
      box :       w(d) = 1                     if d<1
                       = 0                     otherwise
      hann :      w(d) = 0.5*(1+cos(pi*d))     if d<1
                  w(d) = 0                     otherwise

When using one of these five smoothing kernels, up to two additional numerical parameters can be specified: dx and dy. These are used to rescale the coordinate differences when calculating the distance: d_i = sqrt( ((x-x_i)/dx)**2 + ((y-y_i)/dy)**2 ), where x,y are the coordinates of the current grid point and x_i,y_i are the coordinates of the i-th data point. The value of dy defaults to the value of dx, which defaults to 1. The parameters dx and dy make it possible to control the radius over which data points contribute to a grid point IN THE UNITS OF THE DATA ITSELF.

The optional keyword ‘kdensity‘, which must come after the name of the kernel, but before the (optional) scale parameters, modifies the algorithm so that the values calculated for the grid points are not divided by the sum of the weights ( z = Sum_i w(d_i) * z_i ). If all z_i are constant, this effectively plots a bivariate kernel density estimate: a kernel function (one of the five defined above) is placed at each data point, the sum of these kernels is evaluated at every grid point, and this smooth surface is plotted instead of the original data. This is similar in principle to what the ‘smooth kdensity‘ option does to 1D datasets. (See kdensity2d.dem for usage demo)

DEPRECATED: A slightly different syntax is also supported for backwards compatibility. If no interpolation algorithm has been explicitly selected, the ‘qnorm‘ algorithm is assumed. Up to three comma-separated, optional parameters can be specified, which are interpreted as the the number of rows, the number of columns, and the norm value, respectively.

The dgrid3d option is a simple scheme which replaces scattered data with weighted averages on a regular grid. More sophisticated approaches to this problem exist and should be used to preprocess the data outside ‘gnuplot‘ if this simple solution is found inadequate.

See also the online dgrid3d demo and scatter demo

3.29.23 dummy

The dummy command changes the default dummy variable names.


      set dummy {<dummy-var>} {,<dummy-var>}
      show dummy

By default, ‘gnuplot‘ assumes that the independent, or "dummy", variable for the ‘plot‘ command is "t" if in parametric or polar mode, or "x" otherwise. Similarly the independent variables for the ‘splot‘ command are "u" and "v" in parametric mode (‘splot‘ cannot be used in polar mode), or "x" and "y" otherwise.

It may be more convenient to call a dummy variable by a more physically meaningful or conventional name. For example, when plotting time functions:

      set dummy t
      plot sin(t), cos(t)


      set dummy u,v
      set dummy ,s

The second example sets the second variable to s. To reset the dummy variable names to their default values, use

      unset dummy

3.29.24 encoding

The encoding command selects a character encoding.


      set encoding {<value>}
      set encoding locale
      show encoding

Valid values are

   default     - tells a terminal to use its default encoding
   iso_8859_1  - the most common Western European encoding prior to UTF-8.
                 Known in the PostScript world as 'ISO-Latin1'.
   iso_8859_15 - a variant of iso_8859_1 that includes the Euro symbol
   iso_8859_2  - used in Central and Eastern Europe
   iso_8859_9  - used in Turkey (also known as Latin5)
   koi8r       - popular Unix cyrillic encoding
   koi8u       - Ukrainian Unix cyrillic encoding
   cp437       - codepage for MS-DOS
   cp850       - codepage for OS/2, Western Europe
   cp852       - codepage for OS/2, Central and Eastern Europe
   cp950       - MS version of Big5 (emf terminal only)
   cp1250      - codepage for MS Windows, Central and Eastern Europe
   cp1251      - codepage for 8-bit Russian, Serbian, Bulgarian, Macedonian
   cp1252      - codepage for MS Windows, Western Europe
   cp1254      - codepage for MS Windows, Turkish (superset of Latin5)
   sjis        - shift-JIS Japanese encoding
   utf8        - variable-length (multibyte) representation of Unicode
                 entry point for each character

The command locale is different from the other options. It attempts to determine the current locale from the runtime environment. On most systems this is controlled by the environmental variables LC_ALL, LC_CTYPE, or LANG. This mechanism is necessary, for example, to pass multibyte character encodings such as UTF-8 or EUC_JP to the wxt and pdf terminals. This command does not affect the locale-specific representation of dates or numbers. See also locale and decimalsign.

Generally you must set the encoding before setting the terminal type, as it may affect the choice of appropriate fonts.

3.29.25 errorbars

The errorbars command controls the tics at the ends of error bars, and also at the end of the whiskers belonging to a boxplot.


      set errorbars {small | large | fullwidth | <size>} {front | back}
      unset errorbars
      show errorbars

‘small‘ is a synonym for 0.0 (no crossbar), and ‘large‘ for 1.0. The default is 1.0 if no size is given.

The keyword ‘fullwidth‘ is relevant only to boxplots and to histograms with errorbars. It sets the width of the errorbar ends to be the same as the width of the associated box. It does not change the width of the box itself.

The ‘front‘ and ‘back‘ keywords are relevant only to errorbars attached to filled rectangles (boxes, candlesticks, histograms).

Error bars are by default drawn using the same line properties as the border of the associated box. You can change this by providing a separate set of line properties for the error bars.

     set errorbars linecolor black linewidth 0.5 dashtype '.'

3.29.26 fit

The fit command controls the options for the fit command.


      set fit {nolog | logfile {"<filename>"|default}}
              {maxiter <value>|default}
              {limit <epsilon>|default}
              {limit_abs <epsilon_abs>}
              {start-lambda <value>|default}
              {lambda-factor <value>|default}
              {script {"<command>"|default}}
              {v4 | v5}
      unset fit
      show fit

The ‘logfile‘ option defines where the fit command writes its output. The <filename> argument must be enclosed in single or double quotes. If no filename is given or fit is used the log file is reset to its default value "fit.log" or the value of the environmental variable ‘FIT_LOG‘. If the given logfile name ends with a / or \, it is interpreted to be a directory name, and the actual filename will be "fit.log" in that directory.

By default the information written to the log file is also echoed to the terminal session. ‘set fit quiet‘ turns off the echo, whereas ‘results‘ prints only final results. ‘brief‘ gives one line summaries for every iteration of the fit in addition. ‘verbose‘ yields detailed iteration reports as in version 4.

If the ‘errorvariables‘ option is turned on, the error of each fitted parameter computed by fit will be copied to a user-defined variable whose name is formed by appending "_err" to the name of the parameter itself. This is useful mainly to put the parameter and its error onto a plot of the data and the fitted function, for reference, as in:

       set fit errorvariables
       fit f(x) 'datafile' using 1:2 via a, b
       print "error of a is:", a_err
       set label 1 sprintf("a=%6.2f +/- %6.2f", a, a_err)
       plot 'datafile' using 1:2, f(x)

If the ‘errorscaling‘ option is specified, which is the default, the calculated parameter errors are scaled with the reduced chi square. This is equivalent to providing data errors equal to the calculated standard deviation of the fit (FIT_STDFIT) resulting in a reduced chi square of one. With the ‘noerrorscaling‘ option the estimated errors are the unscaled standard deviations of the fit parameters. If no weights are specified for the data, parameter errors are always scaled.

If the ‘prescale‘ option is turned on, parameters are prescaled by their initial values before being passed to the Marquardt-Levenberg routine. This helps tremendously if there are parameters that differ in size by many orders of magnitude. Fit parameters with an initial value of exactly zero are never prescaled.

The maximum number of iterations may be limited with the ‘maxiter‘ option. A value of 0 or ‘default‘ means that there is no limit.

The ‘limit‘ option can be used to change the default epsilon limit (1e-5) to detect convergence. When the sum of squared residuals changes by a factor less than this number (epsilon), the fit is considered to have ’converged’. The ‘limit_abs‘ option imposes an additional absolute limit in the change of the sum of squared residuals and defaults to zero.

If you need even more control about the algorithm, and know the Marquardt-Levenberg algorithm well, the following options can be used to influence it. The startup value of ‘lambda‘ is normally calculated automatically from the ML-matrix, but if you want to, you may provide your own using the ‘start_lambda‘ option. Setting it to ‘default‘ will re-enable the automatic selection. The option ‘lambda_factor‘ sets the factor by which ‘lambda‘ is increased or decreased whenever the chi-squared target function increased or decreased significantly. Setting it to ‘default‘ re-enables the default factor of 10.0.

The ‘script‘ option may be used to specify a ‘gnuplot‘ command to be executed when a fit is interrupted—see fit. This setting takes precedence over the default of replot and the environment variable ‘FIT_SCRIPT‘.

If the ‘covariancevariables‘ option is turned on, the covariances between final parameters will be saved to user-defined variables. The variable name for a certain parameter combination is formed by prepending "FIT_COV_" to the name of the first parameter and combining the two parameter names by "_". For example given the parameters "a" and "b" the covariance variable is named "FIT_COV_a_b".

In version 5 the syntax of the fit command changed and it now defaults to unitweights if no ’error’ keyword is given. The ‘v4‘ option restores the default behavior of gnuplot version 4, see also fit.

3.29.27 fontpath


      set fontpath "/directory/where/my/fonts/live"
      set term postscript fontfile <filename>

[DEPRECATED in version 5.4]

The fontpath directory is relevant only for embedding fonts in postscript output produced by the postscript terminal. It has no effect on other gnuplot terminals. If you are not embedding fonts you do not need this command, and even if you are embedding fonts you only need it for fonts that cannot be found via the other paths below.

Earlier versions of gnuplot tried to emulate a font manager by tracking multiple directory trees containing fonts. This is now replaced by a search in the following places: (1) an absolute path given in the ‘set term postscript fontfile‘ command (2) the current directory (3) any of the directories specified by loadpath (4) the directory specified by fontpath (5) the directory provided in environmental variable GNUPLOT_FONTPATH

Note: The search path for fonts specified by filename for the libgd terminals (png gif jpeg sixel) is controlled by environmental variable GDFONTPATH.

3.29.28 format

The format of the tic-mark labels can be set with the ‘set format‘ command or with the ‘set tics format‘ or individual ‘set {axis}tics format‘ commands.


      set format {<axes>} {"<format-string>"} {numeric|timedate|geographic}
      show format

where <axes> is either ‘x‘, ‘y‘, ‘xy‘, ‘x2‘, ‘y2‘, ‘z‘, ‘cb‘ or nothing (which applies the format to all axes). The following two commands are equivalent:

      set format y "%.2f"
      set ytics format "%.2f"

The length of the string is restricted to 100 characters. The default format is "% h", "$%h$" for LaTeX terminals. Other formats such as "%.2f" or "%3.0em" are often desirable. "set format" with no following string will restore the default.

If the empty string "" is given, tics will have no labels, although the tic mark will still be plotted. To eliminate the tic marks, use ‘unset xtics‘ or ‘set tics scale 0‘.

Newline (\n) and enhanced text markup is accepted in the format string. Use double-quotes rather than single-quotes in this case. See also ‘syntax‘. Characters not preceded by "%" are printed verbatim. Thus you can include spaces and labels in your format string, such as "%g m", which will put " m" after each number. If you want "%" itself, double it: "%g %%".

See also ‘set xtics‘ for more information about tic labels, and decimalsign for how to use non-default decimal separators in numbers printed this way. See also electron demo (electron.dem). gprintf

The string function gprintf("format",x) uses gnuplot’s own format specifiers, as do the gnuplot commands ‘set format‘, timestamp, and others. These format specifiers are not the same as those used by the standard C-language routine sprintf(). gprintf() accepts only a single variable to be formatted. Gnuplot also provides an sprintf("format",x1,x2,...) routine if you prefer. For a list of gnuplot’s format options, see ‘format specifiers‘. format specifiers

The acceptable formats (if not in time/date mode) are:

      Format       Explanation
      %f           floating point notation
      %e or %E     exponential notation; an "e" or "E" before the power
      %g or %G     the shorter of %e (or %E) and %f
      %h or %H     like %g with "x10^{%S}" or "*10^{%S}" instead of "e%S"
      %x or %X     hex
      %o or %O     octal
      %t           mantissa to base 10
      %l           mantissa to base of current logscale
      %s           mantissa to base of current logscale; scientific power
      %T           power to base 10
      %L           power to base of current logscale
      %S           scientific power
      %c           character replacement for scientific power
      %b           mantissa of ISO/IEC 80000 notation (ki, Mi, Gi, Ti, Pi, Ei, Zi, Yi)
      %B           prefix of ISO/IEC 80000 notation (ki, Mi, Gi, Ti, Pi, Ei, Zi, Yi)
      %P           multiple of pi

A ’scientific’ power is one such that the exponent is a multiple of three. Character replacement of scientific powers (‘"%c"‘) has been implemented for powers in the range -18 to +18. For numbers outside of this range the format reverts to exponential.

Other acceptable modifiers (which come after the "%" but before the format specifier) are "-", which left-justifies the number; "+", which forces all numbers to be explicitly signed; " " (a space), which makes positive numbers have a space in front of them where negative numbers have "-"; "#", which places a decimal point after floats that have only zeroes following the decimal point; a positive integer, which defines the field width; "0" (the digit, not the letter) immediately preceding the field width, which indicates that leading zeroes are to be used instead of leading blanks; and a decimal point followed by a non-negative integer, which defines the precision (the minimum number of digits of an integer, or the number of digits following the decimal point of a float).

Some systems may not support all of these modifiers but may also support others; in case of doubt, check the appropriate documentation and then experiment.


      set format y "%t"; set ytics (5,10)          # "5.0" and "1.0"
      set format y "%s"; set ytics (500,1000)      # "500" and "1.0"
      set format y "%+-12.3f"; set ytics(12345)    # "+12345.000  "
      set format y "%.2t*10^%+03T"; set ytic(12345)# "1.23*10^+04"
      set format y "%s*10^{%S}"; set ytic(12345)   # "12.345*10^{3}"
      set format y "%s %cg"; set ytic(12345)       # "12.345 kg"
      set format y "%.0P pi"; set ytic(6.283185)   # "2 pi"
      set format y "%.0f%%"; set ytic(50)          # "50%"

      set log y 2; set format y '%l'; set ytics (1,2,3)
      #displays "1.0", "1.0" and "1.5" (since 3 is 1.5 * 2^1)

There are some problem cases that arise when numbers like 9.999 are printed with a format that requires both rounding and a power.

If the data type for the axis is time/date, the format string must contain valid codes for the ’strftime’ function (outside of ‘gnuplot‘, type "man strftime"). See timefmt for a list of the allowed input format codes. time/date specifiers

There are two groups of time format specifiers: time/date and relative time. These may be used to generate axis tic labels or to encode time in a string. See ‘set xtics time‘, strftime, strptime.

The time/date formats are

      Format       Explanation
      %a           short name of day of the week (ignored on input)
      %A           full name of day of the week (ignored on input)
      %b or %h     abbreviated name of the month
      %B           full name of the month
      %d           day of the month, 01--31
      %D           shorthand for "%m/%d/%y" (only output)
      %F           shorthand for "%Y-%m-%d" (only output)
      %k           hour, 0--23 (one or two digits)
      %H           hour, 00--23 (always two digits)
      %l           hour, 1--12 (one or two digits)
      %I           hour, 01--12 (always two digits)
      %j           day of the year, 001--366
      %m           month, 01--12
      %M           minute, 00--60
      %p           "am" or "pm"
      %r           shorthand for "%I:%M:%S %p" (only output)
      %R           shorthand for "%H:%M" (only output)
      %s           number of seconds since the start of year 1970
      %S           second, integer 00--60 on output, (double) on input
      %T           shorthand for "%H:%M:%S" (only output)
      %U           week of the year (CDC/MMWR "epi week") (ignored on input)
      %w           day of the week, 0--6 (Sunday = 0) (ignored on input)
      %W           week of the year (ISO 8601 week date) (ignored on input)
      %y           year, 0-68 for 2000-2068, 69-99 for 1969-1999
      %Y           year, 4-digit
      %z           timezone, [+-]hh:mm
      %Z           timezone name, ignored string

For more information on the %W format (ISO week of year) see tm_week. The %U format (CDC/MMWR epidemiological week) is similar to %W except that it uses weeks that start on Sunday rather than Monday. Caveat: Both the %W and the %U formats were unreliable in gnuplot versions prior to 5.4.2. See unit test "week_date.dem".

The relative time formats express the length of a time interval on either side of a zero time point. The relative time formats are

      Format       Explanation
      %tD          +/- days relative to time=0
      %tH          +/- hours relative to time=0 (does not wrap at 24)
      %tM          +/- minutes relative to time=0
      %tS          +/- seconds associated with previous tH or tM field

Numerical formats may be preceded by a "0" ("zero") to pad the field with leading zeroes, and preceded by a positive digit to define the minimum field width. The %S, and %t formats also accept a precision specifier so that fractional hours/minutes/seconds can be written.


Examples of date format:

Suppose the x value in seconds corresponds a time slightly before midnight on 25 Dec 1976. The text printed for a tic label at this position would be

      set format x                 # defaults to "12/25/76 \n 23:11"
      set format x "%A, %d %b %Y"  # "Saturday, 25 Dec 1976"
      set format x "%r %D"         # "11:11:11 pm 12/25/76"

Examples of time format:

The date format specifiers encode a time in seconds as a clock time on a particular day. So hours run only from 0-23, minutes from 0-59, and negative values correspond to dates prior to the epoch (1-Jan-1970). In order to report a time value in seconds as some number of hours/minutes/seconds relative to a time 0, use time formats %tH %tM %tS. To report a value of -3672.50 seconds

      set format x                 # default date format "12/31/69 \n 22:58"
      set format x "%tH:%tM:%tS"   # "-01:01:12"
      set format x "%.2tH hours"   # "-1.02 hours"
      set format x "%tM:%.2tS"     # "-61:12.50" tm_week

The ‘tm_week(t, standard)‘ function interprets its first argument t as a time in seconds from 1 Jan 1970. Despite the name of this function it does not report a field from the POSIX tm structure.

If standard = 0 it returns the week number in the ISO 8601 "week date" system. This corresponds to gnuplot’s %W time format. If standard = 1 it returns the CDC epidemiological week number ("epi week"). This corresponds to gnuplot’s %U time format. For corresponding inverse functions that convert week dates to calendar time see weekdate_iso, weekdate_cdc.

In brief, ISO Week 1 of year YYYY begins on the Monday closest to 1 Jan YYYY. This may place it in the previous calendar year. For example Tue 30 Dec 2008 has ISO week date 2009-W01-2 (2nd day of week 1 of 2009). Up to three days at the start of January may come before the Monday of ISO week 1; these days are assigned to the final week of the previous calendar year. E.g. Fri 1 Jan 2021 has ISO week date 2020-W53-5.

The US Center for Disease Control (CDC) epidemiological week is a similar week date convention that differs from the ISO standard by defining a week as starting on Sunday, rather than on Monday. weekdate_iso


     time = weekdate_iso( year, week [, day] )

This function converts from the year, week, day components of a date in ISO 8601 "week date" format to the calendar date as a time in seconds since the epoch date 1 Jan 1970. Note that the nominal year in the week date system is not necessarily the same as the calendar year. The week is an integer from 1 to 53. The day parameter is optional. If it is omitted or equal to 0 the time returned is the start of the week. Otherwise day is an integer from 1 (Monday) to 7 (Sunday). See tm_week for additional information on an inverse function that converts from calendar date to week number in the ISO standard convention.


     # Plot data from a file with column 1 containing ISO weeks
     #     Week     cases  deaths
     #     2020-05    432       1
     calendar_date(w) = weekdate_iso( int(w[1:4]), int(w[6:7]) )
     set xtics time format "%b\n%Y"
     plot FILE using (calendar_date(strcol(1))) : 2   title columnhead weekdate_cdc


     time = weekdate_cdc( year, week [, day] )

This function converts from the year, week, day components of a date in the CDC/MMWR "epi week" format to the calendar date as a time in seconds since the epoch date 1 Jan 1970. The CDC week date convention differs from the ISO week date in that it is defined in terms of each week running from day 1 = Sunday to day 7 = Saturday. If the third parameter is 0 or is omitted, the time returned is the start of the week. See tm_week and weekdate_iso.

3.29.29 function style

This form of the command is deprecated. Please use ‘set style function‘.

3.29.30 functions

The functions command lists all user-defined functions and their definitions.


      show functions

For information about the definition and usage of functions in ‘gnuplot‘, please see ‘expressions‘. See also splines as user defined functions (spline.dem) and use of functions and complex variables for airfoils (airfoil.dem).

3.29.31 grid

The ‘set grid‘ command allows grid lines to be drawn on the plot.


      set grid {{no}{m}xtics} {{no}{m}ytics} {{no}{m}ztics}
               {{no}{m}x2tics} {{no}{m}y2tics} {{no}{m}rtics}
               {polar {<angle>}}
               {layerdefault | front | back}
               {<line-properties-major> {, <line-properties-minor>}}
      unset grid
      show grid

The grid can be enabled and disabled for the major and/or minor tic marks on any axis, and the linetype and linewidth can be specified for major and minor grid lines, also via a predefined linestyle, as far as the active terminal driver supports this (see ‘set style line‘).

A polar grid can be drawn for 2D plots. This is the default action of ‘set grid‘ if the program is already in polar mode, but can be enabled explicitly by rtics whether or not the program is in polar mode. Circles are drawn to intersect major and/or minor tics along the r axis, and radial lines are drawn with a spacing of <angle>. Tic marks around the perimeter are controlled by ttics, but these do not produce radial grid lines.

The pertinent tics must be enabled before ‘set grid‘ can draw them; ‘gnuplot‘ will quietly ignore instructions to draw grid lines at non-existent tics, but they will appear if the tics are subsequently enabled.

If no linetype is specified for the minor gridlines, the same linetype as the major gridlines is used. The default polar angle is 30 degrees.

If ‘front‘ is given, the grid is drawn on top of the graphed data. If ‘back‘ is given, the grid is drawn underneath the graphed data. Using ‘front‘ will prevent the grid from being obscured by dense data. The default setup, ‘layerdefault‘, is equivalent to ‘back‘ for 2D plots. In 3D plots the default is to split up the grid and the graph box into two layers: one behind, the other in front of the plotted data and functions. Since hidden3d mode does its own sorting, it ignores all grid drawing order options and passes the grid lines through the hidden line removal machinery instead. These options actually affect not only the grid, but also the lines output by border and the various ticmarks (see ‘set xtics‘).

In 3D plots grid lines at x- and y- axis tic positions are by default drawn only on the base plane parallel to z=0. The ‘vertical‘ keyword activates drawing grid lines in the xz and yz planes also, running from zmin to zmax.

Z grid lines are drawn on the bottom of the plot. This looks better if a partial box is drawn around the plot—see border.

3.29.32 hidden3d

The hidden3d command enables hidden line removal for surface plotting (see ‘splot‘). Some optional features of the underlying algorithm can also be controlled using this command.


      set hidden3d {defaults} |
                   { {front|back}
                     {{offset <offset>} | {nooffset}}
                     {trianglepattern <bitpattern>}
                     {{undefined <level>} | {noundefined}}
                     {{no}bentover} }
      unset hidden3d
      show hidden3d

In contrast to the usual display in gnuplot, hidden line removal actually treats the given function or data grids as real surfaces that can’t be seen through, so plot elements behind the surface will be hidden by it. For this to work, the surface needs to have ’grid structure’ (see datafile about this), and it has to be drawn ‘with lines‘ or linespoints.

When hidden3d is set, both the hidden portion of the surface and possibly its contours drawn on the base (see contour) as well as the grid will be hidden. Each surface has its hidden parts removed with respect to itself and to other surfaces, if more than one surface is plotted. Contours drawn on the surface (surface) don’t work.

hidden3d also affects 3D plotting styles ‘points‘, labels, vectors, and impulses even if no surface is present in the graph. Unobscured portions of each vector are drawn as line segments (no arrowheads). Individual plots within the graph may be explicitly excluded from this processing by appending the extra option ‘nohidden3d‘ to the with specifier.

Hidden3d does not affect solid surfaces drawn using the pm3d mode. To achieve a similar effect purely for pm3d surfaces, use instead ‘set pm3d depthorder‘. To mix pm3d surfaces with normal hidden3d processing, use the option ‘set hidden3d front‘ to force all elements included in hidden3d processing to be drawn after any remaining plot elements, including the pm3d surface.

Functions are evaluated at isoline intersections. The algorithm interpolates linearly between function points or data points when determining the visible line segments. This means that the appearance of a function may be different when plotted with hidden3d than when plotted with ‘nohidden3d‘ because in the latter case functions are evaluated at each sample. Please see samples and isosamples for discussion of the difference.

The algorithm used to remove the hidden parts of the surfaces has some additional features controllable by this command. Specifying ‘defaults‘ will set them all to their default settings, as detailed below. If ‘defaults‘ is not given, only explicitly specified options will be influenced: all others will keep their previous values, so you can turn on/off hidden line removal via ‘set {no}hidden3d‘, without modifying the set of options you chose.

The first option, ‘offset‘, influences the linetype used for lines on the ’back’ side. Normally, they are drawn in a linetype one index number higher than the one used for the front, to make the two sides of the surface distinguishable. You can specify a different linetype offset to add instead of the default 1, by ‘offset <offset>‘. Option ‘nooffset‘ stands for ‘offset 0‘, making the two sides of the surface use the same linetype.

Next comes the option ‘trianglepattern <bitpattern>‘. <bitpattern> must be a number between 0 and 7, interpreted as a bit pattern. Each bit determines the visibility of one edge of the triangles each surface is split up into. Bit 0 is for the ’horizontal’ edges of the grid, Bit 1 for the ’vertical’ ones, and Bit 2 for the diagonals that split each cell of the original grid into two triangles. The default pattern is 3, making all horizontal and vertical lines visible, but not the diagonals. You may want to choose 7 to see those diagonals as well.

The ‘undefined <level>‘ option lets you decide what the algorithm is to do with data points that are undefined (missing data, or undefined function values), or exceed the given x-, y- or z-ranges. Such points can either be plotted nevertheless, or taken out of the input data set. All surface elements touching a point that is taken out will be taken out as well, thus creating a hole in the surface. If <level> = 3, equivalent to option ‘noundefined‘, no points will be thrown away at all. This may produce all kinds of problems elsewhere, so you should avoid this. <level> = 2 will throw away undefined points, but keep the out-of-range ones. <level> = 1, the default, will get rid of out-of-range points as well.

By specifying ‘noaltdiagonal‘, you can override the default handling of a special case can occur if undefined is active (i.e. <level> is not 3). Each cell of the grid-structured input surface will be divided in two triangles along one of its diagonals. Normally, all these diagonals have the same orientation relative to the grid. If exactly one of the four cell corners is excluded by the undefined handler, and this is on the usual diagonal, both triangles will be excluded. However if the default setting of ‘altdiagonal‘ is active, the other diagonal will be chosen for this cell instead, minimizing the size of the hole in the surface.

The ‘bentover‘ option controls what happens to another special case, this time in conjunction with the ‘trianglepattern‘. For rather crumply surfaces, it can happen that the two triangles a surface cell is divided into are seen from opposite sides (i.e. the original quadrangle is ’bent over’), as illustrated in the following ASCII art:

    original quadrangle:  A--B      displayed quadrangle:     |\   |
      ("set view 0,0")    | /|    ("set view 75,75" perhaps)  | \  |
                          |/ |                                |  \ |
                          C--D                                |   \|
                                                              A    D

If the diagonal edges of the surface cells aren’t generally made visible by bit 2 of the <bitpattern> there, the edge CB above wouldn’t be drawn at all, normally, making the resulting display hard to understand. Therefore, the default option of ‘bentover‘ will turn it visible in this case. If you don’t want that, you may choose ‘nobentover‘ instead. See also hidden line removal demo (hidden.dem) and complex hidden line demo (singulr.dem).

3.29.33 historysize

(Deprecated). ‘set historysize N‘ is equivalent to ‘set history size N‘. historysize is equivalent to ‘set history size -1‘.

3.29.34 history


   set history {size <N>} {quiet|numbers} {full|trim} {default}

A log of recent gnuplot commands is kept by default in $HOME/.gnuplot_history. If this file is not found and xdg desktop support is enabled, the program will instead use $XDG_STATE_HOME/gnuplot_history.

When leaving gnuplot the value of history size limits the number of lines saved to the history file. ‘set history size -1‘ allows an unlimited number of lines to be written to the history file.

By default the ‘history‘ command prints a line number in front of each command. ‘history quiet‘ suppresses the number for this command only. ‘set history quiet‘ suppresses numbers for all future ‘history‘ commands.

The trim option reduces the number of duplicate lines in the history list by removing earlier instances of the current command.

Default settings: trim.

3.29.35 isosamples

The isoline density (grid) for plotting functions as surfaces may be changed by the isosamples command.


      set isosamples <iso_1> {,<iso_2>}
      show isosamples

Each function surface plot will have <iso_1> iso-u lines and <iso_2> iso-v lines. If you only specify <iso_1>, <iso_2> will be set to the same value as <iso_1>. By default, sampling is set to 10 isolines per u or v axis. A higher sampling rate will produce more accurate plots, but will take longer. These parameters have no effect on data file plotting.

An isoline is a curve parameterized by one of the surface parameters while the other surface parameter is fixed. Isolines provide a simple means to display a surface. By fixing the u parameter of surface s(u,v), the iso-u lines of the form c(v) = s(u0,v) are produced, and by fixing the v parameter, the iso-v lines of the form c(u) = s(u,v0) are produced.

When a function surface plot is being done without the removal of hidden lines, samples controls the number of points sampled along each isoline; see samples and hidden3d. The contour algorithm assumes that a function sample occurs at each isoline intersection, so change in samples as well as isosamples may be desired when changing the resolution of a function surface/contour.

3.29.36 isosurface


     set isosurface {mixed|triangles}
     set isosurface {no}insidecolor <n>

Surfaces plotted by the command isosurface are by default constructed from a mixture of quadrangles and triangles. The use of quadrangles creates a less complicated visual impression. This is the default. This command proveds an option to tessellate with only triangles.

By default the inside of an isosurface is drawn in a separate color. The method of choosing that color is the same as for hidden3d surfaces, where an offset <n> is added to the base linetype. To draw both the inside and outside surfaces in the same color, use ‘set isosurface noinsidecolor‘.

3.29.37 jitter


      set jitter {overlap <yposition>} {spread <factor>} {wrap <limit>}


      set jitter                    # jitter points within 1 character width
      set jitter overlap 1.5        # jitter points within 1.5 character width
      set jitter over 1.5 spread 0.5  # same but half the displacement on x

When one or both coordinates of a data set are restricted to discrete values then many points may lie exactly on top of each other. Jittering introduces an offset to the coordinates of these superimposed points that spreads them into a cluster. The threshold value for treating the points as being overlapped may be specified in character widths or any of the usual coordinate options. See ‘coordinates‘. Jitter affects 2D plot styles ‘with points‘ and impulses. It also affects 3D plotting of voxel grids.

The default jittering operation displaces points only along x. This produces a distinctive pattern sometimes called a "bee swarm plot". The optional keyword ‘square‘ adjusts the y coordinate of displaced points in addition to their x coordinate so that the points lie in distinct layers separated by at least the ‘overlap‘ distance.

To jitter along y (only) rather than along x, use keyword ‘vertical‘.

The maximum displacement (in character units) can be limited using the ‘wrap‘ keyword.

Note that both the overlap criterion and the magnitude of jitter default to one character unit. Thus the plot appearance will change with the terminal font size, canvas size, or zoom factor. To avoid this you can specify the overlap criterion in the y axis coordinate system (the ‘first‘ keyword) and adjust the point size and spread multiplier as appropriate. See ‘coordinates‘, pointsize.

Caveat: jitter is incompatible with "pointsize variable".

jitter is also useful in 3D plots of voxel data. Because voxel grids are regular lattices of evenly spaced points, many view angles cause points to overlap and/or generate Moiré patterns. These artifacts can be removed by displacing the symbol drawn at each grid point by a random amount.

3.29.38 key

The ‘set key‘ command enables a key (or legend) containing a title and a sample (line, point, box) for each plot in the graph. The key may be turned off by requesting ‘set key off‘ or ‘unset key‘. Individual key entries may be turned off by using the ‘notitle‘ keyword in the corresponding plot command. The text of the titles is controlled by the ‘set key autotitle‘ option or by the title keyword of individual ‘plot‘ and ‘splot‘ commands.

See ‘key placement‘ for syntax of options that affect where the key is placed. See ‘key layout‘ for syntax of options that affect the content of the key.

Syntax (global options):

      set key {on|off} {default}
            {font "<face>,<size>"} {{no}enhanced}
            {{no}title "<text>" {<font or other text options>}}
            {{no}autotitle {columnheader}}
            {{no}box {<line properties>}} {{no}opaque {fc <colorspec>}}
            {width <width_increment>} {height <height_increment>}
      unset key

By default the key is placed in the upper right inside corner of the graph. The optional ‘font‘ becomes the default for all elements of the key. You can provide an option title for the key as a whole that spans the full width of the key at the top. This title can use different font, color, justification, and enhancement from individual plot titles.

Each component in a plot command is represented in the key by a single line containing corresponding title text and a line or symbol or shape representing the plot style. The title text may be auto-generated or given explicitly in the plot command as ‘title "text"‘. The keyword ‘notitle‘ in the plot command will suppress both the text and the style sample. If you want to suppress the text only, use ‘title ""‘ in the plot command.

Contour plots generated additional entries in the key (see cntrlabel). You can add extra lines to the key by inserting a dummy plot command that uses the keyword ‘keyentry‘ rather than a filename or a function. See ‘keyentry‘.

A box can be drawn around the key (‘box {...}‘) with user-specified line properties. The ‘height‘ and ‘width‘ increments (specified in character units) are added to or subtracted from the size of the key box. This is useful mainly when you want larger borders around the key entries.

By default the key is built up one plot at a time. That is, the key symbol and title are drawn at the same time as the corresponding plot. That means newer plots may sometimes place elements on top of the key. ‘set key opaque‘ causes the key to be generated after all the plots. In this case the key area is filled with background color or the requested fill color and then the key symbols and titles are written. The default can be restored by ‘set key noopaque‘.

The text in the key uses ‘enhanced‘ mode by default. This can be suppressed by the ‘noenhanced‘ keyword applied to the entire key, to the key title only, or to individual plot titles.

‘set key default‘ restores the default key configuration.

     set key notitle
     set key nobox noopaque
     set key fixed right top vertical Right noreverse enhanced autotitle
     set key noinvert samplen 4 spacing 1 width 0 height 0 
     set key maxcolumns 0 maxrows 0 3D key

Placement of the key for 3D plots (‘splot‘) by default uses the ‘fixed‘ option. This is very similar to ‘inside‘ placement with one important difference. The plot boundaries of a 3D plot change as the view point is rotated or scaled. If the key is positioned ‘inside‘ these boundaries then the key also moves when the view is changed. ‘fixed‘ positioning ignores changes to the view angles or scaling; i.e. the key remains fixed in one location on the canvas as the plot is rotated.

For 2D plots the ‘fixed‘ option is exactly equivalent to ‘inside‘.

If ‘splot‘ is being used to draw contours, by default a separate key entry is generated for each contour level with a distinct line type. To modify this see cntrlabel. key examples

This places the key at the default location:

      set key default

This places a key at a specific place (upper right) on the screen:

      set key at screen 0.85, 0.85

This places the key below the graph and minimizes the vertical space taken:

      set key below horizontal

This places the key in the bottom left corner of the plot, left-justifies the text, gives the key box a title at the top, and draws a box around it with a thick border:

      set key left bottom Left title 'Legend' box lw 3 extra key entries

Normally each plot autogenerates a single line entry in the key. If you need more control over what appears in the key you can use the ‘keyentry‘ keyword in the ‘plot‘ or ‘splot‘ command to insert extra lines. Instead of providing a filename or function to plot, use ‘keyentry‘ as a placeholder followed by plot style information (used to generate a key symbol) and a title. All the usual options for title font, text color, ‘at‘ coordinates, and enhanced text markup apply. Example:

     set key outside right center title "Outcomes"
     plot $HEATMAP matrix with image notitle, \
          keyentry with boxes fc palette cb 0 title "no effect", \
          keyentry with boxes fc palette cb 1 title "threshold", \
          keyentry with boxes fc palette cb 3 title "typical range", \
          keyentry with labels nopoint title "as reported in [12]", \
          keyentry with boxes fc palette cb 5 title "strong effect" key autotitle

‘set key autotitle‘ causes each plot to be identified in the key by the name of the data file or function used in the plot command. This is the default. ‘set key noautotitle‘ disables the automatic generation of plot titles.

The command ‘set key autotitle columnheader‘ causes the first entry in each column of input data to be interpreted as a text string and used as a title for the corresponding plot. If the quantity being plotted is a function of data from several columns, gnuplot may be confused as to which column to draw the title from. In this case it is necessary to specify the column explicitly in the plot command, e.g.

      plot "datafile" using (($2+$3)/$4) title columnhead(3) with lines

Note: The effect of ‘set key autotitle columnheader‘, treatment of the first line in a data file as column headers rather than data applies even if the key is disabled by ‘unset key‘. It also applies to ‘stats‘ and fit commands even though they generate no key. If you want the first line of data to be treated as column headers but _not_ to use them for plot titles, use columnheaders.

In all cases an explicit title or ‘notitle‘ keyword in the plot command itself will override the default from ‘set key autotitle‘. key layout

Key layout options:

     set key {vertical | horizontal}
            {maxcols {<max no. of columns> | auto}}
            {maxrows {<max no. of rows> | auto}}
            {columns <exact no. of columns>}
            {keywidth [screen|graph] <fraction>}
            {Left | Right}
            {{no}reverse} {{no}invert}
            {samplen <sample_length>} {spacing <line_spacing>}
            {width <width_increment>} {height <height_increment>}
            {title {"<text>"} {{no}enhanced} {center | left | right}}
            {font "<face>,<size>"} {textcolor <colorspec>}

Automatic arrangement of elements within the key into rows and columns is affected by the keywords shown above. The default is ‘vertical‘, for which the key uses the fewest columns possible. Elements are aligned in a column until there is no more vertical space, at which point a new column is started. The vertical space may be limited using ’maxrows’. In the case of ‘horizontal‘, the key instead uses the fewest rows possible. The horizontal space may be limited using ’maxcols’.

The auto-selected number of rows and columns may be unsatisfactory. You can specify a definite number of columns using ‘set key columns <N>‘. In this case you may need to adjust the sample widths (‘samplen‘) and the total key width (‘keywidth‘).

By default the first plot label is at the top of the key and successive labels are entered below it. The ‘invert‘ option causes the first label to be placed at the bottom of the key, with successive labels entered above it. This option is useful to force the vertical ordering of labels in the key to match the order of box types in a stacked histogram.

‘set key title "text"‘ places an overall title at the top of the key. Font, text justification, and other text properties specific to the title can be specified by placing the required keywords immediately after the ‘"text"‘ in this command. Font or text properties specified elsewhere apply to all text in the key.

The default layout places a style sample (color, line, point, shape, etc) at the left of the key entry line, and the title text at the right. The text and sample positions can be swapped using the ‘reverse‘ keyword. Text justification of the individual plot titles within the key is controlled by ‘Left‘ or ‘Right‘ (default). The horizontal extend of the style sample can be set to an approximate number of character width (‘samplen‘).

When using the TeX/LaTeX group of terminals or terminals in which formatting information is embedded in the string, ‘gnuplot‘ is bad at estimating the amount of space required, so the automatic key layout may be poor. If the key is to be positioned at the left, it may help to use the combination ‘set key left Left reverse‘ and force the appropriate number of columns or total key width. key placement

Key placement options:

      set key {inside | outside | fixed}
              {lmargin | rmargin | tmargin | bmargin}
              {at <position>}}
              {left | right | center} {top | bottom | center}
              {offset <dx>,<dy>}

This section describes placement of the primary, auto-generated key. To construct a secondary key or place plot titles elsewhere, see ‘multiple keys‘.

To understand positioning, the best concept is to think of a region, i.e., inside/outside, or one of the margins. Along with the region, keywords ‘left/center/right‘ (l/c/r) and ‘top/center/bottom‘ (t/c/b) control where within the particular region the key should be placed. In ‘inside‘ mode, the keywords ‘left‘ (l), ‘right‘ (r), ‘top‘ (t), ‘bottom‘ (b), and ‘center‘ (c) push the key out toward the plot boundary as illustrated here:

     t/l   t/c   t/r

     c/l    c    c/r

     b/l   b/c   b/r

In ‘outside‘ mode, automatic placement is similar to the above illustration, but with respect to the view, rather than the graph boundary. That is, a border is moved inward to make room for the key outside of the plotting area, although this may interfere with other labels and may cause an error on some devices. The particular plot border that is moved depends upon the position described above and the stacking direction. For options centered in one of the dimensions, there is no ambiguity about which border to move. For the corners, when the stack direction is ‘vertical‘, the left or right border is moved inward appropriately. When the stack direction is ‘horizontal‘, the top or bottom border is moved inward appropriately.

The margin syntax allows automatic placement of key regardless of stack direction. When one of the margins lmargin (lm), rmargin (rm), tmargin (tm), and bmargin (bm) is combined with a single, non-conflicting direction keyword, the key is positioned along the outside of the page as shown here. Keywords ‘above‘ and ‘over‘ are synonymous with tmargin. Keywords ‘below‘ and ‘under‘ are synonymous with bmargin.

          l/tm  c/tm  r/tm

     t/lm                  t/rm

     c/lm                  c/rm

     b/lm                  b/rm

          l/bm  c/bm  r/bm

For version compatibility, ‘above‘, ‘over‘, ‘below‘, or ‘under‘ without any additional l/c/r or stack direction keyword uses ‘center‘ and ‘horizontal‘. The keyword ‘outside‘ without any additional t/b/c or stack direction keyword uses ‘top‘, ‘right‘ and ‘vertical‘ (i.e., the same as t/rm above).

The <position> can be a simple x,y,z as in previous versions, but these can be preceded by one of five keywords (‘first‘, ‘second‘, ‘graph‘, ‘screen‘, ‘character‘) which selects the coordinate system in which the position of the first sample line is specified. See ‘coordinates‘ for more details. The effect of ‘left‘, ‘right‘, ‘top‘, ‘bottom‘, and ‘center‘ when <position> is given is to align the key as though it were text positioned using the label command, i.e., ‘left‘ means left align with key to the right of <position>, etc. key offset

Regardless of the key placement options chosen, the final position of the key can be adjusted manually by specifying an offset. As usual, the x and y components of the offset may be given in character, graph, or screen coordinates. key samples

By default, each plot on the graph generates a corresponding entry in the key. This entry contains a plot title and a sample line/point/box of the same color and fill properties as used in the plot itself. The font and textcolor properties control the appearance of the individual plot titles that appear in the key. Setting the textcolor to "variable" causes the text for each key entry to be the same color as the line or fill color for that plot. This was the default in some earlier versions of gnuplot.

The length of the sample line can be controlled by ‘samplen‘. The sample length is computed as the sum of the tic length and <sample_length> times the character width. It also affects the positions of point samples in the key since these are drawn at the midpoint of the sample line, even if the line itself is not drawn.

Key entry lines are single-spaced based on the current font size. This can be adjusted by ‘set key spacing <line-spacing>‘.

The <width_increment> is a number of character widths to be added to or subtracted from the length of the string. This is useful only when you are putting a box around the key and you are using control characters in the text. ‘gnuplot‘ simply counts the number of characters in the string when computing the box width; this allows you to correct it. multiple keys

It is possible to construct a legend/key manually rather than having the plot titles all appear in the auto-generated key. This allows, for example, creating a single legend for the component panels in a multiplot.

       set multiplot layout 3,2 columnsfirst
       set style data boxes
       plot $D using 0:6  lt 1 title at 0.75, 0.20
       plot $D using 0:12 lt 2 title at 0.75, 0.17
       plot $D using 0:13 lt 3 title at 0.75, 0.14
       plot $D using 0:14 lt 4 title at 0.75, 0.11
       set label 1 at screen 0.75, screen 0.22 "Custom combined key area"
       plot $D using 0:($6+$12+$13+$14) with linespoints title "total"
       unset multiplot

3.29.39 label

Arbitrary labels can be placed on the plot using the ‘set label‘ command.


      set label {<tag>} {"<label text>"} {at <position>}
                {left | center | right}
                {norotate | rotate {by <degrees>}}
                {font "<name>{,<size>}"}
                {front | back}
                {textcolor <colorspec>}
                {point <pointstyle> | nopoint}
                {offset <offset>}
                {nobox} {boxed {bs <boxstyle>}}
      unset label {<tag>}
      show label

The <position> is specified by either x,y or x,y,z, and may be preceded by ‘first‘, ‘second‘, ‘polar‘, ‘graph‘, ‘screen‘, or ‘character‘ to indicate the coordinate system. See ‘coordinates‘ for details.

The tag is an integer that is used to identify the label. If no <tag> is given, the lowest unused tag value is assigned automatically. The tag can be used to delete or modify a specific label. To change any attribute of an existing label, use the ‘set label‘ command with the appropriate tag, and specify the parts of the label to be changed.

The <label text> can be a string constant, a string variable, or a string- valued expression. See ‘strings‘, sprintf, and gprintf.

By default, the text is placed flush left against the point x,y,z. To adjust the way the label is positioned with respect to the point x,y,z, add the justification parameter, which may be ‘left‘, ‘right‘ or ‘center‘, indicating that the point is to be at the left, right or center of the text. Labels outside the plotted boundaries are permitted but may interfere with axis labels or other text.

Some terminals support enclosing the label in a box. See ‘set style textbox‘. Not all terminals can handle boxes for rotated text.

If ‘rotate‘ is given, the label is written vertically. If ‘rotate by <degrees>‘ is given, the baseline of the text will be set to the specified angle. Some terminals do not support text rotation.

Font and its size can be chosen explicitly by ‘font "<name>{,<size>}"‘ if the terminal supports font settings. Otherwise the default font of the terminal will be used.

Normally the enhanced text mode string interpretation, if enabled for the current terminal, is applied to all text strings including label text. The ‘noenhanced‘ property can be used to exempt a specific label from the enhanced text mode processing. The can be useful if the label contains underscores, for example. See ‘enhanced text‘.

If ‘front‘ is given, the label is written on top of the graphed data. If ‘back‘ is given (the default), the label is written underneath the graphed data. Using ‘front‘ will prevent a label from being obscured by dense data.

‘textcolor <colorspec>‘ changes the color of the label text. <colorspec> can be a linetype, an rgb color, or a palette mapping. See help for colorspec and palette. ‘textcolor‘ may be abbreviated ‘tc‘.

   `tc default` resets the text color to its default state.
   `tc lt <n>` sets the text color to that of line type <n>.
   `tc ls <n>` sets the text color to that of line style <n>.
   `tc palette z` selects a palette color corresponding to the label z position.
   `tc palette cb <val>` selects a color corresponding to <val> on the colorbar.
   `tc palette fraction <val>`, with 0<=val<=1, selects a color corresponding to
       the mapping [0:1] to grays/colors of the palette.
   `tc rgb "#RRGGBB"` or `tc rgb "0xRRGGBB"` sets an arbitrary 24-bit RGB color.
   `tc rgb 0xRRGGBB`  As above; a hexadecimal constant does not require quotes.

If a <pointstyle> is given, using keywords ‘lt‘, ‘pt‘ and ‘ps‘, see style, a point with the given style and color of the given line type is plotted at the label position and the text of the label is displaced slightly. This option is used by default for placing labels in ‘mouse‘ enhanced terminals. Use ‘nopoint‘ to turn off the drawing of a point near the label (this is the default).

The displacement defaults to 1,1 in pointsize units if a <pointstyle> is given, 0,0 if no <pointstyle> is given. The displacement can be controlled by the optional ‘offset <offset>‘ where <offset> is specified by either x,y or x,y,z, and may be preceded by ‘first‘, ‘second‘, ‘graph‘, ‘screen‘, or ‘character‘ to select the coordinate system. See ‘coordinates‘ for details.

If one (or more) axis is timeseries, the appropriate coordinate should be given as a quoted time string according to the timefmt format string. See xdata and timefmt.

The options available for ‘set label‘ are also available for the labels plot style. See labels. In this case the properties ‘textcolor‘, ‘rotate‘, and pointsize may be followed by keyword ‘variable‘ rather than by a fixed value. In this case the corresponding property of individual labels is determined by additional columns in the ‘using‘ specifier. examples


To set a label at (1,2) to "y=x", use:

      set label "y=x" at 1,2

To set a Sigma of size 24, from the Symbol font set, at the center of the graph, use:

      set label "S" at graph 0.5,0.5 center font "Symbol,24"

To set a label "y=x^2" with the right of the text at (2,3,4), and tag the label as number 3, use:

      set label 3 "y=x^2" at 2,3,4 right

To change the preceding label to center justification, use:

      set label 3 center

To delete label number 2, use:

      unset label 2

To delete all labels, use:

      unset label

To show all labels (in tag order), use:

      show label

To set a label on a graph with a timeseries on the x axis, use, for example:

      set timefmt "%d/%m/%y,%H:%M"
      set label "Harvest" at "25/8/93",1

To display a freshly fitted parameter on the plot with the data and the fitted function, do this after the fit, but before the ‘plot‘:

      set label sprintf("a = %3.5g",par_a) at 30,15
      bfit = gprintf("b = %s*10^%S",par_b)
      set label bfit at 30,20

To display a function definition along with its fitted parameters, use:

      fit f(x) 'datafile' via a,b
      set label GPFUN_f at graph .05,.95
      set label sprintf("a = %g", a) at graph .05,.90
      set label sprintf("b = %g", b) at graph .05,.85

To set a label displaced a little bit from a small point:

      set label 'origin' at 0,0 point lt 1 pt 2 ps 3 offset 1,-1

To set a label whose color matches the z value (in this case 5.5) of some point on a 3D splot colored using pm3d:

      set label 'text' at 0,0,5.5 tc palette z hypertext

Some terminals (wxt, qt, svg, canvas, win) allow you to attach hypertext to specific points on the graph or elsewhere on the canvas. When the mouse hovers over the anchor point, a pop-up box containing the text is displayed. Terminals that do not support hypertext will display nothing. You must enable the ‘point‘ attribute of the label in order for the hypertext to be anchored. Examples:

      set label at 0,0 "Plot origin" hypertext point pt 1
      plot 'data' using 1:2:0 with labels hypertext point pt 7 \
           title 'mouse over point to see its order in data set'

For the wxt and qt terminals, left-click on a hypertext anchor after the text has appeared will copy the hypertext to the clipboard.

EXPERIMENTAL (implementation details may change) Text of the form "image{<xsize>,<ysize>}:<filename>{\n<caption text>}" will trigger display of the image file in a pop-up box. The optional size overrides a default box size 300x200. The types of image file recognized may vary by terminal type, but *.png should always work. Any additional text lines following the image filename are displayed as usual for hypertext. Example:

      set label 7 "image:../figures/Fig7_inset.png\nFigure 7 caption..."
      set label 7 at 10,100 hypertext point pt 7

3.29.40 linetype

The ‘set linetype‘ command allows you to redefine the basic linetypes used for plots. The command options are identical to those for "set style line". Unlike line styles, redefinitions by ‘set linetype‘ are persistent; they are not affected by reset.

For example, whatever linetypes one and two look like to begin with, if you redefine them like this:

      set linetype 1 lw 2 lc rgb "blue" pointtype 6
      set linetype 2 lw 2 lc rgb "forest-green" pointtype 8

everywhere that uses lt 1 will now get a thick blue line. This includes uses such as the definition of a temporary linestyle derived from the base linetype 1. Similarly lt 2 will now produce a thick green line.

This mechanism can be used to define a set of personal preferences for the sequence of lines used in gnuplot. The recommended way to do this is to add to the run-time initialization file ~/.gnuplot a sequence of commands like

      set linetype 1 lc rgb "dark-violet" lw 2 pt 1
      set linetype 2 lc rgb "sea-green"   lw 2 pt 7
      set linetype 3 lc rgb "cyan"        lw 2 pt 6 pi -1
      set linetype 4 lc rgb "dark-red"    lw 2 pt 5 pi -1
      set linetype 5 lc rgb "blue"        lw 2 pt 8
      set linetype 6 lc rgb "dark-orange" lw 2 pt 3
      set linetype 7 lc rgb "black"       lw 2 pt 11
      set linetype 8 lc rgb "goldenrod"   lw 2
      set linetype cycle 8

Every time you run gnuplot the line types will be initialized to these values. You may initialize as many linetypes as you like. If you do not redefine, say, linetype 3 then it will continue to have the default properties (in this case blue, pt 3, lw 1, etc).

Similar script files can be used to define theme-based color choices, or sets of colors optimized for a particular plot type or output device.

The command ‘set linetype cycle 8‘ tells gnuplot to re-use these definitions for the color and linewidth of higher-numbered linetypes. That is, linetypes 9-16, 17-24, and so on will use this same sequence of colors and widths. The point properties (pointtype, pointsize, pointinterval) are not affected by this command. ‘unset linetype cycle‘ disables this feature. If the line properties of a higher numbered linetype are explicitly defined, this takes precedence over the recycled low-number linetype properties.

3.29.42 lmargin

The command lmargin sets the size of the left margin. Please see margin for details.

3.29.43 loadpath

The loadpath setting defines additional locations for data and command files searched by the call, ‘load‘, ‘plot‘ and ‘splot‘ commands. If a file cannot be found in the current directory, the directories in loadpath are tried.


      set loadpath {"pathlist1" {"pathlist2"...}}
      show loadpath

Path names may be entered as single directory names, or as a list of path names separated by a platform-specific path separator, eg. colon (’:’) on Unix, semicolon (’;’) on DOS/Windows/OS/2 platforms. The loadpath, save and ‘save set‘ commands replace the platform-specific separator with a space character (’ ’).

If the environment variable GNUPLOT_LIB is set, its contents are appended to loadpath. However, loadpath prints the contents of loadpath and GNUPLOT_LIB separately. Also, the save and ‘save set‘ commands ignore the contents of GNUPLOT_LIB.

3.29.44 locale

The locale setting determines the language with which ‘{x,y,z}{d,m}tics‘ will write the days and months.


      set locale {"<locale>"}

<locale> may be any language designation acceptable to your installation. See your system documentation for the available options. The command ‘set locale ""‘ will try to determine the locale from the LC_TIME, LC_ALL, or LANG environment variables.

To change the decimal point locale, see decimalsign. To change the character encoding to the current locale, see encoding.

3.29.45 logscale


      set logscale <axes> {<base>}
      unset logscale <axes>
      show logscale

where <axes> may be any combinations of ‘x‘, ‘x2‘, ‘y‘, ‘y2‘, ‘z‘, ‘cb‘, and ‘r‘ in any order. <base> is the base of the log scaling (default is base 10). If no axes are specified, the command affects all axes except ‘r‘. The command logscale turns off log scaling for all axes. Note that the ticmarks generated for logscaled axes are not uniformly spaced. See ‘set xtics‘.


To enable log scaling in both x and z axes:

      set logscale xz

To enable scaling log base 2 of the y axis:

      set logscale y 2

To enable z and color log axes for a pm3d plot:

      set logscale zcb

To disable z axis log scaling:

      unset logscale z

3.29.46 macros

In this version of gnuplot macro substitution is always enabled. Tokens in the command line of the form @<stringvariablename> will be replaced by the text string contained in <stringvariablename>. See ‘substitution‘.

3.29.47 mapping

If data are provided to ‘splot‘ in spherical or cylindrical coordinates, the mapping command should be used to instruct ‘gnuplot‘ how to interpret them.


      set mapping {cartesian | spherical | cylindrical}

A cartesian coordinate system is used by default.

For a spherical coordinate system, the data occupy two or three columns (or ‘using‘ entries). The first two are interpreted as the azimuthal and polar angles theta and phi (or "longitude" and "latitude"), in the units specified by angles. The radius r is taken from the third column if there is one, or is set to unity if there is no third column. The mapping is:

      x = r * cos(theta) * cos(phi)
      y = r * sin(theta) * cos(phi)
      z = r * sin(phi)

Note that this is a "geographic" spherical system, rather than a "polar" one (that is, phi is measured from the equator, rather than the pole).

For a cylindrical coordinate system, the data again occupy two or three columns. The first two are interpreted as theta (in the units specified by angles) and z. The radius is either taken from the third column or set to unity, as in the spherical case. The mapping is:

      x = r * cos(theta)
      y = r * sin(theta)
      z = z

The effects of mapping can be duplicated with the ‘using‘ filter on the ‘splot‘ command, but mapping may be more convenient if many data files are to be processed. However even if mapping is used, ‘using‘ may still be necessary if the data in the file are not in the required order.

mapping has no effect on ‘plot‘. world.dem: mapping demos.

3.29.48 margin

The margin is the distance between the plot border and the outer edge of the canvas. The size of the margin is chosen automatically, but can be overridden by the margin commands. margin shows the current settings. To alter the distance between the inside of the plot border and the data in the plot itself, see offsets.


      set lmargin {{at screen} <margin>}
      set rmargin {{at screen} <margin>}
      set tmargin {{at screen} <margin>}
      set bmargin {{at screen} <margin>}
      set margins <left>, <right>, <bottom>, <top>
      show margin

The default units of <margin> are character heights or widths, as appropriate. A positive value defines the absolute size of the margin. A negative value (or none) causes ‘gnuplot‘ to revert to the computed value. For 3D plots, only the left margin can be set using character units.

The keywords ‘at screen‘ indicates that the margin is specified as a fraction of the full drawing area. This can be used to precisely line up the corners of individual 2D and 3D graphs in a multiplot. This placement ignores the current values of origin and size, and is intended as an alternative method for positioning graphs within a multiplot.

Normally the margins of a plot are automatically calculated based on tics, tic labels, axis labels, the plot title, the timestamp and the size of the key if it is outside the borders. If, however, tics are attached to the axes (‘set xtics axis‘, for example), neither the tics themselves nor their labels will be included in either the margin calculation or the calculation of the positions of other text to be written in the margin. This can lead to tic labels overwriting other text if the axis is very close to the border.

3.29.49 micro

By default the "%c" format specifier for scientific notation used to generate axis tick labels uses a lower case u as a prefix to indicate "micro" (10^-6). The micro command tells gnuplot to use a different typographic character (unicode U+00B5). The byte sequence used to represent this character depends on the current encoding. See ‘format specifiers‘, encoding.

This command is EXPERIMENTAL. Implementation details may change.

3.29.50 minussign

Gnuplot uses the C language library routine sprintf() for most formatted input. However it also has its own formatting routine ‘gprintf()‘ that is used to generate axis tic labels. The C library routine always use a hyphen character (ascii \055) to indicate a negative number, as in -7. Many people prefer a different typographic minus sign character (unicode U+2212) for this purpose, as in −7. The command

     set minussign

causes gprintf() to use this minus sign character rather than a hyphen in numeric output. In a utf-8 locale this is the multibyte sequence corresponding to unicode U+2212. In a Window codepage 1252 locale this is the 8-bit character ALT+150 ("en dash"). The minussign command will affect axis tic labels and any labels that are created by explicitly invoking gprintf. It has no effect on other strings that contain a hyphen. See gprintf.

Note that this command is ignored when you are using any of the LaTeX terminals, as LaTeX has its own mechanism for handling minus signs. It also is not necessary when using the postscript terminal because the postscript prologue output by gnuplot remaps the ascii hyphen code \055 to a different glyph named ‘minus‘.

This command is EXPERIMENTAL. Implementation details may change.

Example (assumes utf8 locale):

     set minus
     A = -5
     print "A = ",A                 # printed string will contain a hyphen
     print gprintf("A = %g",A)      # printed string will contain character U+2212
     set label "V = -5"             # label will contain a hyphen
     set label sprintf("V = %g",-5) # label will contain a hyphen
     set label gprintf("V = %g",-5) # label will contain character U+2212

3.29.51 monochrome


     set monochrome {linetype N <linetype properties>}

The monochrome command selects an alternative set of linetypes that differ by dot/dash pattern or line width rather than by color. This command replaces the monochrome option offered by certain terminal types in earlier versions of gnuplot. For backward compatibility these terminal types now implicitly invoke "set monochrome" if their own "mono" option is present. For example,

     set terminal pdf mono

is equivalent to

     set terminal pdf
     set mono

Selecting monochrome mode does not prevent you from explicitly drawing lines using RGB or palette colors, but see also gray. Six monochrome linetypes are defined by default. You can change their properties or add additional monochrome linetypes by using the full form of the command. Changes made to the monochrome linetypes do not affect the color linetypes and vice versa. To restore the usual set of color linetypes, use either monochrome or ‘set color‘.

3.29.52 mouse

The command ‘set mouse‘ enables mouse actions for the current interactive terminal. It is usually enabled by default in interactive mode, but disabled by default if commands are being read from a file.

There are two mouse modes. The 2D mode works for ‘plot‘ commands and for ‘splot‘ maps (i.e. view with z-rotation 0, 90, 180, 270 or 360 degrees, including ‘set view map‘). In this mode the mouse position is tracked and you can pan or zoom using the mouse buttons or arrow keys. Some terminals support toggling individual plots on/off by clicking on the corresponding key title or on a separate widget.

For 3D graphs ‘splot‘, the view and scaling of the graph can be changed with mouse buttons 1 and 2, respectively. A vertical motion of Button 2 with the shift key held down changes the xyplane. If additionally to these buttons the modifier <ctrl> is held down, the coordinate axes are displayed but the data are suppressed. This is useful for large data sets. Mouse button 3 controls the azimuth of the z axis (see azimuth).

Mousing is not available inside multiplot mode. When multiplot is completed using multiplot, then the mouse will be turned on again but acts only on the most recent plot within the multiplot (like replot does).


      set mouse {doubleclick <ms>} {nodoubleclick}
                {zoomfactors <xmultiplier>, <ymultiplier>}
                {noruler | ruler {at x,y}}
                {polardistance{deg|tan} | nopolardistance}
                {format <string>}
                {mouseformat <int> | <string> | function <f(x,y)>}
                {{no}labels {"labeloptions"}}
                {{no}zoomjump} {{no}verbose}
      unset mouse

The options ‘noruler‘ and ‘ruler‘ switch the ruler off and on, the latter optionally setting the origin at the given coordinates. While the ruler is on, the distance in user units from the ruler origin to the mouse is displayed continuously. By default, toggling the ruler has the key binding ’r’.

The option ‘polardistance‘ determines if the distance between the mouse cursor and the ruler is also shown in polar coordinates (distance and angle in degrees or tangent (slope)). This corresponds to the default key binding ’5’.

Choose the option labels to define persistent gnuplot labels using Button 2. The default is ‘nolabels‘, which makes Button 2 draw only a temporary label at the mouse position. Labels are drawn with the current setting of mouseformat. The ‘labeloptions‘ string is passed to the ‘set label‘ command. The default is "point pointstyle 1" which will plot a small plus at the label position. Temporary labels will disappear at the next replot or mouse zoom operation. Persistent labels can be removed by holding the Ctrl-Key down while clicking Button 2 on the label’s point. The threshold for how close you must be to the label is also determined by the pointsize.

If the option ‘verbose‘ is turned on the communication commands are shown during execution. This option can also be toggled by hitting ‘6‘ in the driver’s window. ‘verbose‘ is off by default.

Press ’h’ in the driver’s window for a short summary of the mouse and key bindings. This will also display user defined bindings or ‘hotkeys‘ which can be defined using the ‘bind‘ command, see help for ‘bind‘. Note, that user defined ‘hotkeys‘ may override the default bindings. See also help for ‘bind‘ and ‘label‘. doubleclick

The doubleclick resolution is given in milliseconds and used for Button 1, which copies the current mouse position to the ‘clipboard‘ on some terminals. The default value is 300 ms. Setting the value to 0 ms triggers the copy on a single click. format

The ‘set mouse format‘ command specifies a format string for sprintf() which determines how the mouse cursor [x,y] coordinates are printed to the plot window and to the clipboard. The default is "% #g".

This setting is superseded by "set mouse mouseformat". mouseformat


     set mouse mouseformat i
     set mouse mouseformat "custom format"
     set mouse mouseformat function string_valued_function(x, y)

This command controls the format used to report the current mouse position. An integer argument selects one of the format options in the table below. A string argument is used as a format for sprintf() in option 7 and should contain two float specifiers, one for x and one for y.

Use of a custom function returning a string is EXPERIMENTAL. It allows readout of coordinate systems in which inverse mapping from screen coordinates to plot coordinates requires joint consideration of both x and y. See for example the map_projection demo.


     `set mouse mouseformat "mouse x,y = %5.2g, %10.3f"`.

Use ‘set mouse mouseformat ""‘ to turn this string off again.

The following formats are available:

 0   default (same as 1)
 1   axis coordinates                    1.23, 2.45
 2   graph coordinates (from 0 to 1)    /0.00, 1.00/
 3   x = timefmt     y = axis           [(as set by timefmt), 2.45]
 4   x = date        y = axis           [31. 12. 1999, 2.45]
 5   x = time        y = axis           [23:59, 2.45]
 6   x = date time   y = axis           [31. 12. 1999 23:59, 2.45]
 7   format from `set mouse mouseformat <format-string>`
 8   format from `set mouse mouseformat function <func>` scrolling

X and Y axis scaling in both 2D and 3D graphs can be adjusted using the mouse wheel. <wheel-up> scrolls up (increases both YMIN and YMAX by ten percent of the Y range, and increases both Y2MIN and Y2MAX likewise), and <wheel down> scrolls down. <shift-wheel-up> scrolls left (decreases both XMIN and XMAX, and both X2MIN and X2MAX), and <shift-wheel-down> scrolls right. <control-wheel-up> zooms in toward the center of the plot, and <control-wheel-down> zooms out. <shift-control-wheel-up> zooms in along the X and X2 axes only, and <shift-control-wheel-down> zooms out along the X and X2 axes only. X11 mouse

If multiple X11 plot windows have been opened using the ‘set term x11 <n>‘ terminal option, then only the current plot window supports the entire range of mouse commands and hotkeys. The other windows will, however, continue to display mouse coordinates at the lower left. zoom

Zooming is usually accomplished by holding down the left mouse button and dragging the mouse to delineate a zoom region. Some platforms may require using a different mouse button. The original plot can be restored by typing the ’u’ hotkey in the plot window. The hotkeys ’p’ and ’n’ step back and forth through a history of zoom operations.

The option ‘zoomcoordinates‘ determines if the coordinates of the zoom box are drawn at the edges while zooming. This is on by default.

If the option ‘zoomjump‘ is on, the mouse pointer will be automatically offset a small distance after starting a zoom region with button 3. This can be useful to avoid a tiny (or even empty) zoom region. ‘zoomjump‘ is off by default.

3.29.53 mttics

Minor tic marks around the perimeter of a polar plot are controlled by by mttics. Please see mxtics.

3.29.54 multiplot

The command multiplot places ‘gnuplot‘ in the multiplot mode, in which several plots are placed next to each other on the same page or screen window.


      set multiplot
          { title <page title> {font <fontspec>} {enhanced|noenhanced} }
          { layout <rows>,<cols>
            {rowsfirst|columnsfirst} {downwards|upwards}
            {scale <xscale>{,<yscale>}} {offset <xoff>{,<yoff>}}
            {margins <left>,<right>,<bottom>,<top>}
            {spacing <xspacing>{,<yspacing>}}
      set multiplot {next|previous}
      unset multiplot

For some terminals, no plot is displayed until the command multiplot is given, which causes the entire page to be drawn and then returns gnuplot to its normal single-plot mode. For other terminals, each separate ‘plot‘ command produces an updated display.

The clear command is used to erase the rectangular area of the page that will be used for the next plot. This is typically needed to inset a small plot inside a larger plot.

Any labels or arrows that have been defined will be drawn for each plot according to the current size and origin (unless their coordinates are defined in the ‘screen‘ system). Just about everything else that can be ‘set‘ is applied to each plot, too. If you want something to appear only once on the page, for instance a single time stamp, you’ll need to put a ‘set time‘/‘unset time‘ pair around one of the ‘plot‘, ‘splot‘ or replot commands within the multiplot/multiplot block.

The multiplot title is separate from the individual plot titles, if any. Space is reserved for it at the top of the page, spanning the full width of the canvas.

The commands origin and size must be used to correctly position each plot if no layout is specified or if fine tuning is desired. See origin and size for details of their usage.


      set multiplot
      set size 0.4,0.4
      set origin 0.1,0.1
      plot sin(x)
      set size 0.2,0.2
      set origin 0.5,0.5
      plot cos(x)
      unset multiplot

This displays a plot of cos(x) stacked above a plot of sin(x).

size and origin refer to the entire plotting area used for each plot. Please also see size. If you want to have the axes themselves line up, you can guarantee that the margins are the same size with the margin commands. See margin for their use. Note that the margin settings are absolute, in character units, so the appearance of the graph in the remaining space will depend on the screen size of the display device, e.g., perhaps quite different on a video display and a printer.

With the ‘layout‘ option you can generate simple multiplots without having to give the size and origin commands before each plot: Those are generated automatically, but can be overridden at any time. With ‘layout‘ the display will be divided by a grid with <rows> rows and <cols> columns. This grid is filled rows first or columns first depending on whether the corresponding option is given in the multiplot command. The stack of plots can grow ‘downwards‘ or ‘upwards‘. Default is ‘rowsfirst‘ and ‘downwards‘. The commands ‘set multiplot next‘ and ‘set multiplot previous‘ are relevant only in the context of using the layout option. ‘next‘ skips the next position in the grid, leaving a blank space. ‘prev‘ returns to the grid position immediately preceding the most recently plotted position.

Each plot can be scaled by ‘scale‘ and shifted with ‘offset‘; if the y-values for scale or offset are omitted, the x-value will be used. multiplot will turn off the automatic layout and restore the values of size and origin as they were before ‘set multiplot layout‘.


      set size 1,1
      set origin 0,0
      set multiplot layout 3,2 columnsfirst scale 1.1,0.9
      [ up to 6 plot commands here ]
      unset multiplot

The above example will produce 6 plots in 2 columns filled top to bottom, left to right. Each plot will have a horizontal size of 1.1/2 and a vertical size of 0.9/3.

Another possibility is to set uniform margins for all plots in the layout with options ‘layout margins‘ and ‘spacing‘, which must be used together. With ‘margins‘ you set the outer margins of the whole multiplot grid.

‘spacing‘ gives the gap size between two adjacent subplots, and can also be given in ‘character‘ or ‘screen‘ units. If a single value is given, it is used for both x and y direction, otherwise two different values can be selected.

If one value has no unit, the one of the preceding margin setting is used.


      set multiplot layout 2,2 margins 0.1, 0.9, 0.1, 0.9 spacing 0.0

In this case the two left-most subplots will have left boundaries at screen coordinate 0.1, the two right-most subplots will have right boundaries at screen coordinate 0.9, and so on. Because the spacing between subplots is given as 0, their inner boundaries will superimpose.


      set multiplot layout 2,2 margins char 5,1,1,2 spacing screen 0, char 2

This produces a layout in which the boundary of both left subplots is 5 character widths from the left edge of the canvas, the right boundary of the right subplots is 1 character width from the canvas edge. The overall bottom margin is one character height and the overall top margin is 2 character heights. There is no horizontal gap between the two columns of subplots. The vertical gap between subplots is equal to 2 character heights.


      set multiplot layout 2,2 columnsfirst margins 0.1,0.9,0.1,0.9 spacing 0.1
      set ylabel 'ylabel'
      plot sin(x)
      set xlabel 'xlabel'
      plot cos(x)
      unset ylabel
      unset xlabel
      plot sin(2*x)
      set xlabel 'xlabel'
      plot cos(2*x)
      unset multiplot

See also multiplot demo (multiplt.dem)

3.29.55 mx2tics

Minor tic marks along the x2 (top) axis are controlled by mx2tics. Please see mxtics.

3.29.56 mxtics

Minor tic marks along the x axis are controlled by mxtics. They can be turned off with mxtics. Similar commands control minor tics along the other axes.


      set mxtics {<freq> | default}
      unset mxtics
      show mxtics

The same syntax applies to mytics, mztics, mx2tics, my2tics, ‘mrtics‘, mttics and ‘mcbtics‘.

<freq> is the number of sub-intervals (NOT the number of minor tics) between major tics (the default for a linear axis is either two or five depending on the major tics, so there are one or four minor tics between major tics). Selecting ‘default‘ will return the number of minor ticks to its default value.

If the axis is logarithmic, the number of sub-intervals will be set to a reasonable number by default (based upon the length of a decade). This will be overridden if <freq> is given. However the usual minor tics (2, 3, ..., 8, 9 between 1 and 10, for example) are obtained by setting <freq> to 10, even though there are but nine sub-intervals.

To set minor tics at arbitrary positions, use the ("<label>" <pos> <level>, ...) form of ‘set {x|x2|y|y2|z}tics‘ with <label> empty and <level> set to 1.

The ‘set m{x|x2|y|y2|z}tics‘ commands work only when there are uniformly spaced major tics. If all major tics were placed explicitly by ‘set {x|x2|y|y2|z}tics‘, then minor tic commands are ignored. Implicit major tics and explicit minor tics can be combined using ‘set {x|x2|y|y2|z}tics‘ and ‘set {x|x2|y|y2|z}tics add‘.


      set xtics 0, 5, 10
      set xtics add (7.5)
      set mxtics 5

Major tics at 0,5,7.5,10, minor tics at 1,2,3,4,6,7,8,9

      set logscale y
      set ytics format ""
      set ytics 1e-6, 10, 1
      set ytics add ("1" 1, ".1" 0.1, ".01" 0.01, "10^-3" 0.001, \
                     "10^-4" 0.0001)
      set mytics 10

Major tics with special formatting, minor tics at log positions

By default, minor tics are off for linear axes and on for logarithmic axes. They inherit the settings for ‘axis|border‘ and ‘{no}mirror‘ specified for the major tics. Please see ‘set xtics‘ for information about these.

3.29.57 my2tics

Minor tic marks along the y2 (right-hand) axis are controlled by my2tics. Please see mxtics.

3.29.58 mytics

Minor tic marks along the y axis are controlled by mytics. Please see mxtics.

3.29.59 mztics

Minor tic marks along the z axis are controlled by mztics. Please see mxtics.

3.29.60 nonlinear


      set nonlinear <axis> via f(axis) inverse g(axis)
      unset nonlinear <axis>

This command is similar to the link command except that only one of the two linked axes is visible. The hidden axis remains linear. Coordinates along the visible axis are mapped by applying g(x) to hidden axis coordinates. f(x) maps the visible axis coordinates back onto the hidden linear axis. You must provide both the forward and inverse expressions.

To illustrate how this works, consider the case of a log-scale x2 axis.

      set x2ange [1:1000]
      set nonlinear x2 via log10(x) inverse 10**x

This achieves the same effect as ‘set log x2‘. The hidden axis in this case has range [0:3], obtained by calculating [log10(xmin):log10(xmax)].

The transformation functions f() and g() must be defined using a dummy variable appropriate to the nonlinear axis:

    axis: x x2   dummy variable x
    axis: y y2   dummy variable y
    axis: z cb   dummy variable z
    axis: r      dummy variable r


      set xrange [-3:3]
      set nonlinear x via norm(x) inverse invnorm(x)

This example establishes a probability-scaled ("probit") x axis, such that plotting the cumulative normal function Phi(x) produces a straight line plot against a linear y axis.


      logit(p) = log(p/(1-p))
      logistic(a) = 1. / (1. + exp(-a))
      set xrange [.001 : .999]
      set nonlinear y via logit(y) inverse logistic(y)
      plot logit(x)

This example establishes a logit-scaled y axis such that plotting logit(x) on a linear x axis produces a straight line plot.


      f(x) = (x <= 100) ? x : (x < 500) ? NaN : x-390
      g(x) = (x <= 100) ? x : x+390
      set xrange [0:1000] noextend
      set nonlinear x via f(x) inverse g(x)
      set xtics add (100,500)
      plot sample [x=1:100] x, [x=500:1000] x

This example creates a "broken axis". X coordinates 0-100 are at the left, X coordinates 500-1000 are at the right, there is a small gap (10 units) between them. So long as no data points with (100 < x < 500) are plotted, this works as expected.

3.29.61 object

The object command defines a single object which will appear in subsequent plots. You may define as many objects as you like. Currently the supported object types are rectangle, ‘circle‘, ‘ellipse‘, and ‘polygon‘. Rectangles inherit a default set of style properties (fill, color, border) from those set by the command rectangle, but each object can also be given individual style properties. Circles, ellipses, and polygons inherit the fill style from ‘set style fill‘. Objects to be drawn in 2D plots may be defined in any combination of axis, graph, polar, or screen coordinates.

Object specifications in 3D plots cannot use graph coordinates. Rectangles and ellipses in 3D plots are limited to screen coordinates.


    set object <index>
        <object-type> <object-properties>
        {fc|fillcolor <colorspec>} {fs <fillstyle>}
        {default} {lw|linewidth <width>} {dt|dashtype <dashtype>}
    unset object <index>

<object-type> is either rectangle, ‘ellipse‘, ‘circle‘, or ‘polygon‘. Each object type has its own set of characteristic properties.

The options ‘front‘, ‘back‘, ‘behind‘ control whether the object is drawn before or after the plot itself. See layers. Setting ‘front‘ will draw the object in front of all plot elements, but behind any labels that are also marked ‘front‘. Setting ‘back‘ will place the object behind all plot curves and labels. Setting ‘behind‘ will place the object behind everything including the axes and ‘back‘ rectangles, thus

    set object rectangle from screen 0,0 to screen 1,1 behind

can be used to provide a colored background for the entire graph or page.

By default, objects are clipped to the graph boundary unless one or more vertices are given in screen coordinates. Setting ‘noclip‘ will disable clipping to the graph boundary, but will still clip against the screen size.

The fill color of the object is taken from the <colorspec>. fillcolor may be abbreviated ‘fc‘. The fill style is taken from <fillstyle>. See colorspec and ‘fillstyle‘. If the keyword ‘default‘ is given, these properties are inherited from the default settings at the time a plot is drawn. See rectangle. rectangle


    set object <index> rectangle
        {from <position> {to|rto} <position> |
         center <position> size <w>,<h> |
         at <position> size <w>,<h>}

The position of the rectangle may be specified by giving the position of two diagonal corners (bottom left and top right) or by giving the position of the center followed by the width and the height. In either case the positions may be given in axis, graph, or screen coordinates. See ‘coordinates‘. The options ‘at‘ and ‘center‘ are synonyms.


    # Force the entire area enclosed by the axes to have background color cyan
    set object 1 rect from graph 0, graph 0 to graph 1, graph 1 back
    set object 1 rect fc rgb "cyan" fillstyle solid 1.0

    # Position a red square with lower left at 0,0 and upper right at 2,3
    set object 2 rect from 0,0 to 2,3 fc lt 1

    # Position an empty rectangle (no fill) with a blue border
    set object 3 rect from 0,0 to 2,3 fs empty border rgb "blue"

    # Return fill and color to the default style but leave vertices unchanged
    set object 2 rect default

Rectangle corners specified in screen coordinates may extend beyond the edge of the current graph. Otherwise the rectangle is clipped to fit in the graph. ellipse


    set object <index> ellipse {at|center} <position> size <w>,<h>
        {angle <orientation>} {units xy|xx|yy}

The position of the ellipse is specified by giving the center followed by the width and the height (actually the major and minor axes). The keywords ‘at‘ and ‘center‘ are synonyms. The center position may be given in axis, graph, or screen coordinates. See ‘coordinates‘. The major and minor axis lengths must be given in axis coordinates. The orientation of the ellipse is specified by the angle between the horizontal axis and the major diameter of the ellipse. If no angle is given, the default ellipse orientation will be used instead (see ‘set style ellipse‘). The ‘units‘ keyword controls the scaling of the axes of the ellipse. ‘units xy‘ means that the major axis is interpreted in terms of units along the x axis, while the minor axis in that of the y axis. ‘units xx‘ means that both axes of the ellipses are scaled in the units of the x axis, while ‘units yy‘ means that both axes are in units of the y axis. The default is ‘xy‘ or whatever ‘set style ellipse units‘ was set to.

NB: If the x and y axis scales are not equal, (e.g. ‘units xy‘ is in effect) then the major/minor axis ratio will no longer be correct after rotation.

Note that ‘set object ellipse size <2r>,<2r>‘ does not in general produce the same result as ‘set object circle <r>‘. The circle radius is always interpreted in terms of units along the x axis, and will always produce a circle even if the x and y axis scales are different and even if the aspect ratio of your plot is not 1. If ‘units‘ is set to ‘xy‘, then ’set object ellipse’ interprets the first <2r> in terms of x axis units and the second <2r> in terms of y axis units. This will only produce a circle if the x and y axis scales are identical and the plot aspect ratio is 1. On the other hand, if ‘units‘ is set to ‘xx‘ or ‘yy‘, then the diameters specified in the ’set object’ command will be interpreted in the same units, so the ellipse will have the correct aspect ratio, and it will maintain its aspect ratio even if the plot is resized. circle


    set object <index> circle {at|center} <position> size <radius>
        {arc [<begin>:<end>]} {no{wedge}}

The position of the circle is specified by giving the position of the center center followed by the radius. The keywords ‘at‘ and ‘center‘ are synonyms. In 2D plots the position and radius may be given in any coordinate system. See ‘coordinates‘. Circles in 3D plots cannot use graph coordinates. In all cases the radius is calculated relative to the horizontal scale of the axis, graph, or canvas. Any disparity between the horizontal and vertical scaling will be corrected for so that the result is always a circle. If you want to draw a circle in plot coordinates (such that it will appear as an ellipse if the horizontal and vertical scales are different), use ‘set object ellipse‘ instead.

By default a full circle is drawn. The optional qualifier ‘arc‘ specifies a starting angle and ending angle, in degrees, for one arc of the circle. The arc is always drawn counterclockwise.

See also ‘set style circle‘, ‘set object ellipse‘. polygon


    set object <index> polygon
        from <position> to <position> ... {to <position>}


        from <position> rto <position> ... {rto <position>}

The position of the polygon may be specified by giving the position of a sequence of vertices. These may be given in any coordinate system. If relative coordinates are used (rto) then the coordinate type must match that of the previous vertex. See ‘coordinates‘.


    set object 1 polygon from 0,0 to 1,1 to 2,0
    set object 1 fc rgb "cyan" fillstyle solid 1.0 border lt -1


The option ‘set object N depthorder‘ applies to 3D polygon objects only. Rather than assigning the object to layer front/back/behind it is included in the list of pm3d quadrangles sorted and rendered in order of depth by ‘set pm3d depthorder‘. As with pm3d surfaces, two-sided coloring can be generated by specifying the object fillcolor as a linestyle. In this case the ordering of the first three vertices in the polygon determines the "side".

If you set this property for an object that is not a 3D polygon it probably will not be drawn at all.

3.29.62 offsets

Autoscaling sets the x and y axis ranges to match the coordinates of the data that is plotted. Offsets provide a mechanism to expand these ranges to leave empty space between the data and the plot borders. Autoscaling then further extends each range to reach the next axis tic unless this has been suppressed by noextend or noextend. See noextend. Offsets affect only scaling for the x1 and y1 axes.


      set offsets <left>, <right>, <top>, <bottom>
      unset offsets
      show offsets

Each offset may be a constant or an expression. Each defaults to 0. By default, the left and right offsets are given in units of the first x axis, the top and bottom offsets in units of the first y axis. Alternatively, you may specify the offsets as a fraction of the total graph dimension by using the keyword "graph". Only "graph" offsets are possible for nonlinear axes.

A positive offset expands the axis range in the specified direction, e.g. a positive bottom offset makes ymin more negative. Negative offsets interact badly with autoscaling and clipping.


      set autoscale noextend
      set offsets graph 0.05, 0, 2, 2
      plot sin(x)

This graph of sin(x) will have y range [-3:3] because the function will be autoscaled to [-1:1] and the vertical offsets add 2 at each end of the range. The x range will be [-11:10] because the default is [-10:10] and it has been expanded to the left by 0.05 of that total range.

3.29.63 origin

The origin command is used to specify the origin of a plotting surface (i.e., the graph and its margins) on the screen. The coordinates are given in the ‘screen‘ coordinate system (see ‘coordinates‘ for information about this system).


      set origin <x-origin>,<y-origin>

3.29.64 output

By default, screens are displayed to the standard output. The output command redirects the display to the specified file or device.


      set output {"<filename>"}
      show output

The filename must be enclosed in quotes. If the filename is omitted, any output file opened by a previous invocation of output will be closed and new output will be sent to STDOUT. (If you give the command ‘set output "STDOUT"‘, your output may be sent to a file named "STDOUT"! ["May be", not "will be", because some terminals, like ‘x11‘ or ‘wxt‘, ignore output.])

When both terminal and output are used together, it is safest to give terminal first, because some terminals set a flag which is needed in some operating systems. This would be the case, for example, if the operating system needs a separate open command for binary files.

On platforms that support pipes, it may be useful to pipe terminal output. For instance,

      set output "|lpr -Plaser filename"
      set term png; set output "|display png:-"

On MSDOS machines, ‘set output "PRN"‘ will direct the output to the default printer. On VMS, output can be sent directly to any spooled device.

3.29.65 overflow


     set overflow {float | NaN | undefined}
     unset overflow

This version of gnuplot supports 64-bit integer arithmetic. This means that for values from 2^53 to 2^63 (roughly 10^16 to 10^19) integer evaluation preserves more precision than evaluation using IEEE 754 floating point arithmetic. However unlike the IEEE floating point representation, which sacrifices precision to span a total range of roughly [-10^307 : 10^307], integer operations that result in values outside the range [-2^63 : 2^63] overflow. The overflow command lets you control what happens in case of overflow. See options below.

overflow is the same as float. It causes the result to be returned as a real number rather than as an integer. This is the default.

The command overflow causes integer arithmetic overflow to be ignored. No error is shown. This may be desirable if your platform allows only 32-bit integer arithmetic and you want to approximate the behaviour of gnuplot versions prior to 5.4.

The reset command does not affect the state of overflow handling.

Earlier gnuplot versions were limited to 32-bit arithmetic and ignored integer overflow. Note, however, that some built-in operators did not use integer arithmetic at all, even when given integer arguments. This included the exponentiation operator N**M and the summation operator (see ‘summation‘). These operations now return an integer value when given integer arguments, making them potentially susceptible to overflow and thus affected by the state of overflow. float

If an integer arithmetic expression overflows the limiting range, [-2^63 : 2^63] for 64-bit integers, the result is returned as a floating point value instead. This is not treated as an error. Example:

     gnuplot> set overflow float
     gnuplot> A = 2**62 - 1;  print A, A+A, A+A+A
     4611686018427387903 9223372036854775806 1.38350580552822e+19 NaN

If an integer arithmetic expression overflows the limiting range, [-2^63 : 2^63] for 64-bit integers, the result is returned as NaN (Not a Number). This is not treated as an error. Example:

     gnuplot> set overflow NaN
     gnuplot> print 10**18, 10**19
     1000000000000000000 NaN undefined

If an integer arithmetic expression overflows the limiting range, [-2^63 : 2^63] for 64-bit integers, the result is undefined. This is treated as an error. Example:

     gnuplot> set overflow undefined
     gnuplot> A = 10**19
              undefined value affected operations

The overflow state affects the arithmetic operators

     + - * / **

and the built-in summation operation ‘sum‘.

All of these operations will return an integer result if all of the arguments are integers, so long as no overflow occurs during evaluation.

The overflow state does not affect logical or bit operations

     << >>  | ^ &

If overflow occurs at any point during the course of evaluating of a summation float will cause the result to be returned as a real number even if the final sum is within the range of integer representation.

3.29.66 palette

The palette is a set of colors, usually ordered in the form of one or more stepped gradients, used for pm3d surfaces and other graph elements colored by z value. Colors in the current palette are automatically mapped from plot coordinates z values or an extra data column of gray values. Palette colors also can be accessed explicitly in a color specification (see colorspec)

  • as a value also known as ‘palette fraction‘ in the range [0:1]
  • as a value corresponding to the z coordinate of a plot element
  • as a value in the range [cbmin:cbmax] (see cbrange)

The current palette is shown by default in a separate ‘colorbox‘ drawn next to plots that use plot style pm3d. The colorbox can be manually selected or disabled. See ‘set colorbox‘.


      set palette
      set palette {
                 { gray | color }
                 { gamma <gamma> }
                 {   rgbformulae <r>,<g>,<b>
                   | defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }
                   | file '<filename>' {datafile-modifiers}
                   | functions <R>,<G>,<B>
                 { cubehelix {start <val>} {cycles <val>} {saturation <val>} }
                 { model { RGB | HSV | CMY } }
                 { positive | negative }
                 { nops_allcF | ps_allcF }
                 { maxcolors <maxcolors> }
      show palette
      show palette palette <n> {{float | int}}
      show palette gradient
      show palette fit2rgbformulae
      show palette rgbformulae
      show colornames

palette (i.e. without options) sets up the default values. Otherwise, the options can be given in any order. palette shows the current palette properties.

‘show palette gradient‘ displays the gradient defining the palette (if appropriate). rgbformulae prints the available fixed gray –> color transformation formulae. colornames prints the known color names.

‘show palette palette <n>‘ prints to the screen or to the file given by ‘set print‘ a table of RGB triplets calculated for the current palette settings and a palette having <n> discrete colors. The default wide table can be limited to 3 columns of r,g,b float values [0..1] or integer values [0..255] by options float or int, respectively. This way, the current gnuplot color palette can be loaded into other imaging applications, for example Octave. Alternatively, the palette command will plot the R,G,B profiles for the current palette and leave the profile values in a datablock $PALETTE.

The following options determine the coloring properties.

Figure using this palette can be gray or ‘color‘. For instance, in pm3d color surfaces the gray of each small spot is obtained by mapping the averaged z-coordinate of the 4 corners of surface quadrangles into the range [min_z,max_z] providing range of grays [0:1]. This value can be used directly as the gray for gray maps. The color map requires a transformation gray –> (R,G,B), i.e. a mapping [0:1] –> ([0:1],[0:1],[0:1]).

Basically two different types of mappings can be used: Analytic formulae to convert gray to color, or discrete mapping tables which are interpolated. rgbformulae and functions use analytic formulae whereas defined and ‘palette file‘ use interpolated tables. rgbformulae reduces the size of postscript output to a minimum.

The command ‘show palette fit2rgbformulae‘ finds the best matching rgbformulae for the current palette. Naturally, it makes sense to use it for non-rgbformulae palettes. This command can be found useful mainly for external programs using the same rgbformulae definition of palettes as gnuplot, like zimg ( ).

gray switches to a gray only palette. rgbformulae, defined, ‘set palette file‘ and functions switch to a color mapping. ‘set palette color‘ is an easy way to switch back from the gray palette to the last color mapping.

Automatic gamma correction via ‘set palette gamma <gamma>‘ can be done for gray maps (gray) and for the cubehelix color palette schemes. Gamma = 1 produces a linear ramp of intensity. See palette.

Many terminals support only discrete number of colors (e.g. 256 colors in gif). After the default gnuplot linetype colors are allocated, the rest of the available colors are by default reserved for pm3d. Thus a multiplot using multiple palettes could fail because the first palette has used all the available color positions. You can mitigate this limitation by using ‘set palette maxcolors <N>‘ with a reasonably small value of N. This option causes N discrete colors to be selected from a continuous palette sampled at equally spaced intervals. If you want unequal spacing of N discrete colors, use defined instead of a single continuous palette.

RGB color space might not be the most useful color space to work in. For that reason you may change the color space ‘model‘ to one of ‘RGB‘, ‘HSV‘, ‘CMY‘. Using color names for defined tables and a color space other than RGB will result in funny colors. All explanation have been written for RGB color space, so please note, that ‘R‘ can be ‘H‘, or ‘C‘, depending on the actual color space (‘G‘ and ‘B‘ accordingly).

All values for all color spaces are limited to [0,1].

RGB stands for Red, Green, Blue; CMY stands for Cyan, Magenta, Yellow; HSV stands for Hue, Saturation, Value. For more information on color models see: Note: Earlier gnuplot versions accepted YIQ and XYZ color space models also, but the implementation was never complete or correct. rgbformulae

For rgbformulae three suitable mapping functions have to be chosen. This is done via ‘rgbformulae <r>,<g>,<b>‘. The available mapping functions are listed by rgbformulae. Default is ‘7,5,15‘, some other examples are ‘3,11,6‘, ‘21,23,3‘ or ‘3,23,21‘. Negative numbers, like ‘3,-11,-6‘, mean inverted color (i.e. 1-gray passed into the formula, see also ‘positive‘ and ‘negative‘ options below).

Some nice schemes in RGB color space

   7,5,15   ... traditional pm3d (black-blue-red-yellow)
   3,11,6   ... green-red-violet
   23,28,3  ... ocean (green-blue-white); try also all other permutations
   21,22,23 ... hot (black-red-yellow-white)
   30,31,32 ... color printable on gray (black-blue-violet-yellow-white)
   33,13,10 ... rainbow (blue-green-yellow-red)
   34,35,36 ... AFM hot (black-red-yellow-white)

A full color palette in HSV color space

   3,2,2    ... red-yellow-green-cyan-blue-magenta-red

Please note that even if called rgbformulae the formulas might actually determine the <H>,<S>,<V> or <X>,<Y>,<Z> or ... color components as usual.

Use ‘positive‘ and ‘negative‘ to invert the figure colors.

Note that it is possible to find a set of the best matching rgbformulae for any other color scheme by the command

   show palette fit2rgbformulae defined

Gray-to-rgb mapping can be manually set by use of defined: A color gradient is defined and used to give the rgb values. Such a gradient is a piecewise linear mapping from gray values in [0,1] to the RGB space [0,1]x[0,1]x[0,1]. You must specify the gray values and the corresponding RGB values between which linear interpolation will be done.


      set palette  defined { ( <gray1> <color1> {, <grayN> <colorN>}... ) }

<grayX> are gray values which are mapped to [0,1] and <colorX> are the corresponding rgb colors. The color can be specified in three different ways:

     <color> :=  { <r> <g> <b> | '<color-name>' | '#rrggbb' }

Either by three numbers (each in [0,1]) for red, green and blue, separated by whitespace, or the name of the color in quotes or X style color specifiers also in quotes. You may freely mix the three types in a gradient definition, but the named color "red" will be something strange if RGB is not selected as color space. Use colornames for a list of known color names.

Please note, that even if written as <r>, this might actually be the <H> component in HSV color space depending on the selected color model.

The <gray> values have to form an ascending sequence of real numbers; the sequence will be automatically rescaled to [0,1].

defined (without a gradient definition in braces) switches to RGB color space and uses a preset full-spectrum color gradient. Use ‘show palette gradient‘ to display the gradient.


To produce a gray palette (useless but instructive) use:

      set palette model RGB
      set palette defined ( 0 "black", 1 "white" )

To produce a blue yellow red palette use (all equivalent):

      set palette defined ( 0 "blue", 1 "yellow", 2 "red" )
      set palette defined ( 0 0 0 1, 1 1 1 0, 2 1 0 0 )
      set palette defined ( 0 "#0000ff", 1 "#ffff00", 2 "#ff0000" )

To produce some rainbow-like palette use:

      set palette defined ( 0 "blue", 3 "green", 6 "yellow", 10 "red" )

Full color spectrum within HSV color space:

      set palette model HSV
      set palette defined ( 0 0 1 1, 1 1 1 1 )
      set palette defined ( 0 0 1 0, 1 0 1 1, 6 0.8333 1 1, 7 0.8333 0 1)

Approximate the default palette used by MATLAB:

      set pal defined (1 '#00008f', 8 '#0000ff', 24 '#00ffff', \
                       40 '#ffff00', 56 '#ff0000', 64 '#800000')

To produce a palette with only a few, equally-spaced colors:

      set palette model RGB maxcolors 4
      set palette defined ( 0 "yellow", 1 "red" )

’Traffic light’ palette (non-smooth color jumps at gray = 1/3 and 2/3).

      set palette model RGB
      set palette defined (0 "dark-green", 1 "green", \
                           1 "yellow",     2 "dark-yellow", \
                           2 "red",        3 "dark-red" ) functions

Use ‘set palette functions <Rexpr>, <Gexpr>, <Bexpr>‘ to define three formulae for the R(gray), G(gray) and B(gray) mapping. The three formulae may depend on the variable gray which will take values in [0,1] and should also produce values in [0,1]. Please note that <Rexpr> might be a formula for the H-value if HSV color space has been chosen (same for all other formulae and color spaces).


To produce a full color palette use:

      set palette model HSV functions gray, 1, 1

A nice black to gold palette:

      set palette model RGB functions 1.1*gray**0.25, gray**0.75, 0

A gamma-corrected black and white palette

      gamma = 2.2
      color(gray) = gray**(1./gamma)
      set palette model RGB functions color(gray), color(gray), color(gray) gray

gray switches to a grayscale palette shading from 0.0 = black to 1.0 = white. ‘set palette color‘ is an easy way to switch back from the gray palette to the last color mapping. cubehelix

The "cubehelix" option defines a family of palettes in which color (hue) varies along the standard color wheel while at the same time the net intensity increases monotonically as the gray value goes from 0 to 1.

      D A Green (2011)

‘start‘ defines the starting point along the color wheel in radians. ‘cycles‘ defines how many color wheel cycles span the palette range. Larger values of ‘saturation‘ produce more saturated color; saturation > 1 may lead to clipping of the individual RGB components and to intensity becoming non-monotonic. The palette is also affected by ‘set palette gamma‘. The default values are

      set palette cubehelix start 0.5 cycles -1.5 saturation 1
      set palette gamma 1.5 file

‘set palette file‘ is basically a ‘set palette defined (<gradient>)‘ where <gradient> is read from a datafile. Either 4 columns (gray,R,G,B) or just three columns (R,G,B) have to be selected via the ‘using‘ data file modifier. In the three column case, the line number will be used as gray. The gray range is automatically rescaled to [0,1]. The file is read as a normal data file, so all datafile modifiers can be used. Please note, that ‘R‘ might actually be e.g. ‘H‘ if HSV color space is selected.

As usual <filename> may be ‘’-’‘ which means that the data follow the command inline and are terminated by a single ‘e‘ on a line of its own.

Use ‘show palette gradient‘ to display the gradient.


Read in a palette of RGB triples each in range [0,255]:

      set palette file 'some-palette' using ($1/255):($2/255):($3/255)

Equidistant rainbow (blue-green-yellow-red) palette:

      set palette model RGB file "-"
      0 0 1
      0 1 0
      1 1 0
      1 0 0

Binary palette files are supported as well, see general. Example: put 64 triplets of R,G,B doubles into file palette.bin and load it by

      set palette file "palette.bin" binary record=64 using 1:2:3 gamma correction

For gray mappings gamma correction can be turned on by ‘set palette gamma <gamma>‘. <gamma> defaults to 1.5 which is quite suitable for most terminals.

The gamma correction is applied to the cubehelix color palette family, but not to other palette coloring schemes. However, you may easily implement gamma correction for explicit color functions.


      set palette model RGB
      set palette functions gray**0.64, gray**0.67, gray**0.70

To use gamma correction with interpolated gradients specify intermediate gray values with appropriate colors. Instead of

      set palette defined ( 0 0 0 0, 1 1 1 1 )

use e.g.

      set palette defined ( 0 0 0 0, 0.5 .73 .73 .73, 1 1 1 1 )

or even more intermediate points until the linear interpolation fits the "gamma corrected" interpolation well enough. postscript

In order to reduce the size of postscript files, the gray value and not all three calculated r,g,b values are written to the file. Therefore the analytical formulae are coded directly in the postscript language as a header just before the pm3d drawing, see /g and /cF definitions. Usually, it makes sense to write therein definitions of only the 3 formulae used. But for multiplot or any other reason you may want to manually edit the transformations directly in the postscript file. This is the default option ‘nops_allcF‘. Using the option ‘ps_allcF‘ writes postscript definitions of all formulae. This you may find interesting if you want to edit the postscript file in order to have different palettes for different surfaces in one graph. Well, you can achieve this functionality by multiplot with fixed origin and size.

If you are writing a pm3d surface to a postscript file, it may be possible to reduce the file size by up to 50% by the enclosed awk script ‘pm3dCompress.awk‘. If the data lies on a rectangular grid, even greater compression may be possible using the script ‘pm3dConvertToImage.awk‘. Usage:

    awk -f pm3dCompress.awk >
    awk -f pm3dConvertToImage.awk >

3.29.67 parametric

The parametric command changes the meaning of ‘plot‘ (‘splot‘) from normal functions to parametric functions. The command parametric restores the plotting style to normal, single-valued expression plotting.


      set parametric
      unset parametric
      show parametric

For 2D plotting, a parametric function is determined by a pair of parametric functions operating on a parameter. An example of a 2D parametric function would be ‘plot sin(t),cos(t)‘, which draws a circle (if the aspect ratio is set correctly—see size). ‘gnuplot‘ will display an error message if both functions are not provided for a parametric ‘plot‘.

For 3D plotting, the surface is described as x=f(u,v), y=g(u,v), z=h(u,v). Therefore a triplet of functions is required. An example of a 3D parametric function would be ‘cos(u)*cos(v),cos(u)*sin(v),sin(u)‘, which draws a sphere. ‘gnuplot‘ will display an error message if all three functions are not provided for a parametric ‘splot‘.

The total set of possible plots is a superset of the simple f(x) style plots, since the two functions can describe the x and y values to be computed separately. In fact, plots of the type t,f(t) are equivalent to those produced with f(x) because the x values are computed using the identity function. Similarly, 3D plots of the type u,v,f(u,v) are equivalent to f(x,y).

Note that the order the parametric functions are specified is xfunction, yfunction (and zfunction) and that each operates over the common parametric domain.

Also, the parametric function implies a new range of values. Whereas the normal f(x) and f(x,y) style plotting assume an xrange and yrange (and zrange), the parametric mode additionally specifies a trange, urange, and vrange. These ranges may be set directly with trange, urange, and vrange, or by specifying the range on the ‘plot‘ or ‘splot‘ commands. Currently the default range for these parametric variables is [-5:5]. Setting the ranges to something more meaningful is expected.

3.29.68 paxis


      set paxis <axisno> {range <range-options> | tics <tic-options>}
      set paxis <axisno> label <label-options> { offset <radial-offset> }
      show paxis <axisno> {range | tics}

The paxis command is equivalent to the xrange and ‘set xtics‘ commands except that it acts on one of the axes p1, p2, ... used in parallel axis plots and spiderplots. See parallelaxes, xrange, and ‘set xtics‘. The normal options to the range and tics commands are accepted although not all options make sense for parallel axis plots.

‘set paxis <axisno> label <label-options>‘ is relevant to spiderplots but ignored otherwise. Axes of a parallel axis plot can be labeled using the title option of the plot command, which generates an xtic label. Note that this may require also ‘set xtics‘.

The axis linetype properties are controlled using ‘set style parallelaxis‘.

3.29.69 pixmap


      set pixmap <index> "filename" at <position>
                 {width <w> | height <h> | size <w>,<h>}
                 {front|back|behind} {center}
      show pixmaps
      unset pixmaps
      unset pixmap <index>

The pixmap command is similar to object in that it defines an object that will appear on subsequent plots. The rectangular array of red/green/blue/alpha values making up the pixmap are read from a png, jpeg, or gif file. The position and extent occupied by the pixmap in the gnuplot output may be specified in any coordinate system (see ‘coordinates‘). The coordinates given by ‘at <position>‘ refer to the lower left corner of the pixmap unless keyword ‘center‘ is present.

If the x-extent of the rendered pixmap is set using ‘width <x-extent>‘ the aspect ratio of the original image is retained and neither the aspect ratio nor the orientation of the pixmap changes with axis scaling or rotation. Similarly if the y-extent is set using ‘height <y-extent>‘. If both the x-extent and y-extent are given using ‘size <x-extent> <y-extent>‘ this overrides the original aspect ratio. If no size is set then the original size in pixels is used (the effective size is then terminal-dependent).

Pixmaps are not clipped to the border of the plot. As an exception to the general behaviour of objects and layers, a pixmap assigned to layer ‘behind‘ is rendered for only the first plot in a multiplot. This allows all panels in a multiplot to share a single background pixmap.


      # Use a gradient as the background for all plotting
      # Both x and y will be resized to fill the entire canvas
      set pixmap 1 "gradient.png"
      set pixmap 1 at screen 0, 0 size screen 1, 1 behind

      # Place a logo at the lower right of each page plotted
      set pixmap 2 "logo.jpg"
      set pixmap 2 at screen 0.95, 0 width screen 0.05 behind

      # Place a small image at some 3D coordinate
      # It will move as if attached to the surface being plotted
      # but will always face forward and remain upright
      set pixmap 3 "image.png" at my_x, my_y, f(my_x,my_y) width screen .05
      splot f(x,y)

3.29.70 plot

The ‘show plot‘ command shows the current plotting command as it results from the last ‘plot‘ and/or ‘splot‘ and possible subsequent replot commands.

In addition, the ‘show plot add2history‘ command adds this current plot command into the ‘history‘. It is useful if you have used replot to add more curves to the current plot and you want to edit the whole command now.

3.29.71 pm3d

pm3d is an ‘splot‘ style for drawing palette-mapped 3d and 4d data as color/gray maps and surfaces. It allows plotting gridded or non-gridded data without preprocessing. pm3d style options also affect solid-fill polygons used to construct other 3D plot elements.

Syntax (the options can be given in any order):

      set pm3d {
                 { at <position> }
                 { interpolate <steps/points in scan, between scans> }
                 { scansautomatic | scansforward | scansbackward
                                  | depthorder {base} }
                 { flush { begin | center | end } }
                 { ftriangles | noftriangles }
                 { clip {z} | clip1in | clip4in }
                 { {no}clipcb }
                 { corners2color
                   { mean|geomean|harmean|rms|median|min|max|c1|c2|c3|c4 }
                 { {no}lighting
                   {primary <fraction>} {specular <fraction>} {spec2 <fraction>}
                 { {no}border {retrace} {<linestyle-options>}}
                 { implicit | explicit }
                 { map }
      show pm3d
      unset pm3d

Note that pm3d plots are plotted sequentially in the order given in the splot command. Thus earlier plots may be obscured by later plots. To avoid this you can use the ‘depthorder‘ scan option.

The pm3d surfaces can be projected onto the ‘top‘ or ‘bottom‘ of the view box. See position. The following command draws three color surfaces at different altitudes:

      set border 4095
      set pm3d at s
      splot 10*x with pm3d at b, x*x-y*y, x*x+y*y with pm3d at t

See also help for palette, cbrange, ‘set colorbox‘, and the demo file ‘demo/pm3d.dem‘. implicit

A pm3d color surface is drawn if the splot command specifies pm3d, if the data or function style is set to pm3d globally, or if the pm3d mode is implicit. In the latter two cases, the pm3d surface is draw in addition to the mesh produced by the style specified in the plot command. E.g.

      splot 'fred.dat' with lines, 'lola.dat' with lines

would draw both a mesh of lines and a pm3d surface for each data set. If the option ‘explicit‘ is on (or implicit is off) only plots specified by the pm3d attribute are plotted with a pm3d surface, e.g.:

      splot 'fred.dat' with lines, 'lola.dat' with pm3d

would plot ’fred.dat’ with lines (only) and ’lola.dat’ with a pm3d surface.

On gnuplot start-up, the mode is ‘explicit‘. For historical and compatibility reasons, the commands ‘set pm3d;‘ (i.e. no options) and ‘set pm3d at X ...‘ (i.e. ‘at‘ is the first option) change the mode to implicit. The command ‘set pm3d;‘ sets other options to their default state.

If you set the default data or function style to pm3d, e.g.:

      set style data pm3d

then the options implicit and ‘explicit‘ have no effect. algorithm

Let us first describe how a map/surface is drawn. The input data come from an evaluated function or from an ‘splot data file‘. Each surface consists of a sequence of separate scans (isolines). The pm3d algorithm fills the region between two neighbouring points in one scan with another two points in the next scan by a gray (or color) according to z-values (or according to an additional ’color’ column, see help for ‘using‘) of these 4 corners; by default the 4 corner values are averaged, but this can be changed by the option corners2color. In order to get a reasonable surface, the neighbouring scans should not cross and the number of points in the neighbouring scans should not differ too much; of course, the best plot is with scans having same number of points. There are no other requirements (e.g. the data need not be gridded). Another advantage is that the pm3d algorithm does not draw anything outside of the input (measured or calculated) region.

Surface coloring works with the following input data:

1. splot of function or of data file with one or three data columns: The gray/color scale is obtained by mapping the averaged (or corners2color) z-coordinate of the four corners of the above-specified quadrangle into the range [min_color_z,max_color_z] of zrange or cbrange providing a gray value in the range [0:1]. This value can be used directly as the gray for gray maps. The normalized gray value can be further mapped into a color—see palette for the complete description.

2. splot of data file with two or four data columns: The gray/color value is obtained by using the last-column coordinate instead of the z-value, thus allowing the color and the z-coordinate be mutually independent. This can be used for 4d data drawing.

Other notes:

1. The term ’scan’ referenced above is used more among physicists than the term ’iso_curve’ referenced in gnuplot documentation and sources. You measure maps recorded one scan after another scan, that’s why.

2. The ’gray’ or ’color’ scale is a linear mapping of a continuous variable onto a smoothly varying palette of colors. The mapping is shown in a rectangle next to the main plot. This documentation refers to this as a "colorbox", and refers to the indexing variable as lying on the colorbox axis. See ‘set colorbox‘, cbrange. lighting

By default the colors assigned to pm3d objects are not dependent on orientation or viewing angle. This state corresponds to ‘set pm3d nolighting‘. The command lighting selects a simple lighting model consisting of a single fixed source of illumination contributing 50% of the overall lighting. The strength of this light relative to the ambient illumination can be adjusted by ‘set pm3d lighting primary <fraction>‘. Inclusion of specular highlighting can be adjusted by setting a fractional contribution:

     set pm3d lighting primary 0.50 specular 0.0   # no highlights
     set pm3d lighting primary 0.50 specular 0.6   # strong highlights

Solid-color pm3d surfaces tend to look very flat without specular highlights. Since the highlights from a single source only affect one side of the surface, a second spotlight source may be desirable to add specular highlights from the opposite direction. This is controlled by "spec2 <contribution>". EXPERIMENTAL (details may change in a future version): The second spotlight is a pure red light source that by default contributes nothing (spec2 0.0). See also hidden_compare.dem (comparison of hidden3d and pm3d treatment of solid-color surfaces) position

Color surface can be drawn at the base or top (then it is a gray/color planar map) or at z-coordinates of surface points (gray/color surface). This is defined by the ‘at‘ option with a string of up to 6 combinations of ‘b‘, ‘t‘ and ‘s‘. For instance, ‘at b‘ plots at bottom only, ‘at st‘ plots firstly surface and then top map, while ‘at bstbst‘ will never by seriously used.

Colored quadrangles are plotted one after another. When plotting surfaces (‘at s‘), the later quadrangles overlap (overdraw) the previous ones. (Gnuplot is not virtual reality tool to calculate intersections of filled polygon meshes.) You may try to switch between ‘scansforward‘ and ‘scansbackward‘ to force the first scan of the data to be plotted first or last. The default is ‘scansautomatic‘ where gnuplot makes a guess about scans order. On the other hand, the ‘depthorder‘ option completely reorders the quadrangles. The rendering is performed after a depth sorting, which allows to visualize even complicated surfaces; see ‘pm3d depthorder‘ for more details. scanorder

     set pm3d {scansautomatic | scansforward | scansbackward | depthorder}

By default the quadrangles making up a pm3d solid surface are rendered in the order they are encountered along the surface grid points. This order may be controlled by the options ‘scansautomatic‘|‘scansforward‘|‘scansbackward‘. These scan options are not in general compatible with hidden-surface removal.

If two successive scans do not have same number of points, then it has to be decided whether to start taking points for quadrangles from the beginning of both scans (‘flush begin‘), from their ends (‘flush end‘) or to center them (‘flush center‘). Note, that ‘flush (center|end)‘ are incompatible with ‘scansautomatic‘: if you specify ‘flush center‘ or ‘flush end‘ and ‘scansautomatic‘ is set, it is silently switched to ‘scansforward‘.

If two subsequent scans do not have the same number of points, the option ‘ftriangles‘ specifies whether color triangles are drawn at the scan tail(s) where there are not enough points in either of the scans. This can be used to draw a smooth map boundary.

Gnuplot does not do true hidden surface removal for solid surfaces, but often it is sufficient to render the component quadrangles in order from furthest to closest. This mode may be selected using the option

      set pm3d depthorder

Note that the global option hidden3d does not affect pm3d surfaces.

The ‘depthorder‘ option by itself tends to produce bad results when applied to the long thin rectangles generated by boxes. It works better to add the keyword ‘base‘, which performs the depth sort using the intersection of the box with the plane at z=0. This type of plot is further improved by adding a lighing model. Example:

     set pm3d depthorder base
     set pm3d lighting
     set boxdepth 0.4
     splot $DATA using 1:2:3 with boxes clipping


     set pm3d {clip {z} | clip1in | clip4in}
     set pm3d {no}clipcb

The component quadrangles of a pm3d surface or other 3D object are by default smoothly clipped against the current zrange. This is a change from earlier gnuplot versions.

Alternatively, surfaces can be clipped by rendering whole quadrangles but only those with all 4 corners in-range on x, y, and z (‘set pm3d clip4in‘), or only those with at least one corner in-range on x, y, and z (‘set pm3d clip1in‘). The options ‘clip‘, ‘clip1in‘, and ‘clip4in‘ are mutually exclusive.

Separate from clipping based on spatial x, y, and z coordinates, quadrangles can be rendered or not based on extreme palette color values. ‘clipcb‘: (default) palette color values < cbmin are clipped to equal cbmin; palette color values > cbmax are clipped to equal cbmax. ‘noclipcb‘: quadrangles with color value outside cbrange are not drawn at all. color_assignment

The default pm3d coloring assigns an individual color to each quadrangle of the surface grid. For alternative coloring schemes that assign uniform color to the entire surface, see fillcolor.

A single gray/color value (i.e. not a gradient) is assigned to each quadrangle. This value is calculated from the z-coordinates the four quadrangle corners according to ‘corners2color <option>‘. The value is then used to select a color from the current palette. See palette. It is not possible to change palettes inside a single ‘splot‘ command.

If a fourth column of data is provided, the coloring of individual quadrangles works as above except that the color value is distinct from the z value. As a separate coloring option, the fourth data column may provide instead an RGB color. See ‘rgbcolor variable‘. In this case the plotting command must be

      splot ... using 1:2:3:4 with pm3d lc rgb variable

Notice that ranges of z-values and color-values for surfaces are adjustable independently by zrange, cbrange, ‘set log z‘, ‘set log cb‘, etc. corners2color

The color of each quadrangle in a pm3d surface is assigned based on the color values of its four bounding vertices. The options ’mean’ (default), ’geomean’, ’harmean, ’rms’, and ’median’ produce various kinds of surface color smoothing, while options ’min’ and ’max’ choose minimal or maximal value, respectively. This may not be desired for pixel images or for maps with sharp and intense peaks, in which case the options ’c1’, ’c2’, ’c3’ or ’c4’ can be used instead to assign the quadrangle color based on the z-coordinate of only one corner. Some experimentation may be needed to determine which corner corresponds to ’c1’, as the orientation depends on the drawing direction. Because the pm3d algorithm does not extend the colored surface outside the range of the input data points, the ’c<j>’ coloring options will result in pixels along two edges of the grid not contributing to the color of any quadrangle. For example, applying the pm3d algorithm to the 4x4 grid of data points in script ‘demo/pm3d.dem‘ (please have a look) produces only (4-1)x(4-1)=9 colored rectangles. border

     set pm3d border {retrace} {line-properties}
     set pm3d noborder

This option draws bounding lines around each pm3d quadrangle as it is rendered. Additional line properties (linetype, color, linewidth) are optional. By default the border is drawn as a solid black line with width 1.

‘set pm3d border retrace‘ causes a border to be drawn in the same color as the quadrangle. In principle this should give the same result as ‘noborder‘, but some output modes can suffer from antialiasing artifacts between adjacent filled quadrangles. Retracing the border hides these artifacts, at the cost of a larger output file. fillcolor

     splot FOO with pm3d fillcolor <colorspec>

Plot style pm3d accepts an optional fillcolor in the splot command. This specification is applied to the entire pm3d surface. See colorspec. Most fillcolor specifications will result in a single solid color, which is hard to interpret visually unless there is also a lighting model present to distinguish surface components based on orientation. See lighting.

There are a few special cases. palette would produce the same result as the default pm3d palette-based coloring, and is therefore not a useful option. ‘with pm3d fillcolor linestyle N‘ is more interesting. This variant assigns distinct colors to the top and bottom of the pm3d surface, similar to the color scheme used by gnuplot’s hidden3d mode. Linestyle N is used for the top surface; linestyle N+1 for the bottom surface. Note that "top" and "bottom" depend on the scan order, so that the colors are inverted for ‘pm3d scansbackward‘ as compared to ‘pm3d scansforward‘. This coloring option works best with ‘pm3d depthorder‘, however, which unfortunately does not allow you to control the scan order so you may have to instead swap the colors defined for linestyles N and N+1. interpolate

The option ‘interpolate m,n‘ will interpolate between grid points to generate a finer mesh. For data files, this smooths the color surface and enhances the contrast of spikes in the surface. When working with functions, interpolation makes little sense. It would usually make more sense to increase samples and isosamples.

For positive m and n, each quadrangle or triangle is interpolated m-times and n-times in the respective direction. For negative m and n, the interpolation frequency is chosen so that there will be at least |m| and |n| points drawn; you can consider this as a special gridding function.

Note: ‘interpolate 0,0‘, will automatically choose an optimal number of interpolated surface points.

Note: Currently color interpolation is always linear, even if corners2color is set to a nonlinear scheme such as the geometric mean. deprecated_options

The deprecated option ‘set pm3d map‘ was equivalent to ‘set pm3d at b; set view map; set style data pm3d; set style func pm3d;‘

The deprecated option ‘set pm3d hidden3d N‘ was equivalent to ‘set pm3d border ls N‘.

3.29.72 pointintervalbox

The ‘pointinterval‘ and ‘pointnumber‘ properties of a line type are used only in plot style linespoints. A negative value of pointinterval or pointnumber, e.g. -N, means that before the selected set of point symbols are drawn a box (actually circle) behind each point symbol is blanked out by filling with the background color. The command pointintervalbox controls the radius of this blanked-out region. It is a multiplier for the default radius, which is equal to the point size.

3.29.73 pointsize

The pointsize command scales the size of the points used in plots.


      set pointsize <multiplier>
      show pointsize

The default is a multiplier of 1.0. Larger pointsizes may be useful to make points more visible in bitmapped graphics.

The pointsize of a single plot may be changed on the ‘plot‘ command. See with for details.

Please note that the pointsize setting is not supported by all terminal types.

3.29.74 polar

The ‘set polar‘ command changes the meaning of the plot from rectangular coordinates to polar coordinates.


      set polar
      unset polar
      show polar

In polar coordinates, the dummy variable (t) represents an angle theta. The default range of t is [0:2*pi], or [0:360] if degree units have been selected (see angles).

The command ‘unset polar‘ changes the meaning of the plot back to the default rectangular coordinate system.

The ‘set polar‘ command is not supported for ‘splot‘s. See the mapping command for similar functionality for ‘splot‘s.

While in polar coordinates the meaning of an expression in t is really r = f(t), where t is an angle of rotation. The trange controls the domain (the angle) of the function. The r, x and y ranges control the extent of the graph in the x and y directions. Each of these ranges, as well as the rrange, may be autoscaled or set explicitly. For details, see rrange and xrange.


      set polar
      plot t*sin(t)
      set trange [-2*pi:2*pi]
      set rrange [0:3]
      plot t*sin(t)

The first ‘plot‘ uses the default polar angular domain of 0 to 2*pi. The radius and the size of the graph are scaled automatically. The second ‘plot‘ expands the domain, and restricts the size of the graph to the area within 3 units of the origin. This has the effect of limiting x and y to [-3:3].

By default polar plots are oriented such that theta=0 is at the far right, with theta increasing counterclockwise. You can change both the origin and the sense explicitly. See theta.

You may want to ‘set size square‘ to have ‘gnuplot‘ try to make the aspect ratio equal to unity, so that circles look circular. Tic marks around the perimeter can be specified using ttics. See also polar demos (polar.dem) and polar data plot (poldat.dem).

3.29.76 psdir

The ‘set psdir <directory>‘ command controls the search path used by the postscript terminal to find and character encoding files. You can use this mechanism to switch between different sets of locally-customized prolog files. The search order is

      1) The directory specified by psdir, if any
      2) The directory specified by environmental variable GNUPLOT_PS_DIR
      3) A built-in header or one from the default system directory
      4) Directories set by loadpath

3.29.77 raxis

The commands raxis and raxis toggle whether the polar axis is drawn separately from grid lines and the x axis. If the minimum of the current rrange is non-zero (and not autoscaled), then a white circle is drawn at the center of the polar plot to indicate that the plot lines and axes do not reach 0. The axis line is drawn using the same line type as the plot border. See ‘polar‘, rrange, rtics, rlabel, ‘set grid‘.

3.29.78 rgbmax


     set rgbmax {1.0 | 255}
     unset rgbmax

The red/green/blue color components of an rgbimage plot are by default interpreted as integers in the range [0:255]. ‘set rgbmax 1.0‘ tells the program that data values used to generate the color components of a plot with rgbimage or rgbalpha are floating point values in the range [0:1]. rgbmax returns to the default integer range [0:255].

3.29.79 rlabel

This command places a label above the r axis. The label will be drawn whether or not the plot is in polar mode. See xlabel for additional keywords.

3.29.80 rmargin

The command rmargin sets the size of the right margin. Please see margin for details.

3.29.81 rrange

The rrange command sets the range of the radial coordinate for a graph in polar mode. This has the effect of setting both xrange and yrange as well. The resulting xrange and yrange are both [-(rmax-rmin) : +(rmax-rmin)]. However if you later change the x or y range, for example by zooming, this does not change rrange, so data points continue to be clipped against rrange. Unlike other axes, autoscaling the raxis always results in rmin = 0. The ‘reverse‘ autoscaling flag is ignored. Note: Setting a negative value for rmin may produce unexpected results.

3.29.82 rtics

The rtics command places tics along the polar axis. The tics and labels are drawn to the right of the origin. The ‘mirror‘ keyword causes them to be drawn also to the left of the origin. See ‘polar‘, ‘set xtics‘, and mxtics for discussion of keywords.

3.29.83 samples

The default sampling rate of functions, or for interpolating data, may be changed by the samples command. To change the sampling range for a particular plot, see sampling.


      set samples <samples_1> {,<samples_2>}
      show samples

By default, sampling is set to 100 points. A higher sampling rate will produce more accurate plots, but will take longer. This parameter has no effect on data file plotting unless one of the interpolation/approximation options is used. See smooth re 2D data and cntrparam and dgrid3d re 3D data.

When a 2D graph is being done, only the value of <samples_1> is relevant.

When a surface plot is being done without the removal of hidden lines, the value of samples specifies the number of samples that are to be evaluated for the isolines. Each iso-v line will have <sample_1> samples and each iso-u line will have <sample_2> samples. If you only specify <samples_1>, <samples_2> will be set to the same value as <samples_1>. See also isosamples.

3.29.84 size


      set size {{no}square | ratio <r> | noratio} {<xscale>,<yscale>}
      show size

The <xscale> and <yscale> values are scale factors for the size of the plot, which includes the graph, labels, and margins.

Important note:

      In earlier versions of gnuplot, some terminal types used the values from
      size to control also the size of the output canvas; others did not.
      Almost all terminals now follow the following convention:

‘set term <terminal_type> size <XX>, <YY>‘ controls the size of the output file, or ‘canvas‘. Please see individual terminal documentation for allowed values of the size parameters. By default, the plot will fill this canvas.

‘set size <XX>, <YY>‘ scales the plot itself relative to the size of the canvas. Scale values less than 1 will cause the plot to not fill the entire canvas. Scale values larger than 1 will cause only a portion of the plot to fit on the canvas. Please be aware that setting scale values larger than 1 may cause problems on some terminal types.

‘ratio‘ causes ‘gnuplot‘ to try to create a graph with an aspect ratio of <r> (the ratio of the y-axis length to the x-axis length) within the portion of the plot specified by <xscale> and <yscale>.

The meaning of a negative value for <r> is different. If <r>=-1, gnuplot tries to set the scales so that the unit has the same length on both the x and y axes. This is the 2D equivalent to the 3D command ‘set view equal xy‘. If <r>=-2, the unit on y has twice the length of the unit on x, and so on.

The success of ‘gnuplot‘ in producing the requested aspect ratio depends on the terminal selected. The graph area will be the largest rectangle of aspect ratio <r> that will fit into the specified portion of the output (leaving adequate margins, of course).

‘set size square‘ is a synonym for ‘set size ratio 1‘.

Both ‘noratio‘ and ‘nosquare‘ return the graph to the default aspect ratio of the terminal, but do not return <xscale> or <yscale> to their default values (1.0).

‘ratio‘ and ‘square‘ have no effect on 3D plots, but do affect 3D projections created using ‘set view map‘. See also ‘set view equal‘, which forces the x and y axes of a 3D onto the same scale.


To set the size so that the plot fills the available canvas:

      set size 1,1

To make the graph half size and square use:

      set size square 0.5,0.5

To make the graph twice as high as wide use:

      set size ratio 2

3.29.85 spiderplot

The spiderplot command switches interpretation of coordinates to a polar system in which each data point is mapped to a position along a radial axis. paxis 1 is always vertical; axes 2 to N proceed clockwise with even spacing. The command must be issued prior to plotting. It has additional effects equivalent to

     set style data spiderplot
     unset border
     unset tics
     set key noautotitle
     set size ratio 1.0

Use reset to restore these after plotting.

3.29.86 style

Default plotting styles are chosen with the ‘set style data‘ and ‘set style function‘ commands. See with for information about how to override the default plotting style for individual functions and data sets. See ‘plotting styles‘ or with for a complete list of styles.


      set style function <style>
      set style data <style>
      show style function
      show style data

Default styles for specific plotting elements may also be set.


      set style arrow <n> <arrowstyle>
      set style boxplot <boxplot style options>
      set style circle radius <size> {clip|noclip}
      set style ellipse size <size> units {xy|xx|yy} {clip|noclip}
      set style fill <fillstyle>
      set style histogram <histogram style options>
      set style line <n> <linestyle>
      set style rectangle <object options> <linestyle> <fillstyle>
      set style textbox {<n>} {opaque|transparent} {{no}border} {fillcolor} set style arrow

You can use ‘set style arrow‘ to define a set of arrow types. Each type has its own width, point type, color, etc so that you can refer to them later by an index instead of repeating all the information at each invocation.


      set style arrow <index> default
      set style arrow <index> {nohead | head | backhead | heads}
                              {size <length>,<angle>{,<backangle>} {fixed}}
                              {filled | empty | nofilled | noborder}
                              {front | back}
                              { {linestyle | ls <line_style>}
                                | {linetype | lt <line_type>}
                                  {linewidth | lw <line_width}
                                  {linecolor | lc <colorspec>}
                                  {dashtype | dt <dashtype>} }
      unset style arrow
      show style arrow

<index> is an integer that identifies the arrowstyle.

If ‘default‘ is given all arrow style parameters are set to their default values.

If the linestyle <index> already exists, only the given parameters are changed while all others are preserved. If not, all undefined values are set to the default values.

An arrow style invoked from a ‘plot‘ or ‘splot‘ command can include a data-dependent linecolor (‘lc variable‘ or ‘lc rgb variable‘) that consumes an additional column of data in the corresponding ‘using‘ specification. In this case the style is probably not useful for individual arrows created by ‘set arrow‘.

Specifying ‘nohead‘ produces arrows drawn without a head—a line segment. This gives you yet another way to draw a line segment on the plot. By default, arrows have one head. Specifying ‘heads‘ draws arrow heads on both ends of the line.

Head size can be modified using ‘size <length>,<angle>‘ or ‘size <length>,<angle>,<backangle>‘, where ‘<length>‘ defines length of each branch of the arrow head and ‘<angle>‘ the angle (in degrees) they make with the arrow. ‘<Length>‘ is in x-axis units; this can be changed by ‘first‘, ‘second‘, ‘graph‘, ‘screen‘, or ‘character‘ before the <length>; see ‘coordinates‘ for details.

By default the size of the arrow head is reduced for very short arrows. This can be disabled using the ‘fixed‘ keyword after the size command.

‘<backangle>‘ is the angle (in degrees) the back branches make with the arrow (in the same direction as ‘<angle>‘). It is ignored if the style is ‘nofilled‘.

Specifying ‘filled‘ produces filled arrow heads with a border line around the arrow head. Specifying ‘noborder‘ produces filled arrow heads with no border. In this case the tip of the arrow head lies exactly on the endpoint of the vector and the arrow head is slightly smaller overall. Dashed arrows should always use ‘noborder‘, since a dashed border is ugly. Not all terminals support filled arrow heads.

The line style may be selected from a user-defined list of line styles (see ‘set style line‘) or may be defined here by providing values for ‘<line_type>‘ (an index from the default list of styles) and/or ‘<line_width>‘ (which is a multiplier for the default width).

Note, however, that if a user-defined line style has been selected, its properties (type and width) cannot be altered merely by issuing another ‘set style arrow‘ command with the appropriate index and ‘lt‘ or ‘lw‘.

If ‘front‘ is given, the arrows are written on top of the graphed data. If ‘back‘ is given (the default), the arrow is written underneath the graphed data. Using ‘front‘ will prevent a arrow from being obscured by dense data.


To draw an arrow without an arrow head and double width, use:

      set style arrow 1 nohead lw 2
      set arrow arrowstyle 1

See also ‘set arrow‘ for further examples. boxplot

The boxplot command allows you to change the layout of plots created using the boxplot plot style.


      set style boxplot {range <r> | fraction <f>}
                        {{no}outliers} {pointtype <p>}
                        {candlesticks | financebars}
                        {medianlinewidth <width>}
                        {separation <x>}
                        {labels off | auto | x | x2}
                        {sorted | unsorted}

The box in the boxplot always spans the range of values from the first quartile to the third quartile of the data points. The limit of the whiskers that extend from the box can be controlled in two different ways. By default the whiskers extend from each end of the box for a range equal to 1.5 times the interquartile range (i.e. the vertical height of the box proper). Each whisker is truncated back toward the median so that it terminates at a y value belonging to some point in the data set. Since there may be no point whose value is exactly 1.5 times the interquartile distance, the whisker may be shorter than its nominal range. This default corresponds to

      set style boxplot range 1.5

Alternatively, you can specify the fraction of the total number of points that the whiskers should span. In this case the range is extended symmetrically from the median value until it encompasses the requested fraction of the data set. Here again each whisker is constrained to end at a point in the data set. To span 95% of the points in the set

      set style boxplot fraction 0.95

Any points that lie outside the range of the whiskers are considered outliers. By default these are drawn as individual circles (pointtype 7). The option ‘nooutliers‘ disables this. If outliers are not drawn they do not contribute to autoscaling.

By default boxplots are drawn in a style similar to candlesticks, but you have the option of using instead a style similar to finance bars.

A crossbar indicating the median is drawn using the same line type as box boundary. If you want a thicker line for the median

      set style boxplot medianlinewidth 2.0

If you want no median line, set this to 0.

If the using specification for a boxplot contains a fourth column, the values in that column will be interpreted as the discrete leveles of a factor variable. In this case more than one boxplots may be drawn, as many as the number of levels of the factor variable. These boxplots will be drawn next to each other, the distance between them is 1.0 by default (in x-axis units). This distance can be changed by the option ‘separation‘.

The labels option governs how and where these boxplots (each representing a part of the dataset) are labeled. By default the value of the factor is put as a tick label on the horizontal axis – x or x2, depending on which one is used for the plot itself. This setting corresponds to option ‘labels auto‘. The labels can be forced to use either of the x or x2 axes – options ‘labels x‘ and ‘labels x2‘, respectively –, or they can be turned off altogether with the option ‘labels off‘.

By default the boxplots corresponding to different levels of the factor variable are not sorted; they will be drawn in the same order the levels are encountered in the data file. This behavior corresponds to the ‘unsorted‘ option. If the ‘sorted‘ option is active, the levels are first sorted alphabetically, and the boxplots are drawn in the sorted order.

The ‘separation‘, labels, ‘sorted‘ and ‘unsorted‘ option only have an effect if a fourth column is given the plot specification.

See boxplot, candlesticks, financebars. set style data

The ‘set style data‘ command changes the default plotting style for data plots.


      set style data <plotting-style>
      show style data

See ‘plotting styles‘ for the choices. ‘show style data‘ shows the current default data plotting style. set style fill

The ‘set style fill‘ command is used to set the default style of the plot elements in plots with boxes, histograms, candlesticks and filledcurves. This default can be superseded by fillstyles attached to individual plots.

Note that there is a separate default fill style for rectangles created by ‘set obj‘. See rectangle.


      set style fill {empty
                      | {transparent} solid {<density>}
                      | {transparent} pattern {<n>}}
                     {border {lt} {lc <colorspec>} | noborder}

The ‘empty‘ option causes filled areas not to be filled. This is the default.

The ‘solid‘ option causes filling with a solid color, if the terminal supports that. The <density> parameter specifies the intensity of the fill color. At a <density> of 0.0, the box is empty, at <density> of 1.0, the inner area is of the same color as the current linetype. Some terminal types can vary the density continuously; others implement only a few levels of partial fill. If no <density> parameter is given, it defaults to 1.

The ‘pattern‘ option causes filling to be done with a fill pattern supplied by the terminal driver. The kind and number of available fill patterns depend on the terminal driver. If multiple datasets using filled boxes are plotted, the pattern cycles through all available pattern types, starting from pattern <n>, much as the line type cycles for multiple line plots.

Fill color (‘fillcolor <colorspec>‘) is distinct from fill style. I.e. plot elements or objects can share a fillstyle while retaining separate colors. In most places where a fillstyle is accepted you can also specify a fill color. Fillcolor may be abbreviated ‘fc‘. Otherwise the fill color is take from the current linetype. Example:

      plot FOO with boxes fillstyle solid 1.0 fillcolor "cyan"


The bare keyword border causes the filled object to be surrounded by a solid line of the current linetype and color. You can change the color of this line by adding either a linetype or a linecolor. ‘noborder‘ specifies that no bounding line is drawn. Examples:

     # Half-intensity fill, full intensity border in same color
     set style fill solid 0.5 border
     # Half-transparent fill, solid black border (linetype -1)
     set style fill transparent solid 0.5 border -1
     # Pattern fill in current color, border using color of linetype 5
     plot ... with boxes fillstyle pattern 2 border lt 5
     # Fill area in cyan, border in blue
     plot ... with boxes fillcolor "cyan" fs solid border linecolor "blue"

Note: The border property of a fill style only affects plots drawn filledcurves in the default mode (closed curve).


Some terminals support the attribute ‘transparent‘ for filled areas. In the case of transparent solid fill areas, the ‘density‘ parameter is interpreted as an alpha value; that is, density 0 is fully transparent, density 1 is fully opaque. In the case of transparent pattern fill, the background of the pattern is either fully transparent or fully opaque.

Note that there may be additional limitations on the creation or viewing of graphs containing transparent fill areas. For example, the png terminal can only use transparent fill if the "truecolor" option is set. Some pdf viewers may not correctly display the fill areas even if they are correctly described in the pdf file. Ghostscript/gv does not correctly display pattern-fill areas even though actual PostScript printers generally have no problem. set style function

The ‘set style function‘ command changes the default plotting style for function plots (e.g. lines, points, filledcurves). See ‘plotting styles‘.


      set style function <plotting-style>
      show style function set style histogram

See histograms. set style increment

‘Note‘: This command has been deprecated. Instead please use the newer command ‘set linetype‘, which redefines the linetypes themselves rather than searching for a suitable temporary line style to substitute. See ‘set linetype‘


      set style increment {default|userstyles}
      show style increment

By default, successive plots within the same graph will use successive linetypes from the default set for the current terminal type. However, choosing ‘set style increment user‘ allows you to step through the user-defined line styles rather than through the default linetypes.


      set style line 1 lw 2 lc rgb "gold"
      set style line 2 lw 2 lc rgb "purple"
      set style line 4 lw 1 lc rgb "sea-green"
      set style increment user

      plot f1(x), f2(x), f3(x), f4(x)

should plot functions f1, f2, f4 in your 3 newly defined line styles. If a user-defined line style is not found then the corresponding default linetype is used instead. E.g. in the example above, f3(x) will be plotted using the default linetype 3. set style line

Each terminal has a default set of line and point types, which can be seen by using the command test. ‘set style line‘ defines a set of line types and widths and point types and sizes so that you can refer to them later by an index instead of repeating all the information at each invocation.


      set style line <index> default
      set style line <index> {{linetype  | lt} <line_type> | <colorspec>}
                             {{linecolor | lc} <colorspec>}
                             {{linewidth | lw} <line_width>}
                             {{pointtype | pt} <point_type>}
                             {{pointsize | ps} <point_size>}
                             {{pointinterval | pi} <interval>}
                             {{pointnumber | pn} <max_symbols>}
                             {{dashtype | dt} <dashtype>}
      unset style line
      show style line

‘default‘ sets all line style parameters to those of the linetype with that same index.

If the linestyle <index> already exists, only the given parameters are changed while all others are preserved. If not, all undefined values are set to the default values.

Line styles created by this mechanism do not replace the default linetype styles; both may be used. Line styles are temporary. They are lost whenever you execute a reset command. To redefine the linetype itself, please see ‘set linetype‘.

The line and point types default to the index value. The exact symbol that is drawn for that index value may vary from one terminal type to another.

The line width and point size are multipliers for the current terminal’s default width and size (but note that <point_size> here is unaffected by the multiplier given by the commandpointsize).

The ‘pointinterval‘ controls the spacing between points in a plot drawn with style linespoints. The default is 0 (every point is drawn). For example, ‘set style line N pi 3‘ defines a linestyle that uses pointtype N, pointsize and linewidth equal to the current defaults for the terminal, and will draw every 3rd point in plots using linespoints. A negative value for the interval is treated the same as a positive value, except that some terminals will try to interrupt the line where it passes through the point symbol.

The ‘pointnumber‘ property is similar to ‘pointinterval‘ except that rather than plotting every Nth point it limits the total number of points to N.

Not all terminals support the ‘linewidth‘ and pointsize features; if not supported, the option will be ignored.

Terminal-independent colors may be assigned using either ‘linecolor <colorspec>‘ or ‘linetype <colorspec>‘, abbreviated ‘lc‘ or ‘lt‘. This requires giving a RGB color triple, a known palette color name, a fractional index into the current palette, or a constant value from the current mapping of the palette onto cbrange. See ‘colors‘, colorspec, palette, colornames, cbrange.

‘set style line <n> linetype <lt>‘ will set both a terminal-dependent dot/dash pattern and color. The commands‘set style line <n> linecolor <colorspec>‘ or ‘set style line <n> linetype <colorspec>‘ will set a new line color while leaving the existing dot-dash pattern unchanged.

In 3d mode (‘splot‘ command), the special keyword palette is allowed as a shorthand for "linetype palette z". The color value corresponds to the z-value (elevation) of the splot, and varies smoothly along a line or surface.

Examples: Suppose that the default lines for indices 1, 2, and 3 are red, green, and blue, respectively, and the default point shapes for the same indices are a square, a cross, and a triangle, respectively. Then

      set style line 1 lt 2 lw 2 pt 3 ps 0.5

defines a new linestyle that is green and twice the default width and a new pointstyle that is a half-sized triangle. The commands

      set style function lines
      plot f(x) lt 3, g(x) ls 1

will create a plot of f(x) using the default blue line and a plot of g(x) using the user-defined wide green line. Similarly the commands

      set style function linespoints
      plot p(x) lt 1 pt 3, q(x) ls 1

will create a plot of p(x) using the default triangles connected by a red line and q(x) using small triangles connected by a green line.

      splot sin(sqrt(x*x+y*y))/sqrt(x*x+y*y) w l pal

creates a surface plot using smooth colors according to palette. Note, that this works only on some terminals. See also palette, pm3d.

      set style line 10 linetype 1 linecolor rgb "cyan"

will assign linestyle 10 to be a solid cyan line on any terminal that supports rgb colors. set style circle


      set style circle {radius {graph|screen} <R>}

This command sets the default radius used in plot style "with circles". It applies to data plots with only 2 columns of data (x,y) and to function plots. The default is "set style circle radius graph 0.02". ‘Nowedge‘ disables drawing of the two radii that connect the ends of an arc to the center. The default is ‘wedge‘. This parameter has no effect on full circles. ‘Clip‘ clips the circle at the plot boundaries, ‘noclip‘ disables this. Default is ‘clip‘. set style rectangle

Rectangles defined with the object command can have individual styles. However, if the object is not assigned a private style then it inherits a default that is taken from the rectangle command.


    set style rectangle {front|back} {lw|linewidth <lw>}
                        {fillcolor <colorspec>} {fs <fillstyle>}

See colorspec and ‘fillstyle‘. fillcolor may be abbreviated as ‘fc‘.


    set style rectangle back fc rgb "white" fs solid 1.0 border lt -1
    set style rectangle fc linsestyle 3 fs pattern 2 noborder

The default values correspond to solid fill with the background color and a black border. set style ellipse


      set style ellipse {units xx|xy|yy}
                        {size {graph|screen} <a>, {{graph|screen} <b>}}
                        {angle <angle>}

This command governs whether the diameters of ellipses are interpreted in the same units or not. Default is ‘xy‘, which means that the major diameter (first axis) of ellipses will be interpreted in the same units as the x (or x2) axis, while the minor (second) diameter in those of the y (or y2) axis. In this mode the ratio of the ellipse axes depends on the scales of the plot axes and aspect ratio of the plot. When set to ‘xx‘ or ‘yy‘, both axes of all ellipses will be interpreted in the same units. This means that the ratio of the axes of the plotted ellipses will be correct even after rotation, but either their vertical or horizontal extent will not be correct.

This is a global setting that affects all ellipses, both those defined as objects and those generated with the ‘plot‘ command, however, the value of ‘units‘ can also be redefined on a per-plot and per-object basis.

It is also possible to set a default size for ellipses with the size keyword. This default size applies to data plots with only 2 columns of data (x,y) and to function plots. The two values are interpreted as the major and minor diameters (as opposed to semi-major and semi-minor axes) of the ellipse.

The default is "set style ellipse size graph 0.05,0.03".

Last, but not least it is possible to set the default orientation with the ‘angle‘ keyword. The orientation, which is defined as the angle between the major axis of the ellipse and the plot’s x axis, must be given in degrees.

‘Clip‘ clips the ellipse at the plot boundaries, ‘noclip‘ disables this. Default is ‘clip‘.

For defining ellipse objects, see ‘set object ellipse‘; for the 2D plot style, see ellipses. set style parallelaxis


      set style parallelaxis {front|back} {line-properties}

Determines the line type and layer for drawing the vertical axes in plots parallelaxes. See parallelaxes, paxis. set style spiderplot


        set style spiderplot
                  {fillstyle <fillstyle-properties>}
                  {<line-properties> | <point-properties>}

This commands controls the default appearance of spider plots. The fill, line, and point properties can be modified in the first component of the plot command. The overall appearance of the plot is also affected by other settings such as spiderplot. See also paxis, spiderplot. Example:

     # Default spider plot will be a polygon with a thick border but no fill
     set style spiderplot fillstyle empty border lw 3
     # This one will additionally place an open circle (pt 6) at each axis
     plot for [i=1:6] DATA pointtype 6 pointsize 3 set style textbox


        set style textbox {<boxstyle-index>}
                  {opaque|transparent} {fillcolor <color>}
                  {{no}border {<bordercolor>}}{linewidth <lw>}
                  {margins <xmargin>,<ymargin>}

This command controls the appearance of labels with the attribute ’boxed’. Terminal types that do not support boxed text will ignore this style. Note: Implementation for some terminals (svg, latex) is incomplete. Most terminals cannot place a box correctly around rotated text.

Three numbered textbox styles can be defined. If no boxstyle index <bs> is given, the default (unnumbered) style is changed. Example:

     # default style has only a black border
     set style textbox transparent border lc "black"
     # style 2 (bs 2) has a light blue background with no border
     set style textbox 2 opaque fc "light-cyan" noborder
     set label 1 "I'm in a box" boxed
     set label 2 "I'm blue" boxed bs 2

3.29.87 surface

The surface command is only relevant for 3D plots (‘splot‘).


      set surface {implicit|explicit}
      unset surface
      show surface

surface will cause ‘splot‘ to not draw points or lines corresponding to any of the function or data file points. This is mainly useful for drawing only contour lines rather than the surface they were derived from. Contours may still be drawn on the surface, depending on the contour option. To turn off the surface for an individual function or data file while leaving others active, use the ‘nosurface‘ keyword in the ‘splot‘ command. The combination ‘unset surface; set contour base‘ is useful for displaying contours on the grid base. See also contour.

If a 3D data set is recognizable as a mesh (grid) then by default the program implicitly treats the plot style ‘with lines‘ as requesting a gridded surface. See ‘grid_data‘. The command ‘set surface explicit‘ suppresses this expansion, plotting only the individual lines described by separate blocks of data in the input file. A gridded surface can still be plotted by explicitly requesting splot surface.

3.29.88 table

When table mode is enabled, ‘plot‘ and ‘splot‘ commands print out a multicolumn text table of values

     X Y {Z} <flag>

rather than creating an actual plot on the current terminal. The flag character is "i" if the point is in the active range, "o" if it is out-of-range, or "u" if it is undefined. The data format is determined by the format of the axis tickmarks (see ‘set format‘), and the columns are separated by single spaces. This can be useful if you want to generate contours and then save them for further use. The same method can be used to save interpolated data (see samples and dgrid3d).


      set table {"outfile" | $datablock} {append}
                {separator {whitespace|tab|comma|"<char>"}}
      plot <whatever>
      unset table

Subsequent tabular output is written to "outfile", if specified, otherwise it is written to stdout or other current value of output. If ‘outfile‘ exists it will be replaced unless the ‘append‘ keyword is given. Alternatively, tabular output can be redirected to a named data block. Data block names start with ’$’, see also ‘inline data‘. You must explicitly table in order to go back to normal plotting on the current terminal.

The ‘separator‘ character can be used to output csv (comma separated value) files. This mode only affects plot style table. See table. plot with table

This discussion applies only to the special plot style table.

To avoid any style-dependent processing of the input data being tabulated (smoothing, errorbar expansion, secondary range checking, etc), or to increase the number of columns that can be tabulated, use the keyword "table" instead of a normal plot style. In this case the output does not contain an extra, last, column of flags ‘i‘, ‘o‘, ‘u‘ indicated inrange/outrange/undefined. The destination for output must first be specified with ‘set table <where>‘. For example

     set table $DATABLOCK1
     plot <file> using 1:2:3:4:($5+$6):(func($7)):8:9:10 with table

Because there is no actual plot style in this case the columns do not correspond to specific axes. Therefore xrange, yrange, etc are ignored.

If a ‘using‘ term evaluates to a string, the string is tabulated. Numerical data is always written with format %g. If you want some other format use sprintf or gprintf to create a formatted string.

     plot <file> using ("File 1"):1:2:3 with table
     plot <file> using (sprintf("%4.2f",$1)) : (sprintf("%4.2f",$3)) with table

To create a csv file use

     set table "tab.csv" separator comma
     plot <foo> using 1:2:3:4 with table

[EXPERIMENTAL] To select only a subset of the data points for tabulation you can provide an input filter condition (‘if <expression>‘) at the end of the command. Note that the input filter may reference data columns that are not part of the output. This feature may change substantially before appearing in a released version of gnuplot.

     plot <file> using 1:2:($4+$5) with table if (strcol(3) eq "Red")
     plot <file> using 1:2:($4+$5) with table if (10. < $1 && $1 < 100.)
     plot <file> using 1:2:($4+$5) with table if (filter($6,$7) != 0)

3.29.89 terminal

‘gnuplot‘ supports many different graphics devices. Use terminal to tell ‘gnuplot‘ what kind of output to generate. Use output to redirect that output to a file or device.


      set terminal {<terminal-type> | push | pop}
      show terminal

If <terminal-type> is omitted, ‘gnuplot‘ will list the available terminal types. <terminal-type> may be abbreviated.

If both terminal and output are used together, it is safest to give terminal first, because some terminals set a flag which is needed in some operating systems.

Some terminals have many additional options. The options used by a previous invocation ‘set term <term> <options>‘ of a given ‘<term>‘ are remembered, thus subsequent ‘set term <term>‘ does not reset them. This helps in printing, for instance, when switching among different terminals—previous options don’t have to be repeated.

The command ‘set term push‘ remembers the current terminal including its settings while ‘set term pop‘ restores it. This is equivalent to ‘save term‘ and ‘load term‘, but without accessing the filesystem. Therefore they can be used to achieve platform independent restoring of the terminal after printing, for instance. After gnuplot’s startup, the default terminal or that from ‘startup‘ file is pushed automatically. Therefore portable scripts can rely that ‘set term pop‘ restores the default terminal on a given platform unless another terminal has been pushed explicitly.

For more information, see the ‘complete list of terminals‘.

3.29.90 termoption

The termoption command allows you to change the behaviour of the current terminal without requiring a new terminal command. Only one option can be changed per command, and only a small number of options can be changed this way. Currently the only options accepted are

     set termoption {no}enhanced
     set termoption font "<fontname>{,<fontsize>}"
     set termoption fontscale <scale>
     set termoption {linewidth <lw>}{lw <lw>}

3.29.91 theta

Polar coordinate plots are by default oriented such that theta = 0 is on the right side of the plot, with theta increasing as you proceed counterclockwise so that theta = 90 degrees is at the top. theta allows you to change the origin and direction of the polar angular coordinate theta.

     set theta {right|top|left|bottom}
     set theta {clockwise|cw|counterclockwise|ccw}

theta restores the default state "set theta right ccw".

3.29.92 tics

The ‘set tics‘ command controls the tic marks and labels on all axes at once.

The tics may be turned off with the ‘unset tics‘ command, and may be turned on (the default state) with ‘set tics‘. Fine control of tics on individual axes is possible using the alternative commands ‘set xtics‘, ztics, etc.


      set tics {axis | border} {{no}mirror}
               {in | out} {front | back}
               {{no}rotate {by <ang>}} {offset <offset> | nooffset}
               {left | right | center | autojustify}
               {format "formatstring"} {font "name{,<size>}"} {{no}enhanced}
               { textcolor <colorspec> }
      set tics scale {default | <major> {,<minor>}}
      unset tics
      show tics

The options can be applied to a single axis (x, y, z, x2, y2, cb), e.g.

      set xtics rotate by -90
      unset cbtics

All tic marks are drawn using the same line properties as the plot border (see border).

Set tics ‘back‘ or ‘front‘ applies to all axes at once, but only for 2D plots (not splot). It controls whether the tics are placed behind or in front of the plot elements, in the case that there is overlap.

‘axis‘ or border tells ‘gnuplot‘ to put the tics (both the tics themselves and the accompanying labels) along the axis or the border, respectively. If the axis is very close to the border, the ‘axis‘ option will move the tic labels to outside the border in case the border is printed (see border). The relevant margin settings will usually be sized badly by the automatic layout algorithm in this case.

‘mirror‘ tells ‘gnuplot‘ to put unlabeled tics at the same positions on the opposite border. ‘nomirror‘ does what you think it does.

‘in‘ and ‘out‘ change the tic marks to be drawn inwards or outwards.

‘set tics scale‘ controls the size of the tic marks. The first value <major> controls the auto-generated or user-specified major tics (level 0). The second value controls the auto-generated or user-specified minor tics (level 1). <major> defaults to 1.0, <minor> defaults to <major>/2. Additional values control the size of user-specified tics with level 2, 3, ... Default tic sizes are restored by ‘set tics scale default‘.

‘rotate‘ asks ‘gnuplot‘ to rotate the text through 90 degrees, which will be done if the terminal driver in use supports text rotation. ‘norotate‘ cancels this. ‘rotate by <ang>‘ asks for rotation by <ang> degrees, supported by some terminal types.

The defaults are ‘border mirror norotate‘ for tics on the x and y axes, and ‘border nomirror norotate‘ for tics on the x2 and y2 axes. For the z axis, the default is ‘nomirror‘.

The <offset> is specified by either x,y or x,y,z, and may be preceded by ‘first‘, ‘second‘, ‘graph‘, ‘screen‘, or ‘character‘ to select the coordinate system. <offset> is the offset of the tics texts from their default positions, while the default coordinate system is ‘character‘. See ‘coordinates‘ for details. ‘nooffset‘ switches off the offset.

By default, tic labels are justified automatically depending on the axis and rotation angle to produce aesthetically pleasing results. If this is not desired, justification can be overridden with an explicit ‘left‘, ‘right‘ or ‘center‘ keyword. ‘autojustify‘ restores the default behavior.

‘set tics‘ with no options restores mirrored, inward-facing tic marks for the primary axes. All other settings are retained.

See also ‘set xtics‘ for more control of major (labeled) tic marks and mxtics for control of minor tic marks. These commands provide control of each axis independently.

3.29.93 ticslevel

Deprecated. See xyplane.

3.29.94 ticscale

The ticscale command is deprecated, use ‘set tics scale‘ instead.

3.29.95 timestamp

The command timestamp places the current time and date in the plot margin.


      set timestamp {"<format>"} {top|bottom} {{no}rotate}
                    {offset <xoff>{,<yoff>}} {font "<fontspec>"}
                    {textcolor <colorspec>}
      unset timestamp
      show timestamp

The format string is used to write the date and time. Its default value is what asctime() uses: "%a %b %d %H:%M:%S %Y" (weekday, month name, day of the month, hours, minutes, seconds, four-digit year). With ‘top‘ or ‘bottom‘ you can place the timestamp along the top left or bottom left margin (default: bottom). ‘rotate‘ writes the timestamp vertically. The constants <xoff> and <yoff> are offsets that let you adjust the position more finely. <font> is used to specify the font with which the time is to be written.

The abbreviation ‘time‘ may be used in place of timestamp.


      set timestamp "%d/%m/%y %H:%M" offset 80,-2 font "Helvetica"

See timefmt for more information about time format strings.

3.29.96 timefmt

This command sets the default format used to input time data. See ‘set xdata time‘, ‘timecolumn‘.


      set timefmt "<format string>"
      show timefmt

The valid formats for both timefmt and ‘timecolumn‘ are:

      Format       Explanation
      %d           day of the month, 1--31
      %m           month of the year, 1--12